Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 775

[Aleksey Vyazmikin]

Vladimir Karputov:

Написано же: " ... Шаг 1 ..."

Над шагом 2 - теперь думайте сами, а именно, каким образом несколько потоков БЕЗ КОНФЛИКТОВ смогут писать в ОДИН файл.

Да в том то и дело, что не смогут...

Я так понимаю, что сетевые агенты не могут работать с библиотеками dll?

Как то можно узнать номер прохода тестера? Что б потом склеивать файлы...

[fxsaber]

Aleksey Vyazmikin:

Как агентов научить писать в один файл? Сейчас каждый создает свой файл в своей папке, что не хорошо.

Для записи данных Агентов в один файл нужно использовать Фрейм-режим.

// Пример записи данных Агентов (включая Облачные) в один файл
input int Range = 0;

void OnTick()
{
// ....
}

// Файл открываем только в режимах одиночночного прогона или Фрейма.
const int handle = ((MQLInfoInteger(MQL_TESTER) && !MQLInfoInteger(MQL_OPTIMIZATION)) || MQLInfoInteger(MQL_FRAME_MODE)) ?
                   FileOpen(__FILE__, FILE_WRITE | FILE_TXT) : INVALID_HANDLE;

// Подготовка данных
void GetData( string &Str, MqlTick &Ticks[], double &Balance )
{
  Str = "Hello World!";
  
  CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, 0, 2); // Последние два тика (пример)
  
  Balance = AccountInfoDouble(ACCOUNT_BALANCE);
}

// Запись данных
void SaveData( const string &Str, const MqlTick &Ticks[], const double Balance )
{
  FileWrite(handle, Str);
  
  for (int i = 0; i < ArraySize(Ticks); i++)
    FileWrite(handle, Ticks[i].bid);
    
  FileWrite(handle, Balance);
}

void OnTesterDeinit()
{
  if (handle != INVALID_HANDLE)  
    FileClose(handle);
    
  ChartClose();
}

#include <TypeToBytes.mqh> // https://www.mql5.com/ru/code/16280

double OnTester()
{
  string Str;
  MqlTick Ticks[];
  double Balance;
  
  GetData(Str, Ticks, Balance); // Подготовка данных для записи

  if (MQLInfoInteger(MQL_OPTIMIZATION)) // Оптимизация
  {
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
    
    Container[0] = Str;
    Container[1] = Ticks;
    Container[2] = Balance;
  
    FrameAdd(NULL, 0, 0, Container.Data); // Отправили данные из Агента на Терминал
  }
  else // Одиночный прогон
  {    
    if (handle != INVALID_HANDLE)
      SaveData(Str, Ticks, Balance); // Данные будут записаны в MQL5\Files-папку Агента (не Терминала)
    
    FileClose(handle);
  }
  
  return(0);
}

void OnTesterPass()
{    
  if (handle != INVALID_HANDLE)
  {
    ulong Pass;
    string Name;
    long ID;
    double Value;
  
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
  
    while (FrameNext(Pass, Name, ID, Value, Container.Data))
    {
      string Str;
      MqlTick Ticks[];
      double Balance;
      
      // Получили данные от Агента
      Container[0].Get(Str);
      Container[1].Get(Ticks);
      Container[2].Get(Balance);
      
//      FileWrite(handle, Pass);     // Если хочется записать номер прохода
      SaveData(Str, Ticks, Balance); // Данные будут записаны в MQL5\Files-папку Терминала (не Агента)
    }
  }
}

[Aleksey Vyazmikin]

fxsaber:

Для записи данных Агентов в один файл нужно использовать Фрейм-режим.

Спасибо! Надо изучить.

А что есть "Фрейм-режим"?

[fxsaber]

Aleksey Vyazmikin:

А что есть "Фрейм-режим"?

https://www.mql5.com/ru/docs/optimization_frames

[Aleksey Vyazmikin]

fxsaber:

https://www.mql5.com/ru/docs/optimization_frames

Спасибо - что за режим понял.

Однако не понял, можно ли пачкой передать 100 показателей в этом фрейме? Почему в одном фрейме - так-как каждый фрейм считается отдельным проходом, как я понял из описания, или я не так понял? 

И, где описание формата файла *.mqd можно найти?

[fxsaber]

Aleksey Vyazmikin:

Однако не понял, можно ли пачкой передать 100 показателей в этом фрейме?

Посмотрите пример выше. Там передаются произвольные данные в любом количестве.

[Aleksey Vyazmikin]

fxsaber:

Посмотрите пример выше. Там передаются произвольные данные в любом количестве.

Много вопросов, позвольте мне Вам их позадавать?

Вот функция в коде

// Подготовка данных
void GetData( string &Str, MqlTick &Ticks[], double &Balance )
{
  Str = "Hello World!";
  
  CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, 0, 2); // Последние два тика (пример)
  
  Balance = AccountInfoDouble(ACCOUNT_BALANCE);
}

Смысл понятен - собираем данные, которые будем потом записывать.

Я не совсем понимаю, зачем в скобках объявляем переменные, и что значит знак "&" перед переменной?

[Artyom Trishkin]

Aleksey Vyazmikin:

Много вопросов, позвольте мне Вам их позадавать?

Вот функция в коде

Смысл понятен - собираем данные, которые будем потом записывать.

Я не совсем понимаю, зачем в скобках объявляем переменные, и что значит знак "&" перед переменной?

Это азы. Читайте в справке о формальных параметрах функции и передачу параметров по ссылке.

[Alexey Viktorov]

Aleksey Vyazmikin:

Много вопросов, позвольте мне Вам их позадавать?

Вот функция в коде

Смысл понятен - собираем данные, которые будем потом записывать.

Я не совсем понимаю, зачем в скобках объявляем переменные, и что значит знак "&" перед переменной?

Из документации

Существует возможность передавать по ссылке и параметры простых типов. В этом случае модификация таких параметров внутри вызываемой функции отразится на соответствующих переменных, переданных по ссылке. Для того чтобы указать, что параметр передается по ссылке, после типа данных необходимо поставить модификатор &.

Пример:

void func(int& x, double& y, double & z[])
  {
   double calculated_tp;
   ...
   for(int i=0; i<OrdersTotal(); i++)
     {
      if(i==ArraySize(z))       break;
      if(OrderSelect(i)==false) break;
      z[i]=OrderOpenPrice();
     }
   x=i;
   y=calculated_tp;

[Aleksey Vyazmikin]

Artyom Trishkin:
Это азы. Читайте в справке о формальных параметрах функции и передачу параметров по ссылке.

Может и азы, не спорю, просто не могу въехать в код, где там начало, где конец... поэтому и вопросы. Хорошо это ссылка(?), но на что?

Где первоначально возникла переменная "Str" тут?

    while (FrameNext(Pass, Name, ID, Value, Container.Data))
    {
      string Str;
      MqlTick Ticks[];
      double Balance;
      
      // Получили данные от Агента
      Container[0].Get(Str);
      Container[1].Get(Ticks);
      Container[2].Get(Balance);
      
//      FileWrite(handle, Pass);     // Если хочется записать номер прохода
      SaveData(Str, Ticks, Balance); // Данные будут записаны в MQL5\Files-папку Терминала (не Агента)
    }