Скрипты: Pending orders DOWN - страница 3

Новый комментарий
 
Михаил Рымарь:

 Здравствуйте,скрипт действительно замечательный и в единственном числе на MQ5,но хотелось бы иметь в своем арсенале такой же,но с лотом,ну скажем 1 или 0.5.

Спасибо за труды и с наступающими праздниками.

В данной серии изначально была идея использовать именно минимальный лот. Поэтому пока только так.

 
Здравствуйте, сэр. Не могли бы вы мне немного помочь. Как я могу настроить код на желаемый размер лота. Я пробовал несколько раз, меняя inplots: 5, но все равно значение лота при исполнении становится 0.01, я новичок, надеюсь, что есть способ изменить это. Спасибо
//+------------------------------------------------------------------+
//|Отложенные ордера ВНИЗ.mq5 |
//|Copyright © 2017, Владимир Карпутов |
//| http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2017, Владимир Карпутов"
#property link      "http://wmua.ru/slesar/"
#property version   "1.002"
#property description "The script sets the pending orders down from the price"
#property script_show_inputs
//---
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>  
CTrade         m_trade;                      // торговый объект
CSymbolInfo    m_symbol;                     // объект информации о символе
//+------------------------------------------------------------------+
//| Перечисление отложенных ордеров DOWN|
//+------------------------------------------------------------------+
enum ENUM_PENDING_ORDERS_DOWN
  {
   buy_limit         =0,   // Предел покупки
   sell_stop         =3    // Стоп продажи
  };
//--- входные параметры
input ushort                     InpDownGep        = 10;             // Гэп для отложенных ордеров ВНИЗ от текущей цены (в пунктах)
input ushort                     InpDownStep       = 3;             // Шаг между ордерами ВНИЗ (в пунктах)
input ENUM_PENDING_ORDERS_DOWN   InpDownOrders     = buy_limit;      // Тип отложенных ордеров DOWN
input uchar                      InpDownQuantity   = 33;              // Количество DOWN
input double                     InpLots           = 5;            // Lots
input ushort                     InpStopLoss       = 100;             // Стоп-лосс (в пунктах)
input ushort                     InpTakeProfit     = 100;             // Тейк-профит (в пунктах)
//---
ulong                            m_slippage=1;                      // скольжение
double                           m_adjusted_point;                   // значение баллов скорректировано на 3 или 5 баллов
double                           ExtDownGep=0.0;
double                           ExtDownStep=0.0;
double                           ExtStopLoss=0.0;
double                           ExtTakeProfit=0.0;
//+------------------------------------------------------------------+
//| Функция запуска программы сценария|
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   if(InpLots<=0.0)
     {
      Print("The \"Lots\" can't be smaller or equal to zero");
      return;
     }
//---
   if(!m_symbol.Name(Symbol())) // задает имя символа
      return;
   if(!RefreshRates())
      return;

   string err_text="";
   if(!CheckVolumeValue(InpLots,err_text))
     {
      Print(err_text);
      return;
     }
//---
   if(IsFillingTypeAllowed(SYMBOL_FILLING_FOK))
      m_trade.SetTypeFilling(ORDER_FILLING_FOK);
   else if(IsFillingTypeAllowed(SYMBOL_FILLING_IOC))
      m_trade.SetTypeFilling(ORDER_FILLING_IOC);
   else
      m_trade.SetTypeFilling(ORDER_FILLING_RETURN);
//---
   m_trade.SetDeviationInPoints(m_slippage);
   m_trade.SetAsyncMode(true);
//--- настройка на 3 или 5 цифр
   int digits_adjust=1;
   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)
      digits_adjust=10;
   m_adjusted_point=m_symbol.Point()*digits_adjust;

   ExtDownGep     = m_adjusted_point * InpDownGep;
   ExtDownStep    = m_adjusted_point * InpDownStep;
   ExtStopLoss    = m_adjusted_point * InpStopLoss;
   ExtTakeProfit  = m_adjusted_point * InpTakeProfit;
//--- начать работу
   double start_price_ask=m_symbol.Ask()-ExtDownGep;
   double start_price_bid=m_symbol.Bid()-ExtDownGep;
