Preguntas de los principiantes MQL5 MT5 MetaTrader 5 - página 1225

[[Eliminado]]

Vitaly Muzichenko:

Para todos. Más concretamente, muestra en la ventana del gráfico el número de barras especificado en el ajuste, y no depende del marco temporal

P.D. Nunca he cambiado este valor, pero acabo de comprobarlo y he visto que no se puede poner menos de 1000.

Entonces, ¿es necesario comprobarlo coniBars()?

[SEM]

Buenas tardes. El script no funciona por alguna razón.

¿Cuál es el problema?

//+------------------------------------------------------------------+
//|                                                         test.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   
   if(!ChartSetInteger(0,CHART_IS_MAXIMIZED,true))
     {
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
      //return(false);
     };


  }
//+------------------------------------------------------------------+

[Vladimir Karputov]

Los comentarios no relacionados con este tema han sido trasladados a "Preguntas de los principiantes de MQL4 MT4 MetaTrader 4".

[Vladimir Voronin]

¡Hola amigos!

Preguntas:

1. ¿Las órdenes Sell Stop Limit se colocan en el lado del corredor o en el lado del terminal?

2. Cuando cierre el programa, ¿se activará esta orden cuando se cumplan las condiciones?

Negociación en el mercado de acciones MICEX. Gracias de antemano.

[Alexey Belyakov]

Buenas tardes, queridos programadores. Pregunta sobre MQL5

¿Cómo implementar el control de posición en MetaTrader 5? Quiero tener sólo una posición abierta en una barra, es decir, la posición debe cerrarse sin importar en qué barra, pero la apertura debe ser en una sola barra.

Este código se ignora por completo. ¿Cuál es el error?

if (OrderSelect(HistoryDealsTotal()-1))

{
datetime Cu=PositionsTotal();
int hd=iBarShift(Symbol(),_Period,Cu);
if (hd<=1)
{
return;
}
}

[Aleksey Vyazmikin]

Alexey Belyakov:

Buenas tardes, queridos programadores. Pregunta sobre MQL5

¿Cómo implementar el control de posición en MetaTrader 5? Esto significa que la posición se cierra sin importar en qué barra, pero la apertura debe ser en una sola barra.

La forma más sencilla es guardar la hora de apertura de la barra, en la que se abre la posición en la variable global y luego, al abrir una nueva posición, comprobar la hora de apertura de la barra si el valor es superior al guardado, entonces abrir una posición.

[Vladimir Karputov]

Alexey Belyakov:

Buenas tardes, queridos programadores. Pregunta sobre MQL5

¿Cómo implementar el control de posición en MetaTrader 5? Quiero tener sólo una posición abierta en una barra, es decir, la posición debe cerrarse sin importar en qué barra, pero la apertura debe ser en una sola barra.

Este código se ignora por completo. ¿Cuál es el error?

Error: Has confundido las moscas y las chuletas - has confundido las ORDENES REMOTO y las POSICIONES.

Para evitar confusiones, lea la referencia:Principios generales

La forma más sencilla es recordar la hora de apertura de la barra actual cuando se abre una posición. Entonces, si quiere abrir una nueva posición, comprueba la hora guardada y la hora de apertura de la barra actual.

El almacenamiento de la hora de apertura de una posición es conveniente enOnTradeTransaction:

//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),InpTimeFrame,0);
            int size_need_position=ArraySize(SPosition);
            if(size_need_position>0)
              {
               for(int i=0; i<size_need_position; i++)
                 {
                  if(SPosition[i].waiting_transaction)
                     if(SPosition[i].waiting_order_ticket==m_deal.Order())
                       {
                        Print(__FUNCTION__," Transaction confirmed");
                        SPosition[i].transaction_confirmed=true;
                        break;
                       }
                 }
              }
           }
        }
     }
  }

y comprueba la hora a la que se recibe la señal:

//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);

Ejemplo tomado del códigoOHLC Check 2

[Alexey Belyakov]

Es un poco engañoso .... de alguna manera. No hay problema en la primera etapa "recuerda la hora de apertura del bar actual"

Ahí lo tienes:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции

Pero aquí " se comprueba la hora guardada y la hora de apertura del bar actual". problema.

He hecho más o menos lo mismo. Mira esto:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция (или была открыта, неважно, любое торговое действие)
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции
int hd=+iBarShift(Symbol(),_Period,Cu)+1;    // Здесь в переменную - бар на котором произошло открытие позиции 
if (hd>=1)                                //Здесь проверяем - если этих баров, больше чем один, то.......   
{
return; //....то зацикливанием программу, НО проблема только в return
}
}

Todo lo que necesito hacer aquí es un bucle de un paseo como "return(-1)" Pero no puedo asignar una expresión al retorno debido al vacío. ¿Cómo puedo evitar esto? ¿Cómo hacer un bucle sin retorno?

[Alexey Belyakov]

datetime PR=iTime(NULL,_Period,0);  // проверяю время открытие бара
if (PositionsTotal()==1)  
{
datetime TK=iTime(NULL,_Period,0);  // время открытия бара при открытой позиции                        
if (PR==TK)                         // сравниваю
{
return(true);  // НЕ катит true - ошибка 
}
}

Eso tampoco funcionó.

[Vladimir Karputov]

Alexey Belyakov:

Es un poco engañoso .... de alguna manera. No hay problema en la primera etapa "recuerda la hora de apertura del bar actual"

Ahí lo tienes:

Pero aquí " se concilia la hora guardada y la hora de apertura del bar actual". problema.

He hecho más o menos lo mismo. Mira esto:

Todo lo que necesito hacer aquí es un bucle de un paseo como "return(-1)" Pero no puedo asignar una expresión al retorno debido al vacío. ¿Cómo puedo evitar esto? ¿Cómo hacer un bucle sin retorno?

El tratamiento para los programas de bucle es cortarles los brazos alrededor del cuello. Para no tener que volver a hacerlo en el futuro.

Esto es lo que necesitas - todo el cuerpo del programa, sólo tienes que formalizar la recepción de la señal:

//+------------------------------------------------------------------+
//|                              Example One position on one bar.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\DealInfo.mqh>
//---
CPositionInfo  m_position;                   // object of CPositionInfo class
CTrade         m_trade;                      // object of CTrade class
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
CDealInfo      m_deal;                       // object of CDealInfo class
//--- input parameters
input ulong    InpMagic             = 200;      // Magic number
//---
datetime m_prev_bars                = 0;        // "0" -> D'1970.01.01 00:00';
datetime m_last_deal_in             = 0;        // "0" -> D'1970.01.01 00:00';
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
   RefreshRates();
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- we work only at the time of the birth of new bar
   datetime time_0=iTime(m_symbol.Name(),Period(),0);
   if(time_0==m_prev_bars)
      return;
   m_prev_bars=time_0;
   if(!RefreshRates())
     {
      m_prev_bars=0;
      return;
     }
//--- search for trading signals
   if(!SearchTradingSignals())
     {
      m_prev_bars=0;
      return;
     }
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),Period(),0);
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);
//--- signal
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }
//+------------------------------------------------------------------+

La variable'm_prev_bars' almacena la hora de apertura de la barra actual y la variable'm_last_deal_in' almacena la hora de apertura de la barra en la que se abrió la posición.

Estas dos variables se comparan en el bloque de obtención de señales'SearchTradingSignals'.