Watch how to download trading robots for free
Find us on Telegram!
Join our fan page
Interesting script?
So post a link to it -
let others appraise it
You liked the script? Try it in the MetaTrader 5 terminal
Experts

MQL5 Wizard - Trade Signals Based on Bullish Harami/Bearish Harami + RSI - expert for MetaTrader 5

Views:
8212
Rating:
(19)
Published:
2011.03.17 10:46
Updated:
2016.11.22 07:32
\MQL5\Include\Expert\Signal\MySignals\
acbh_bh_rsi.mqh (7.96 KB) view
Need a robot or indicator based on this code? Order it on Freelance Go to Freelance

The MQL5 Wizard allows creating ready-made Expert Advisors based on the Standard library classes delivered together with the client terminal (see Creating Ready-Made Expert Advisors in MQL5 Wizard for the details). It allows to check your trade ideas quickly, all you need is to create your own trading signals class. The structure of this class and example can be found in the article MQL5 Wizard: How to Create a Module of Trading Signals.

The generic idea is the following: the class of trading signals is derived from CExpertSignal, the next, it's necessary to override the LongCondition() and ShortCondition() virtual methods with your own methods.

There is a book "Strategies of best traders" (in Russian), there are many trading strategies are considered there, we will focus on reversal candlestick patterns, confirmed by Stochastic, CCI, MFI and RSI oscillators.

The best way is to create the separate class, derived from CExpertSignal for checking of formation of candlestick patterns. For confirmation of trade signals, generated by candlestick patterns, it's sufficient to write the class, derived from CCandlePattern and add the necessary features (for example, confirmation by oscillators) there.

Here we will consider the signals, based "Bullish Harami/Bearish Harami" reversal candlestick pattern, confirmed by RSI indicator. The module of trade signals is based on the CCandlePattern class, it's simple example of its use for creation of trade signals with candlestick patterns.


1. "Bullish Harami and "Bearish Harami" reversal candlestick patterns

1.1. Bullish Harami

The Bullish Harami reversal pattern forms in downward trend when large candlestick is followed by a smaller candlestick whose body is located within the vertical range of the larger body. This pattern indicates that the falling trend (downtrend) may be reversing, it signals that it's a good time to enter into a long position. The second candlestick is opened with a gap up.

The smaller the second (white) candlestick, the more likely the reversal.

Fig. 1. "Bullish Harami" candlestick pattern

Fig. 1. "Bullish Harami" candlestick pattern

The recognition of "Bullish Harami" pattern is implemented in CheckPatternBullishHarami() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Bullish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishHarami()
  {
//--- Bullish Harami
   if((Close(1)>Open(1))              && // the last completed bar is bullish (white day)
     ((Open(2)-Close(2))>AvgBody(1))  && // the previous candle is bearish, its body is greater than average (long black)
     ((Close(1)<Open(2))              && // close price of the bullish candle is lower than open price of the bearish candle 
      (Open(1)>Close(2)))             && // open price of the bullish candle is higher than close price of the bearish candle
      (MidPoint(2)<CloseAvg(2)))         // down trend
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) method of CCandlePattern class is used to check formation of "Bullish Harami" candlestick pattern.


1.2. Bearish Harami

The Bearish Harami reversal pattern forms in upward trend when large candlestick is followed by a smaller candlestick whose body is located within the vertical range of the larger body. This pattern indicates that the rising trend (uptrend) may be reversing, it signals that it's a good time to enter into a short position. The second candlestick is opened with a gap down.

The smaller the second (black) candlestick, the more likely the reversal.

Fig. 2. "Bearish Harami" candlestick pattern

Fig. 2. "Bearish Harami" candlestick pattern

The recognition of "Bearish Harami" pattern is implemented in CheckPatternBearishHarami() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Bearish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishHarami()
  {
//--- Bearish Harami
   if((Close(1)<Open(1))              && // last completed bar is bearish (black day)
     ((Close(2)-Open(2))>AvgBody(1))  && // the previous candle is bullish, its body is greater than average (long white)
     ((Close(1)>Open(2))              && // close price of the bearish candle is higher than open price of the bullish candle 
      (Open(1)<Close(2)))             && // open price of the bearish candle is lower than close price of the bullish candle
      (MidPoint(2)>CloseAvg(2)))         // up trend
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) method of CCandlePattern class is used to check formation of "Bearish Harami" candlestick pattern.


2. Trade signals, confirmed by RSI indicator

The trading signals to open long or short position must be confirmed by RSI indicator. The value of RSI must be lower/greater than critical levels (40 for long position and 60 for short position).

The closing of opened position depends on the values of RSI. It can be done in 2 cases:

  1. if RSI has reached the opposite critical level (70 for long position and 30 for short position)
  2. if the reverse signal isn't confirmed (when RSI reaches the following levels: 30 for long position and 70 for short position)

Figure 3. "Bullish Harami" pattern, confirmed by RSI indicator

Figure 3. "Bullish Harami" pattern, confirmed by RSI indicator

  • int CBH_BH_RSI::LongCondition() - checks conditions to open long position (returns 80) and close of the short position (returns 40);
  • int CBH_BH_RSI::ShortCondition() - checks conditions to open short position (returns 80) and close of the long position (returns 40).

