無料でロボットをダウンロードする方法を見る
Telegram上で私たちを見つけてください。
私たちのファンページに参加してください
興味深いスクリプト?
それではリンクにそれを投稿してください。-
他の人にそれを評価してもらいます
記事を気に入りましたか?MetaTrader 5ターミナルの中でそれを試してみてください。
エキスパート

MQL5 Wizard - RSIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナル - MetaTrader 5のためのエキスパート

ビュー:
1050
評価:
(19)
パブリッシュ済み:
2015.11.06 09:19
アップデート済み:
2016.11.22 07:34
\MQL5\Include\Expert\Signal\MySignals\
このコードに基づいたロボットまたはインジケーターが必要なら、フリーランスでご注文ください フリーランスに移動

MQL5 Wizardを使えば、クライアントターミナルにあるStandard libraryのエキスパートアドバイザーを自動生成することができます。(詳細は、Creating Ready-Made Expert Advisors in MQL5 Wizardを参照)トレードシグナルのクラスを生成しさせすれば、トレードアイディアをすぐに確認することができますクラスの例と構造については MQL5 Wizard: How to Create a Module of Trading Signalsを参照してください。

一般的な考え方は下記の通りです。:CExpertSignalがシグナルのクラスです。そして、LongCondition()ShortCondition() を上書きする必要があります。

"Strategies of best traders" (ロシア)という著書があります。 そこには数多くの手法と方法が記述されており、転換足パターンを StochasticCCIMFIRSIの条件のもと、焦点を当てていきます。

最も良い方法は、ロウソク足のパターンの確認に、CExpertSignalから導かれるクラスを切り分けて生成することです。ロウソク足のパターンによるトレードシグナルの確認には、CCandlePatternのクラスを書いて、必要な条件例えば、オシレーターの確認など)を追加すれば十分です。

RSIの条件付きの "Dark Cloud Cover/Piercing Line"のシグナルを考えてみます。トレードシグナルのモジュールは、CCandlePattern classに基づいています。ロウソク足のパターンによるシグナルの生成のシンプルな一例です。


1. "Dark Cloud Cover" and "Piercing Line"のロウソク足の転換パターン

1.1. Dark Cloud Cover

上昇トレンドの最後に起こる、ベア型のロウソク足の転換です。一日目に長い白いロウソク足が形成され、上の窓が2日目に形成される。しかし、2日目の終値が1日目の真ん中よりも下にある。

図1. "Dark Cloud Cover" ロウソク足パターン

図1. "Dark Cloud Cover" ロウソク足パターン

"Dark Cloud Cover"は、 CCandlePattern の CheckPatternDarkCloudCover() メソッドに実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Dark Cloud Cover" candlestick pattern       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternDarkCloudCover()
  {
//--- Dark Cloud Cover 
   if((Close(2)-Open(2)>AvgBody(1))  && // (long white)
      (Close(1)<Close(2))            && // 
      (Close(1)>Open(2))             && // (close within previous body)
      (MidOpenClose(2)>CloseAvg(1))  && // (uptrend)
      (Open(1)>High(2)))                // (open at new high)
      return(true);
//---
   return(false);
  }

クラスCCandlePattern のメソッドCheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) が、"Dark Cloud Cover"の確認に使います。


1.2. Piercing Line

2日目の下窓は下降トレンドを延長している。しかし、2日目の終値が1日目のロウソク足の実体の真ん中よりも上にある。このことは、ベアが底にあるということを示唆します。:このプライスアクションは、ロウソク足チャートとバーチャートでは判別可能な違いはありません。2日目の終値が1日目の実体を超えれば超えるほど、反転シグナルは成功率が高くなります。

図2. "Piercing Line"

図2. "Piercing Line"

