Assistant MQL5 - Signaux de Trading Basés sur un Harami Haussier/Harami Baissier + RSI - expert pour MetaTrader 5

L'Assistant MQL5 permet de créer des Expert Advisors prêts à l'emploi basés sur les classes de la bibliothèque standard livrées avec le terminal client (voir Création d'Expert Advisors prêts à l'emploi dans l'Assistant MQL5 pour les détails). Il permet de vérifier rapidement vos idées de trading, tout ce dont vous avez besoin est de créer votre propre classe de signaux de trading. La structure de cette classe et cet exemple se trouvent dans l'article Assistant MQL5 : Comment créer un module de signaux de trading.

L'idée générique est la suivante : la classe des signaux de trading est dérivée de CExpertSignal, ensuite, il est nécessaire de remplacer les méthodes virtuelles LongCondition() et ShortCondition() avec vos propres méthodes.

Il existe un livre "Stratégies des meilleurs traders" (en russe), de nombreuses stratégies de trading y sont envisagées, nous nous concentrerons sur les modèles de chandeliers d'inversion, confirmés par Stochastique, Oscillateurs CCI, MFI et RSI.

Le meilleur moyen est de créer la classe séparée, dérivée de CExpertSignal pour vérifier la formation des modèles de chandeliers. Pour la confirmation des signaux de trading, générés par les modèles de chandeliers, il suffit d'écrire la classe, dérivée de CCandlePattern et d'y ajouter les fonctionnalités nécessaires (par exemple, la confirmation par des oscillateurs).

Ici, nous allons considérer les signaux, basés sur le modèle de chandelier d'inversion "Harami haussier/Harami baissier", confirmé par l'indicateur RSI. Le module de signaux de trading est basé sur la classe CCandlePattern, c'est un exemple simple de son utilisation pour la création de signaux de trading avec des modèles de chandeliers.

1. Modèles de chandeliers inversés "Harami haussier et Harami baissier"

1.1. Harami Haussier

Le modèle de retournement haussier Harami se forme dans une tendance à la baisse lorsqu'un grand chandelier est suivi d'un plus petit chandelier dont le corps est situé dans la plage verticale du plus grand corps. Ce modèle indique que la tendance baissière (tendance baissière) peut s'inverser, cela signale que c'est le bon moment pour entrer dans une position longue. Le deuxième chandelier est ouvert avec un écart vers le haut.

Plus le deuxième chandelier (blanc) est petit, plus le renversement est probable.

Fig. 1. Modèle de chandelier "Harami haussier"

La reconnaissance du motif "Bullish Harami" est implémentée dans la méthode CheckPatternBullishHarami() de la classe CCandlePattern :

//+------------------------------------------------------------------+
//| Vérifie la formation du modèle de chandelier "Harami Haussier"   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishHarami()
  {
//--- Harami Haussier
   if((Close(1)>Open(1))              && // la dernière barre complétée est haussière (jour blanc)
     ((Open(2)-Close(2))>AvgBody(1))  && // la bougie précédente est baissière , son corps est supérieur à la moyenne (long noir)
     ((Close(1)<Open(2))              && // le prix de clôture de la bougie haussière est inférieur au prix d'ouverture de la bougie baissière 
      (Open(1)>Close(2)))             && // le prix d'ouverture de la bougie haussière est supérieur au prix de clôture de la bougie baissière
      (MidPoint(2)<CloseAvg(2)))         // tendance baissière
      return(true);
//---
   return(false);
  }

1.2. Harami Baissier

Le modèle d'inversion Harami Baissier se forme dans une tendance à la hausse lorsqu'un grand chandelier est suivi d'un plus petit chandelier dont le corps est situé dans la plage verticale du plus grand corps. Ce modèle indique que la tendance haussière (tendance haussière) peut s'inverser, cela signale que c'est le bon moment pour entrer dans une position courte. Le deuxième chandelier est ouvert avec un écart vers le bas.

Plus le deuxième chandelier (noir) est petit, plus le renversement est probable.

Fig. 2. Modèle de chandelier "Harami Baissier"

La reconnaissance du motif "Harami Baissier" est implémentée dans la méthode CheckPatternBearishHarami() de la classe CCandlePattern :

//+------------------------------------------------------------------+
//| Vérifie la formation du modèle de chandelier "Harami Baissier"   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishHarami()
  {
//--- Harami Baissier
   if((Close(1)<Open(1))              && // la dernière barre complétée est baissière (jour noir)
     ((Close(2)-Open(2))>AvgBody(1))  && // la bougie précédente est haussière , son corps est plus grand que la moyenne (long blanc)
     ((Close(1)>Open(2))              && // le prix de clôture de la bougie baissière est supérieur au prix d'ouverture de la bougie haussière 
      (Open(1)<Close(2)))             && // le prix d'ouverture de la bougie baissière est inférieur au prix de clôture de la bougie haussière
      (MidPoint(2)>CloseAvg(2)))         // tendance haussière
      return(true);
//---
   return(false);
  }

2. Signaux de trading, confirmés par l'indicateur RSI

Les signaux de trading pour ouvrir une position longue ou courte doivent être confirmés par l'indicateur RSI. La valeur du RSI doit être inférieure/supérieure aux niveaux critiques (40 pour la position longue et 60 pour la position courte).

La fermeture de la position ouverte dépend des valeurs du RSI. Cela peut se faire dans 2 cas :

1. si le RSI a atteint le niveau critique inverse (70 pour la position longue et 30 pour la position courte)
2. si le signal inverse n'est pas confirmé (lorsque le RSI atteint les niveaux suivants : 30 pour la position longue et 70 pour la position courte)

Figure 3. Modèle "Harami haussier", confirmé par l'indicateur RSI

• int CBH_BH_RSI::LongCondition() - vérifie les conditions d'ouverture d'une position longue (retourne 80) et de clôture de la position courte (retourne 40);
  
• int CBH_BH_RSI::ShortCondition() - vérifie les conditions d'ouverture d'une position courte (retourne 80) et de clôture de la position longue (retourne 40).

2.1. Ouverture d'une position longue/Cloôture d'une position courte

1. La formation du motif "Bullish Harami" doit être confirmée par l'indicateur RSI : RSI(1)<40 (la valeur du RSI de la dernière barre complétée doit être inférieure à 40).

2. La position courte doit être fermée si l'indicateur RSI a franchi à la hausse les niveaux critiques 70 ou 30.

//+------------------------------------------------------------------+
//| Vérifie les conditions d'entrée et de sortie du marché           |
//| 1) Entrée sur le marché (ouvrir position longue, résultat=80)    |
//| 2) Sortie du marché (fermer position courte, résultat=40)        |
//+------------------------------------------------------------------+
int CBH_BH_RSI::LongCondition()
  {
   int result=0;
//--- idx peut être utilisé pour déterminer le mode de travail de l'Expert Advisor
//--- idx=0 - dans ce cas, l'EA vérifie les conditions de trading à chaque tick
//--- idx=1 - dans ce cas, l'EA vérifie la situation de trading uniquement sur les nouvelles barres
   int idx   =StartIndex();
//--- vérification des conditions pour ouvrir une position longue
//--- formation du Harami Haussier et RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) && (RSI(1)<40))
     result=80;
//--- vérification des conditions pour fermer la position courte
//--- croisement de la ligne de signal avec les niveaux de surachat/survente (à la hausse de 30, à la hausse de 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- retourne le résultat
   return(result);
  }

2.2. Ouverture d'une position courte/Clôture d'une position longue

1. La formation du motif "Bearish Harami" doit être confirmée par l'indicateur RSI : RSI(1)>60 (la valeur de l'indicateur RSI de la dernière barre complétée doit être supérieure à 60).