2.1. Open long position/Close short position

  1. The formation of "Bullish Harami" pattern must be confirmed by RSI indicator: RSI(1)<40 (the value of the RSI of the last completed bar must be less than 40).

  2. The short position must be closed if RSI indicator has crossed upward the critical levels 70 or 30.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBH_BH_RSI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Harami pattern and RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) && (RSI(1)<40))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (upward 30, upward 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- return result
   return(result);
  }

2.2. Open short position/Close long position

  1. The formation of "Bearish Harami" pattern must be confirmed by RSI indicator: RSI(1)>60 (the value of the RSI indicator of the last completed bar must be greater than 60).

  2. The long position must be closed if RSI indicator has crossed downward the critical levels 70 or 30.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBH_BH_RSI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Bearish Harami pattern and RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) && (RSI(1)>60))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 70, downward 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- return result
   return(result);
  }


2.3. Creating Expert Advisor using MQL5 Wizard

The CBH_BH_RSI class isn't included in the Standard Library classes, to use it, it's necessary to download the acml_rsi.mqh file (see attachments) and save it to the client_terminal_data\folder\MQL5\Include\Expert\Signal\MySignals. The same should be done with the acandlepatterns.mqh file. You can use it in MQL5 Wizard after restart of the MetaEditor.

To create an Expert Advisor launch MQL5 Wizard:

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Let's specify the name of the Expert Advisor:

Fig. 5. General properties of the Expert Advisor

Fig. 5. General properties of the Expert Advisor

After that we need to select the modules of trade signals used.

Fig. 6. Signal properties of the Expert Advisor

Fig. 6. Signal properties of the Expert Advisor

In our case we use only one module of trade signals.

Adding the "Signals based on Bullish Harami/Bearish Harami confirmed by RSI" module of trading signals:

Fig. 7. Signal properties of the Expert Advisor

Fig. 7. Signal properties of the Expert Advisor

Module of trade signals added:

Fig. 8. Signal properties of the Expert Advisor

Fig. 8. Signal properties of the Expert Advisor

You can select any trailing properties, but we will use "Trailing Stop not used":

Fig. 9. Trailing properties of the Expert Advisor

Fig. 9. Trailing properties of the Expert Advisor

Concerning the money management properties, we will use "Trading with fixed trade volume":

Fig. 10. Money management properties of the Expert Advisor

Fig. 10. Money management properties of the Expert Advisor

By pressing the "Finish" button, we will get the code of the generated Expert Advisor, located in Expert_ABH_BH_RSI.mq5, it will be saved in terminal_data_folder\MQL5\Experts\.

The default input parameters of the generated Expert Advisor:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

must be replaced to:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

The Signal_ThresholdOpen/Signal_ThresholdClose input parameters allow to specify threshold levels for open and close of positions.

In code of the LongCondition() and ShortCondition() methods of the trade signals class we have specified the fixed values of the threshold:

  • Open position: 80;
  • Close position: 40.

The Expert Advisor, generated by MQL5 Wizard open and close position using the "votes" from the modules of trade signals. The vote of the main module (as container, it consist of all the modules added) is also used, but its LongCondition() and ShortCondition() methods always return 0.

The vote results of the main module is also used in "votes" averaging. In our case we have:  main module + 1 module of trade signals, so we need to take this fact into account when setting of the threshold values. Because of this fact the ThresholdOpen and ThresholdClose must be set as 40=(0+80)/2 and 20=(0+40)/2.

The values of  Signal_StopLevel and Signal_TakeLevel input parameters is set to 0, it means that closing of the positions will be done only when closing conditions will be true.


2.4. History backtesting results

Let's consider backtesting of the Expert Advisor on historical data (EURUSD H1, testing period: 2010.01.01-2011.03.11, PeriodRSI=37, MA_period=7).

In creation of Expert Advisor we used the fixed volume (Trading Fixed Lot, 0.1), Trailing Stop algorithm is not used (Trailing not used).

Fig. 11. Testing results of the Expert Advisor, based on Bullish Harami/Bearish Harami + RSI

Fig. 11. Testing results of the Expert Advisor, based on Bullish Harami/Bearish Harami + RSI


The best set of input parameters can be found using the Strategy Tester of MetaTrader 5 client terminal.

The code of the Expert Advisor, created by MQL5 Wizard is attached in expert_aml_rsi.mq5.


Translated from Russian by MetaQuotes Ltd.
Original code: https://www.mql5.com/ru/code/313

MQL5 Wizard - Trade Signals Based on Bullish Harami /Bearish Harami + MFI MQL5 Wizard - Trade Signals Based on Bullish Harami /Bearish Harami + MFI

Trade signals based on "Bullish Harami/Bearish Harami" candlestick pattern, confirmed by Market Facilitation Index (MFI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Bullish Harami/Bearish Harami + CCI MQL5 Wizard - Trade Signals Based on Bullish Harami/Bearish Harami + CCI

Trade signals based on "Bullish Harami/Bearish Harami" candlestick pattern, confirmed by Commodity Channel Index (CCI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man + Stochastic MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man + Stochastic

Trade signals based on "Hammer/Hanging Man" candlestick pattern, confirmed by Stochastic indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man  CCI MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man CCI

Trade signals based on "Hammer/Hanging Man" candlestick pattern, confirmed by Commodity Channel Index (CCI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.