"Piercing Line"は、 CCandlePatternのCheckPatternPiercingLine() method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Piercing Line" candlestick pattern          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternPiercingLine()
  {
//--- Piercing Line
   if((Close(1)-Open(1)>AvgBody(1)) && // (long white)
      (Open(2)-Close(2)>AvgBody(1)) && // (long black)
      (Close(1)>Close(2))           && //  
      (Close(1)<Open(2))            && // (close inside previous body) 
      (MidOpenClose(2)<CloseAvg(2)) && // (downtrend)
      (Open(1)<Low(2)))                // (open lower than previous Low) 
      return(true);
//---
   return(false);
  }

CCandlePattern class のCheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) method を、 "Piercing Line"で使います。


2. RSI の条件付きのシグナル

買いポジション・売りポジションのシグナルは、RSI で確認する必要があります。RSI の値は、基準値よりも低いか/大きい必要があります。 (買いポジションは40、売りポジションは60).

ポジションの決済は RSIの値で行います。2通りのケースがあります。:

  1. RSI が反対の基準点に到達した場合(買いポジションは70。売りポジションは30)
  2. 逆のシグナルが発生しない(RSIが次の点に達したとき: 買いポジションは30。売りポジションは70)

図3. RSIによる条件付きの"Dark Cloud Cover"

図3. RSIによる条件付きの"Dark Cloud Cover"


  • int CDC_PL_RSI::LongCondition() - 買いポジションのエントリー条件(80) と 売りポジションの決済条件 (40);
  • int CDC_PL_RSI::ShortCondition() - 売りポジションのエントリー条件(80) と 買いポジションの決済条件 (40).

2.1. 買いポジション/売りポジションの決済

  1. "Piercing Line"の条件は、RSI で確認しなければなりません。 : RSI(1)<40 (直近の確定した足のRSIの値が40よりも小さい)

  2. RSIが基準値 70 か 30 を上抜けした場合、売りポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CDC_PL_RSI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Piercing Line pattern and RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) && (RSI(1)<40))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (upward 30, upward 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- return result
   return(result);
  }

2.2. 売りポジション/買いポジションの決済

  1. "Dark Cloud Cover"の条件は、RSI で確認しなければなりません。: RSI(1)>60 (直近の確定した足のRSI が60よりも大きい)..

  2. RSIが基準値 70 か 30を下向きにクロスした場合、買いポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CDC_PL_RSI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Dark Cloud Cover pattern and RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) && (RSI(1)>60))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 70, downward 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- return result
   return(result);
  }


2.3. MQL5 WizardでEAを生成する

CDC_PL_RSI classはStandard Libraryには含まれていません。利用するには、adc_pl_rsi.mqh をダウンロードして、client_terminal_data\folder\MQL5\Include\Expert\Signal\MySignalsに保存する必要があります。(添付詳細)同様の操作が acandlepatterns.mqh にも必要です。MQL5 Wizardを使うには、MetaEditorを再起動する必要があります。

エキスパートアドバイザーを生成するには、MQL5 Wizardを立ち上げてください。:

図4. MQL5 WizardでEAを生成する

図4. MQL5 WizardでEAを生成する

エキスパートアドバイザーの名前を決めましょう。:

図5. エキスパートアドバイザーの一般設定

図5. エキスパートアドバイザーの一般設定

トレードシグナルのモジュールを選択します。

図6. エキスパートアドバイザーのシグナルプロパティ

図6. エキスパートアドバイザーのシグナルプロパティ

今回の場合、モジュールは1つだけ使います。

"Signals based on Dark Cloud Cover/Piercing Line confirmed by RSI" のモジュールを追加:

図7. エキスパートアドバイザーのシグナルプロパティ

図7. エキスパートアドバイザーのシグナルプロパティ

シグナルの追加モジュール:

図8. エキスパートアドバイザーのシグナルプロパティ

図8. エキスパートアドバイザーのシグナルプロパティ

トレーリングプロパティにも様々なものがありますが、今回は"Trailing Stop not used"にします。:

図9. エキスパートアドバイザーのトレーリングプロパティTrailing properties of the Expert Advisor