2. La position longue doit être fermée si l'indicateur RSI a franchi à la baisse les niveaux critiques 70 ou 30.

//+------------------------------------------------------------------+
//| Vérifie les conditions d'entrée et de sortie du marché           |
//| 1) Entrée sur le marché (position courte ouverte, résultat=80)   |
//| 2) Sortie du marché (fermer position longue, résultat=40)        |
//+------------------------------------------------------------------+
int CBH_BH_RSI::ShortCondition()
  {
   int result=0;
//--- idx peut être utilisé pour déterminer le mode de travail de l'Expert Advisor
//--- idx=0 - dans ce cas, l'EA vérifie les conditions de trading à chaque tick
//--- idx=1 - dans ce cas, l'EA vérifie la situation de trading uniquement sur les nouvelles barres
   int idx   =StartIndex();
//--- vérification des conditions pour ouvrir une position courte
//--- formation du modèle Harami Baissier et RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) && (RSI(1)>60))
     result=80;
//--- vérification des conditions pour fermer la position longue
//--- croisement de la ligne de signal des niveaux de surachat/survente (à la baisse de 70, à la baisse de 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- retourne le résultat
   return(result);
  }

2.3. Création d'un Expert Advisor à l'aide de l'Assistant MQL5

Pour créer un Expert Advisor, lancez l'Assistant MQL5 :