//--- отложенные ордера DOWN
   for(int i=0;i<InpDownQuantity;i++)
     {
      double price_ask     = start_price_ask-i*ExtDownStep;
      double price_bid     = start_price_bid-i*ExtDownStep;
      if(InpDownOrders==buy_limit)
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_ask - ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_ask + ExtTakeProfit;
         m_trade.BuyLimit(m_symbol.LotsMax(),m_symbol.NormalizePrice(price_ask),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
      else
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_bid + ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_bid - ExtTakeProfit;
         m_trade.SellStop(m_symbol.LotsMax(),m_symbol.NormalizePrice(price_bid),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
     }
  }
//+------------------------------------------------------------------+
//| Обновляет данные о котировках символов.|
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- частота обновления
   if(!m_symbol.RefreshRates())
      return(false);
//--- защита от возврата значения "ноль".
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
      return(false);
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Проверьте правильность объема заказа |
//+------------------------------------------------------------------+
bool CheckVolumeValue(double volume,string &error_description)
  {
//--- минимально допустимый объем для торговых операций
   double min_volume=m_symbol.LotsMin();
   if(volume<min_volume)
     {
      error_description=StringFormat("Volume is less than the minimal allowed SYMBOL_VOLUME_MIN=%.2f",min_volume);
      return(false);
     }

//--- Максимально допустимый объем торговых операций
   double max_volume=m_symbol.LotsMax();
   if(volume>max_volume)
     {
      error_description=StringFormat("Volume is greater than the maximal allowed SYMBOL_VOLUME_MAX=%.2f",max_volume);
      return(false);
     }

//--- получите минимальный шаг изменения объема
   double volume_step=m_symbol.LotsStep();

   int ratio=(int)MathRound(volume/volume_step);
   if(MathAbs(ratio*volume_step-volume)>0.0000001)
     {
      error_description=StringFormat("Volume is not a multiple of the minimal step SYMBOL_VOLUME_STEP=%.2f, the closest correct volume is %.2f",
                                     volume_step,ratio*volume_step);
      return(false);
     }
   error_description="Correct volume value";
   return(true);
  }
//+------------------------------------------------------------------+ 
//| Проверяет, разрешен ли указанный режим заполнения | 
//+------------------------------------------------------------------+ 
bool IsFillingTypeAllowed(int fill_type)
  {
//--- Получите значение свойства, описывающего разрешенные режимы заполнения 
   int filling=m_symbol.TradeFillFlags();
//--- Возвращает true, если режим fill_type разрешен. 
   return((filling & fill_type)==fill_type);
  }
//+------------------------------------------------------------------+

 
Mjame116 :
Здравствуйте, сэр. Не могли бы вы мне немного помочь. Как я могу настроить код на желаемый размер лота. Я пробовал несколько раз, меняя inplots: 5, но все равно значение лота при выполнении становится 0.01, я новичок, надеюсь, что есть способ изменить это. Спасибо

Необходимо вместо минимального лота поставить входной параметр Lots

//--- отложенные ордера DOWN
   for(int i=0;i<InpDownQuantity;i++)
     {
      double price_ask     = start_price_ask-i*ExtDownStep;
      double price_bid     = start_price_bid-i*ExtDownStep;
      if(InpDownOrders==buy_limit)
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_ask - ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_ask + ExtTakeProfit;
         m_trade.BuyLimit(m_symbol.LotsMin(),m_symbol.NormalizePrice(price_ask),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
      else
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_bid + ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_bid - ExtTakeProfit;
         m_trade.SellStop(m_symbol.LotsMin(),m_symbol.NormalizePrice(price_bid),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
     }
  }

нужно сделать так:

//--- отложенные ордера DOWN
   for(int i=0;i<InpDownQuantity;i++)
     {
      double price_ask     = start_price_ask-i*ExtDownStep;
      double price_bid     = start_price_bid-i*ExtDownStep;
      if(InpDownOrders==buy_limit)
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_ask - ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_ask + ExtTakeProfit;
         m_trade.BuyLimit(InpLots,m_symbol.NormalizePrice(price_ask),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
      else
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_bid + ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_bid - ExtTakeProfit;
         m_trade.SellStop(InpLots,m_symbol.NormalizePrice(price_bid),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
     }
  }
 
Vladimir Karputov:

Необходимо вместо минимального лота поставить входной параметр Lots

необходимо:

Большое спасибо, сэр, я очень ценю это
 

Здравствуйте, скрипт отличный и прекрасно работает.

Пользуюсь таким же для выставления сети вверх, и хотелось бы попросить вас: можете ли совместить их в один? Имею ввиду скрипт, который выставлял бы сети ордеров и вверх, и вниз одновременно, с одинаковыми параметрами для сети в лонг, и шорт. 

 
mason_one:

Здравствуйте, скрипт отличный и прекрасно работает.

Пользуюсь таким же для выставления сети вверх, и хотелось бы попросить вас: можете ли совместить их в один? Имею ввиду скрипт, который выставлял бы сети ордеров и вверх, и вниз одновременно, с одинаковыми параметрами для сети в лонг, и шорт. 

Спасибо за проявленный интерес. Публикую скрипт (не советник) который выставляет сетку отложенных ордеров и вверх и вниз - Pending orders UP DOWN.

 
Здравствуйте Владимир, очень интересный ваш скрипт. работает очень хорошо, но я надеюсь, что вы можете помочь мне, сказав мне, как изменить lotaje от 0.01 до 0.03. Я остаюсь внимательным и заранее большое спасибо мой друг.
 
Carlos Devia :
Здравствуйте Владимир, очень интересный ваш скрипт. работает очень хорошо, но я надеюсь, что вы можете помочь мне, сказав мне, как изменить lotaje от 0.01 до 0.03. Остаюсь внимательным и заранее очень благодарен тебе мой друг.

В этом коде вместо"m_symbol.LotsMin()" поставьте"InpLots": 

//--- отложенные ордера DOWN
   for(int i=0;i<InpDownQuantity;i++)
     {
      double price_ask     = start_price_ask-i*ExtDownStep;
      double price_bid     = start_price_bid-i*ExtDownStep;
      if(InpDownOrders==buy_limit)
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_ask - ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_ask + ExtTakeProfit;
         m_trade.BuyLimit(m_symbol.LotsMin(),m_symbol.NormalizePrice(price_ask),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
      else
        {
         double sl         = (ExtStopLoss==0.0)   ? 0.0 : price_bid + ExtStopLoss;
         double tp         = (ExtTakeProfit==0.0) ? 0.0 : price_bid - ExtTakeProfit;
         m_trade.SellStop(m_symbol.LotsMin(),m_symbol.NormalizePrice(price_bid),m_symbol.Name(),
                          m_symbol.NormalizePrice(sl),
                          m_symbol.NormalizePrice(tp));
        }
     }
 

Дорогой Владимир, в этот момент вы для меня как бог. Вы не представляете, как долго я искал это, и я очень ценю, что вы нашли время ответить мне. Я человек, увлеченный трейдингом, и то немногое, что я знаю, я узнал от таких людей, как вы.

Я хочу задать вам последний вопрос, если это возможно. Я запрограммировал горячую клавишу на моей клавиатуре

Я запрограммировал горячую клавишу на клавиатуре, чтобы активировать мой ордер sell stop, но перед его активацией открывается окно, которое я хотел бы не открывать, а просто немедленно исполнить мой ордер.

Прилагаю картинку открывающегося окна.

Буду признателен за помощь, Владимир, чтобы это окно не появлялось, потому что когда оно открывается, мне приходится"принимать" параметры, и я теряю время на этот процесс.

Файлы:
pending_orders.png  29 kb
 
Carlos Devia :

Дорогой Владимир, в этот момент вы для меня как бог. Вы не представляете, как долго я искал это, и я очень ценю, что вы нашли время ответить мне. Я человек, увлеченный трейдингом, и то немногое, что я знаю, я узнал от таких людей, как вы.

Я хочу задать вам последний вопрос, если это возможно. Я запрограммировал горячую клавишу на своей клавиатуре.

Я запрограммировал горячую клавишу на клавиатуре, чтобы активировать мой стоп-приказ на продажу, но перед его активацией открывается окно, которое я хотел бы не открывать, а просто немедленно исполнить мой приказ.

Прилагаю изображение открывающегося окна.

Буду признателен за помощь, Владимир, чтобы это окно не появлялось, потому что когда оно открывается, мне приходится "принимать" параметры, и я теряю время на этот процесс.

Горячая клавиша - не вариант: при запуске все равно будут видны вводимые параметры.

Я бы предложил другой способ:

  • написать советник - панель, в панели у всего есть кнопка "Старт".
  • при запуске советника, после установки входных параметров
  • после запуска на график вешается небольшая панель: при нажатии кнопки "Старт" на этой панели выставляются отложенные ордера (все параметры берутся из входных параметров.

Пример панели:



Вы можете поискать такую панель на Маркете или заказать ее в сервисе Freelance.

123456
Новый комментарий