図9. エキスパートアドバイザーのトレーリングプロパティTrailing properties of the Expert Advisor

資金管理プロパティとして、"Trading with fixed trade volume"(単利)を使います。:

図10エキスパートアドバイザーの資金管理プロパティMoney management properties of the Expert Advisor

図10エキスパートアドバイザーの資金管理プロパティMoney management properties of the Expert Advisor

"Finish"ボタンを押すと、エキスパートアドバイザーがExpert_ADC_PL_RSI.mq5に生成されます。保存場所は、terminal_data_folder\MQL5\Experts\です。

生成後のエキスパートアドバイザーのデフォルトのパラメーター:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

上記は下記にしなければなりません。:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Signal_ThresholdOpen/Signal_ThresholdClose パラメーターは、ポジションのオープン、決済の最初のレベルを決めます。

LongCondition() と ShortCondition() のメソッドのコードの中に、デフォルトの固定値が入っています。:

  • エントリー: 80;
  • 決済: 40.

MQL5 Wizard で生成したエキスパートアドバイザーは、トレードシグナルのモジュールの"ボート"を使ってエントリー、決済を行います。メインモジュール(コンテナとして、すべての追加モジュールを含む)のボートもまた、使われますが、 LongCondition() と ShortCondition() メソッドは常に0を返します。

メインモジュールの評価結果は、"ボート"平均が使われます。今回の場合、メインモジュールとシグナルのモジュールがあるので、初期値を与えるときには、このことを考慮に入れなければいけません。そのことにより、ThresholdOpen と ThresholdClose は、 40=(0+80)/2 and 20=(0+40)/2に設定しなければなりません。

Signal_StopLevel と Signal_TakeLevel パラメーターの値は、0にします。これは、ポジションの決済は、決済条件がtrueのときにのみ行われるということを表します。


2.4. バックテスト結果

過去データでエキスパートアドバイザーをテストしてみましょう(EURUSD H1, テスト期間: 2010.01.01-2011.02.23, PeriodRSI=20, MA_period=14).

エキスパートアドバイザーの生成において、今回は固定ロット(Trading Fixed Lot, 0.1), トレーリングストップ(Trailing not used)はなしを選択しました。

図11. Dark Cloud Cover/Piercing Line  + RSIのテスト結果

図11. Dark Cloud Cover/Piercing Line  + RSIのテスト結果


パラメーターの最適な設定値は、MetaTrader 5 client terminalのStrategy Testerで探すことができます。

MQL5 Wizard で生成したコードは expert_ad_pl_rsi.mq5です。


MetaQuotes Ltdによってロシア語から翻訳されました。
元のコード: https://www.mql5.com/ru/code/300

MQL5 Wizard - MFIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナル MQL5 Wizard - MFIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナル

MFIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナルを検証することができます。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。

MQL5 Wizard - CCIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナル MQL5 Wizard - CCIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナル

CCIによる条件付きの"Dark Cloud Cover/Piercing Line"のロウソク足パターンによるシグナルを検証することができます。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。

MQL5 Wizard - ストキャスティクスをフィルターとした"Morning Star/Evening Star"ロウソク足パターン MQL5 Wizard - ストキャスティクスをフィルターとした"Morning Star/Evening Star"ロウソク足パターン

このトレードシグナルは、ストキャスティクスをフィルターとした"Morning Star/Evening Star"ロウソク足パターンですこの戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。

MQL5 Wizard - ストキャスティクスをフィルターとした"Bullish Engulfing/Bearish Engulfing"ロウソク足パターン MQL5 Wizard - ストキャスティクスをフィルターとした"Bullish Engulfing/Bearish Engulfing"ロウソク足パターン

このトレードシグナルは、ストキャスティクスをフィルターとした"Bullish Engulfing/Bearish Engulfing"ロウソク足パターンです。この戦略のエキスパートのコードは、MQL5ウィザードで自動生成させることができます。