Fig. 4. Création d'un Expert Advisor à l'aide de l'Assistant MQL5

Précisons le nom de l'Expert Advisor :

Fig. 5. Propriétés générales de l'Expert Advisor

Après cela, nous devons sélectionner les modules de signaux de trading utilisés.

Fig. 6. Propriétés du signal de l'Expert Advisor

Dans notre cas, nous n'utilisons qu'un seul module de signaux de trading.

Ajout du module "Signaux basés sur un harami haussier/harami baissier confirmé par RSI" :

Fig. 7. Propriétés du signal de l'Expert Advisor

Module de signaux de trading ajouté :

Fig. 8. Propriétés du signal de l'Expert Advisor

Vous pouvez sélectionner n'importe quelle propriété de fin, mais nous utiliserons "Trailing Stop not used":

Fig. 9. Propriétés de suivi de l'Expert Advisor

Concernant les propriétés de money management, nous utiliserons "Trading with fixed trade volume":

Fig. 10. Propriétés de gestion de l'argent de l'Expert Advisor

En appuyant sur le bouton "Terminer", nous obtiendrons le code de l'Expert Advisor généré, situé dans Expert_ABH_BH_RSI.mq5, il sera enregistré dans terminal_data_folder\MQL5\Experts\.

Les paramètres d'entrée par défaut de l'Expert Advisor généré :

//--- entrées pour le signal principal
input int            Signal_ThresholdOpen   =10 ; // Valeur seuil du signal à ouvrir [0...100]
input int            Signal_ThresholdClose  =10 ; // Valeur seuil du signal de fermeture [0...100]
input double         Signal_PriceLevel      =0.0 ; // Niveau de prix pour exécuter une transaction
input double         Signal_StopLevel       =50,0 ; // Niveau de Stop Loss (en points)
input double         Signal_TakeLevel       =50,0 ; // Niveau de Take Profit (en points)

doit être remplacé par :

//--- entrées pour le signal principal
input int            Signal_ThresholdOpen   =40 ; // Valeur seuil du signal à ouvrir [0...100]
input int            Signal_ThresholdClose  =20 ; // Valeur seuil du signal de fermeture [0...100]
input double         Signal_PriceLevel      =0.0 ; // Niveau de prix pour exécuter une transaction
input double         Signal_StopLevel       =0.0 ; // Niveau de Stop Loss (en points)
input double         Signal_TakeLevel       =0.0 ; // Niveau de Take Profit (en points)

Les paramètres d'entrée Signal_ThresholdOpen/Signal_ThresholdClose permettent de spécifier des niveaux de seuil pour l'ouverture et la fermeture des positions.

Dans le code des méthodes LongCondition() et ShortCondition() de la classe des signaux de trading, nous avons spécifié les valeurs fixes du seuil :

• Ouvreture de position: 80 ;
• Clôture de position : 40.
  

Les valeurs des paramètres d'entrée Signal_StopLevel et Signal_TakeLevel sont définies sur 0, cela signifie que la fermeture des positions ne sera effectuée que lorsque les conditions de fermeture seront vraies.

2.4. Résultats du backtesting de l'historique

Considérons le backtesting de l'Expert Advisor sur des données historiques (EURUSD H1, période de test : 2010.01.01-2011.03.11, PeriodRSI=37, MA_period=7).

Lors de la création de l'Expert Advisor, nous avons utilisé le volume fixe (Trading Fixed Lot, 0.1), l'algorithme Trailing Stop n'est pas utilisé (Trailing not used).

Fig. 11. Résultats des tests de l'Expert Advisor, basés sur Bullish Harami/Bearish Harami + RSI

Le meilleur ensemble de paramètres d'entrée peut être trouvé en utilisant le Strategy Tester du terminal client MetaTrader 5.

Le code de l'Expert Advisor, créé par l'Assistant MQL5 est joint dans expert_aml_rsi.mq5.