Индикаторы: MACD Divergence

Stephen Paul 2020.05.05 08:39 #41

Alain Verleyen:

Вы упустили суть. Пост, на который вы ссылаетесь, был о том, КАК получить сигнал от советника, вы, очевидно, не можете получить его, просто получив значения последних 2 свечей, вам нужен третий.

Невозможно иметь ранний сигнал, потому что для обнаружения дивергенции вам нужен пик/корыто, а для этого вам нужна дополнительная свеча, которая закрывается. Поэтому, когда свеча 0 только что открылась, это означает, что свеча 1 уже закрыта, и это позволяет подтвердить пик/корыто на свече 2. Если кто-то хочет модифицировать индикатор, чтобы использовать неподтвержденные пики/корыта для получения раннего сигнала, то это можно сделать, но я не буду помогать в этом, потому что это плохая идея, так как вы получите много плохих сигналов.

Что можно было бы сделать, так это рисовать сигнал на свече 1 или даже на свече 0, но это ничего не изменит, и я решил рисовать сигнал на свече, которая действительно показывает пик/корыто.

Я изменил код, и вы правы. Вы получаете ложные движения перед фактической дивергенцией. Спасибо за ваше время на это.

bk7 2021.01.16 16:31 #42

Alain Verleyen:

Вы упустили суть. Пост, на который вы ссылаетесь, был о том, КАК получить сигнал от советника, вы, очевидно, не можете получить его, просто получив значения последних 2 свечей, вам нужен третий.

Невозможно иметь ранний сигнал, потому что для обнаружения дивергенции вам нужен пик/корыто, а для этого вам нужна дополнительная свеча, которая закрывается. Поэтому, когда свеча 0 только что открылась, это означает, что свеча 1 закрыта, и это позволяет подтвердить пик/корыто на свече 2. Если кто-то хочет модифицировать индикатор, чтобы использовать неподтвержденные пики/корыта для получения раннего сигнала, то это можно сделать, но я не буду помогать в этом, потому что это плохая идея, так как вы получите много плохих сигналов.

Что можно было бы сделать, так это рисовать сигнал на свече 1 или даже на свече 0, но это ничего не изменит, и я решил рисовать сигнал на свече, которая действительно показывает пик/корыто.

Возможно, вы также упустили один момент.

В случае с графиками ренко текущий бар (в основном) уже закрыт, поэтому вам нужно на одну свечу меньше. Или я что-то упускаю?

Hristo 2021.04.06 23:07 #43

Привет, Алена, очень хороший индикатор, он хорошо работает даже без настройки параметров. Хорошо, что в нем есть оповещения, но мне не хватает одной вещи - возможности отправлять push-уведомления на телефон. То же сообщение, которое появляется на всплывающем оповещении, чтобы оно отправлялось на мой телефон. Можете ли вы добавить эту функцию? Это было бы очень любезно с вашей стороны.

Элитные показатели :) Мультитаймфреймовые индикаторы Электронная почта

Zeke Yaeger 2021.04.12 05:14 #44

Спасибо, Ален, это отличный индикатор.

Vladimir Karputov 2021.09.12 13:50 #45

Форум о трейдинге, автоматизированных торговых системах и тестировании торговых стратегий

macd divegence

ENEZA PETER MKIRAMWENI, 2021.09.12 12:26

помогите пожалуйста с этим индикатором он выводит алерт после трех баров я хочу выводить алерт сразу после 1 бара

//+------------------------------------------------------------------+
//|MACD_Divergence.mq5 |
//|Ален Верлейен |
//| http://www.alamga.be |
//+------------------------------------------------------------------+
#property copyright     "Alain Verleyen (mql5) - Original author FX5 (mql4)"
#property link          "http://codebase.mql4.com/1115"
#property version       "1.01"
#property description   "The original indicator was totally rewrite to improve performance and"
#property description   "to correct a little bug. Also it's more funny that simply converting it."

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   4

//--- Участок 1: Бычий 
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrGreen
#property indicator_label1  "Bullish divergence"
//--- Участок 2: Медвежий
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrRed
#property indicator_label2  "Bearish divergence"
//--- Участок 3: MACD Main
#property indicator_type3   DRAW_LINE
#property indicator_style3  STYLE_SOLID
#property indicator_width3   2
#property indicator_color3  clrMagenta
#property indicator_label3  "Main"
//--- Участок 4: Сигнал MACD
#property indicator_type4   DRAW_LINE
#property indicator_style4  STYLE_SOLID
#property indicator_width4   1
#property indicator_color4  clrNONE
#property indicator_label4  "Signal"
//--- входные параметры
input string s1="-----------------------------------------------";      // ----------- Настройки MACD ----------------------
input int    fastEMA                 = 12;
input int    slowEMA                 = 26;
input int    signalSMA               = 9;
input string s2="-----------------------------------------------";      // ----------- Настройки индикаторов -----------------
input bool   drawIndicatorTrendLines = true;
input bool   drawPriceTrendLines     = true;
input bool   displayAlert            = true;
//--- константы
#define  OBJECT_PREFIX       "MACD_DivergenceLine"
#define  ARROWS_DISPLACEMENT 0.0001
//--- буферы
double bullishDivergence[];
double bearishDivergence[];
double macdBuffer[];
double signalBuffer[];
//--- ручки
int    macdHandle=INVALID_HANDLE;
//--- глобальные переменные
static datetime lastAlertTime;
//+------------------------------------------------------------------+
//| Пользовательская функция инициализации индикатора |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- ручка индикатора 
   macdHandle=iMACD(NULL,0,fastEMA,slowEMA,signalSMA,PRICE_CLOSE);
   if(macdHandle==INVALID_HANDLE)
     {
      Print("The iMACD handle is not created: Error ",GetLastError());
      return(INIT_FAILED);
     }
//--- отображение индикаторных буферов
   SetIndexBuffer(0,bullishDivergence);
   SetIndexBuffer(1,bearishDivergence);
   SetIndexBuffer(2,macdBuffer);
   SetIndexBuffer(3,signalBuffer);
//--- код стрелки см. http://www. mql5.com/en/docs/constants/objectconstants/wingdings
   PlotIndexSetInteger(0,PLOT_ARROW,233);
   PlotIndexSetInteger(1,PLOT_ARROW,234);
//--- свойства индикатора
   string indicatorName=StringFormat("MACD_Divergence(%i, %i, %i)",fastEMA,slowEMA,signalSMA);
   PlotIndexSetInteger(3,PLOT_DRAW_BEGIN,signalSMA);
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+2);
   IndicatorSetString(INDICATOR_SHORTNAME,indicatorName);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Очистка графика|
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   ObjectDeleteByName("MACD_DivergenceLine");
  }
//+------------------------------------------------------------------+
//| Пользовательская функция итерации индикатора|
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- индикатор обновляется только на новой свече, за исключением полного перерисовывания
   static datetime lastCandleTime=0;
   if(lastCandleTime==time[rates_total-1])
      return(rates_total);
   else
      lastCandleTime=time[rates_total-1];
//--- был изменен первый расчет или количество баров
   int start;
   if(prev_calculated<=0)
     {
      start=slowEMA;
      ArrayInitialize(bullishDivergence,EMPTY_VALUE);   // буферы расхождений должны быть инициализированы
      ArrayInitialize(bearishDivergence,EMPTY_VALUE);
     }
   else
     {
      start=prev_calculated-2;
      bullishDivergence[rates_total-1]=EMPTY_VALUE;
      bearishDivergence[rates_total-1]=EMPTY_VALUE;
     }
//--- количество данных (буферов macd) для копирования 
   int toCopy=rates_total-prev_calculated+(prev_calculated<=0 ? 0 : 1);
//--- не все данные могут быть рассчитаны
   int calculated=BarsCalculated(macdHandle);
   if(calculated<rates_total)
     {
      Print("Not all data of macdHandle is calculated (",calculated,"bars ). Error",GetLastError());
      return(0);
     }
//--- получить основной буфер MACD
   if(IsStopped()) return(0); //Проверка наличия флага остановки
   if(CopyBuffer(macdHandle,MAIN_LINE,0,toCopy,macdBuffer)<=0)
     {
      Print("Getting MACD Main is failed! Error : ",GetLastError());
      return(0);
     }
//--- получить сигнальный буфер MACD
   if(IsStopped()) return(0); //Проверка наличия флага остановки
   if(CopyBuffer(macdHandle,SIGNAL_LINE,0,toCopy,signalBuffer)<=0)
     {
      Print("Getting MACD Signal is failed! Error : ",GetLastError());
      return(0);
     }
//--- основной цикл вычислений
   for(int shift=start; shift<rates_total-2; shift++)
     {
      int currentExtremum,lastExtremum;
      bool isBullishDivergence,isBearishDivergence;
      string divergenceMsg;
      ENUM_LINE_STYLE divergenceStyle=0;

      //--- Поймать бычье расхождение
      isBullishDivergence=false;

      if(macdBuffer[shift]<=macdBuffer[shift-1] && 
         macdBuffer[shift]<macdBuffer[shift-2] && 
         macdBuffer[shift]<macdBuffer[shift+1])
         //--- если текущий macd main является дном (ниже, чем 2 предыдущих и 1 следующий)
        {
         currentExtremum=shift;
         lastExtremum=GetIndicatorLastTrough(shift);
         //--- 
         if(macdBuffer[currentExtremum]>macdBuffer[lastExtremum] && 
            low[currentExtremum]<low[lastExtremum])
           {
            isBullishDivergence=true;
            divergenceMsg="Classical bullish divergence on: ";
            divergenceStyle=STYLE_SOLID;
           }
         //--- 
         if(macdBuffer[currentExtremum]<macdBuffer[lastExtremum] && 
            low[currentExtremum]>low[lastExtremum])
           {
            isBullishDivergence=true;
            divergenceMsg="Reverse bullish divergence on: ";
            divergenceStyle=STYLE_DOT;
           }
         //--- Обнаружена бычья дивергенция
         if(isBullishDivergence)
           {
            bullishDivergence[currentExtremum]=macdBuffer[currentExtremum]-ARROWS_DISPLACEMENT;
            //---
            if(drawPriceTrendLines==true)
               DrawTrendLine(TRENDLINE_MAIN,time[currentExtremum],time[lastExtremum],low[currentExtremum],low[lastExtremum],Green,divergenceStyle);
            //---
            if(drawIndicatorTrendLines==true)
               DrawTrendLine(TRENDLINE_INDICATOR,time[currentExtremum],time[lastExtremum],macdBuffer[currentExtremum],macdBuffer[lastExtremum],Green,divergenceStyle);
            //---
            if(displayAlert==true && shift>=rates_total-3 && time[currentExtremum]!=lastAlertTime)
               DisplayAlert(divergenceMsg,time[currentExtremum]);
           }
        }
      //--- Поймать медвежье расхождение
      isBearishDivergence=false;

      if(macdBuffer[shift]>=macdBuffer[shift-1] && 
         macdBuffer[shift]>macdBuffer[shift-2] && 
         macdBuffer[shift]>macdBuffer[shift+1])
         //--- если текущий macd main является вершиной (выше, чем 2 предыдущих и 1 следующий)
        {
         currentExtremum=shift;
         lastExtremum=GetIndicatorLastPeak(shift);
         //--- 
         if(macdBuffer[currentExtremum]<macdBuffer[lastExtremum] && 
            high[currentExtremum]>high[lastExtremum])
           {
            isBearishDivergence=true;
            divergenceMsg="Classical bearish divergence on: ";
            divergenceStyle=STYLE_SOLID;
           }
         if(macdBuffer[currentExtremum]>macdBuffer[lastExtremum] && 
            high[currentExtremum]<high[lastExtremum])
           {
            isBearishDivergence=true;
            divergenceMsg="Reverse bearish divergence on: ";
            divergenceStyle=STYLE_DOT;
           }
         //--- Обнаружена медвежья дивергенция
         if(isBearishDivergence)
           {
            bearishDivergence[currentExtremum]=macdBuffer[currentExtremum]+ARROWS_DISPLACEMENT;
            //---
            if(drawPriceTrendLines==true)
               DrawTrendLine(TRENDLINE_MAIN,time[currentExtremum],time[lastExtremum],high[currentExtremum],high[lastExtremum],Red,STYLE_SOLID);
            //---
            if(drawIndicatorTrendLines==true)
               DrawTrendLine(TRENDLINE_INDICATOR,time[currentExtremum],time[lastExtremum],macdBuffer[currentExtremum],macdBuffer[lastExtremum],Red,STYLE_SOLID);
            //---
            if(displayAlert==true && shift>=rates_total-3 && time[currentExtremum]!=lastAlertTime)
               DisplayAlert(divergenceMsg,time[currentExtremum]);
           }
        }
     }
//--- возвращаем значение prev_calculated для следующего вызова
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Поиск последней впадины|
//+------------------------------------------------------------------+
int GetIndicatorLastTrough(int shift)
  {
   for(int i=shift-5; i>=2; i--)
     {
      if(signalBuffer[i] <= signalBuffer[i-1] && signalBuffer[i] <= signalBuffer[i-2] &&
         signalBuffer[i] <= signalBuffer[i+1] && signalBuffer[i] <= signalBuffer[i+2])
        {
         for(int j=i; j>=2; j--)
           {
            if(macdBuffer[j] <= macdBuffer[j-1] && macdBuffer[j] < macdBuffer[j-2] &&
               macdBuffer[j] <= macdBuffer[j+1] && macdBuffer[j] < macdBuffer[j+2])
               return(j);
           }
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| Поиск последнего пика|
//+------------------------------------------------------------------+
int GetIndicatorLastPeak(int shift)
  {
   for(int i=shift-5; i>=2; i--)
     {
      if(signalBuffer[i] >= signalBuffer[i-1] && signalBuffer[i] >= signalBuffer[i-2] &&
         signalBuffer[i] >= signalBuffer[i+1] && signalBuffer[i] >= signalBuffer[i+2])
        {
         for(int j=i; j>=2; j--)
           {
            if(macdBuffer[j] >= macdBuffer[j-1] && macdBuffer[j] > macdBuffer[j-2] &&
               macdBuffer[j] >= macdBuffer[j+1] && macdBuffer[j] > macdBuffer[j+2])
               return(j);
           }
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| ENUM_TRENDLINE_TYPE используется в DrawTrendLine |
//+------------------------------------------------------------------+
enum ENUM_TRENDLINE_TYPE
  {
   TRENDLINE_MAIN,
   TRENDLINE_INDICATOR
  };
//+------------------------------------------------------------------+
//| Нарисуйте линию тренда на основном графике или на индикаторе |
//+------------------------------------------------------------------+
void DrawTrendLine(ENUM_TRENDLINE_TYPE window,datetime x1,datetime x2,double y1,double y2,color lineColor,ENUM_LINE_STYLE style)
  {
   string label=OBJECT_PREFIX+"#"+IntegerToString(window)+DoubleToString(x1,0);
   int subwindow=(window==TRENDLINE_MAIN) ? 0 : ChartWindowFind();
   ObjectDelete(0,label);
   ObjectCreate(0,label,OBJ_TREND,subwindow,x1,y1,x2,y2,0,0);
   ObjectSetInteger(0,label,OBJPROP_RAY,false);
   ObjectSetInteger(0,label,OBJPROP_COLOR,lineColor);
   ObjectSetInteger(0,label,OBJPROP_STYLE,style);
  }
//+------------------------------------------------------------------+
//| Выводим предупреждение при обнаружении дивергенции|
//+------------------------------------------------------------------+
void DisplayAlert(string message,const datetime alertTime)
  {
   lastAlertTime=alertTime;
   Alert(message,Symbol()," , ",EnumToString(Period())," minutes chart");
  }
//+------------------------------------------------------------------+
//| Удалите все объекты, нарисованные индикатором |
//+------------------------------------------------------------------+
void ObjectDeleteByName(string prefix)
  {
   int total=ObjectsTotal(0),
   length=StringLen(prefix);

//--- Удаление всех объектов, используемых индикатором
   for(int i=total-1; i>=0; i--)
     {
      string objName=ObjectName(0,i);
      if(StringSubstr(objName,0,length)==prefix)
        {
         ObjectDelete(0,objName);
        }
     }
  }
//+------------------------------------------------------------------+

Индикаторы: Эргодический MACD-осциллятор Blau_Ergodic_MACD Индикаторы: XMACD_HTF Индикаторы: Digital_MACD

Alain Verleyen 2021.09.12 13:55 #46

Форум о трейдинге, автоматизированных торговых системах и тестировании торговых стратегий

Индикаторы: Дивергенция MACD

Alain Verleyen, 2013.11.05 19:14

Так дружелюбно.

Сигнал подается при закрытии свечи, 1 свеча в прошлом (2, если считать открытую свечу, а не 3). Это нормально и так должно работать. Дивергенция основана на исследовании экстремума (верх/низ). Если у вас есть способ определить экстремум на текущей свече, я предлагаю вам изучить программирование и предоставить нам, бесплатно, эту замечательную инновацию.

Спасибо за ваш вклад.

Что-то интересное Советники: AscTrend Expert Advisor [SOLVED] Индикаторы неправильно инстанцируются

lego9955 2021.12.14 01:18 #47

Привет, Ален. Очень хороший индикатор. Он делает правильные сигналы.

BTW в части "//--- Bearish divergence is found" должно было быть "divergenceStyle" вместо "STYLE_SOLID".

Индикатор полностью не перерисовывается. Для своей цели я решил сделать небольшую модификацию, чтобы сделать последний бар индикатора перерисовываемым, а также сигнал дивергенции.

Индикатор будет показывать сигнал дивергенции на предыдущем баре, обязательно перерисовываемый. Это будет полезно на быстрых таймфреймах, чтобы использовать сигнал непосредственно перед закрытием бара.

Я сделал изменения:

- удалил всю часть "//--- индикатор обновляется только на новой свече, кроме полного перерисовывания"

- "start=prev_calculated-2;" был заменен на "start=prev_calculated-1;"

- В части "//--- основной цикл вычислений" "for(int shift=start; shift<rates_total-2; shift++)" изменен на "for(int shift=start; shift<rates_total-1; shift++)".

Сигнал дивергенции теперь появляется на предыдущем баре, но замирает в момент появления и не следует за линией индикатора на этом баре.

Можете ли вы помочь мне решить эту проблему?

Помощь в кодировании Функция ICustom Гармоническая торговля

lego9955 2021.12.15 21:10 #48

Я изменил эту часть и решил проблему. Возможно, это можно было сделать лучше и проще, но это работает. Стрелки переместились на 1 бар вперед. Линии без стрелок - неподтвержденные сигналы.

//--- индикатор обновляется только на новой свече, за исключением полного перерисовывания
 // static datetime lastCandleTime=0;
 // if(lastCandleTime==time[rates_total-1])
 // return(rates_total);
 // else
 // lastCandleTime=time[rates_total-1];
//--- был изменен первый расчет или количество баров
   int start;
   if(prev_calculated<=0)
     {
      start=slowEMA;
      ArrayInitialize(bullishDivergence,EMPTY_VALUE);   // буферы расхождений должны быть инициализированы
      ArrayInitialize(bearishDivergence,EMPTY_VALUE);
     }
   else
     { 
      start=prev_calculated-1;
      bullishDivergence[rates_total-1]=EMPTY_VALUE;
      bearishDivergence[rates_total-1]=EMPTY_VALUE;
     }
//--- количество данных (буферов macd) для копирования 
   int toCopy=rates_total-prev_calculated+(prev_calculated<=0 ? 0 : 1);
//--- не все данные могут быть рассчитаны
   int calculated=BarsCalculated(macdHandle);
   if(calculated<rates_total)
     {
      Print("Not all data of macdHandle is calculated (",calculated,"bars ). Error",GetLastError());
      return(0);
     }
//--- получить основной буфер MACD
   if(IsStopped()) return(0); //Проверка наличия флага остановки
   if(CopyBuffer(macdHandle,MAIN_LINE,0,toCopy,macdBuffer)<=0)
     {
      Print("Getting MACD Main is failed! Error : ",GetLastError());
      return(0);
     }
//--- получить сигнальный буфер MACD
   if(IsStopped()) return(0); //Проверка наличия флага остановки
   if(CopyBuffer(macdHandle,SIGNAL_LINE,0,toCopy,signalBuffer)<=0)
     {
      Print("Getting MACD Signal is failed! Error : ",GetLastError());
      return(0);
     }
//--- основной цикл вычислений
   for(int shift=start; shift<rates_total; shift++)
     {
      int currentExtremum,lastExtremum;
      bool isBullishDivergence,isBearishDivergence;
      string divergenceMsg;
      ENUM_LINE_STYLE divergenceStyle=0;
      
      //--- Поймать бычье расхождение
      isBullishDivergence=false;
               
      if(macdBuffer[shift-1]<=macdBuffer[shift-2] && 
         macdBuffer[shift-1]<macdBuffer[shift-3] && 
         macdBuffer[shift-1]<macdBuffer[shift])
         //--- если текущий macd main является дном (ниже, чем 2 предыдущих и 1 следующий)
        {
         currentExtremum=shift;
         lastExtremum=GetIndicatorLastTrough(shift);
         //--- 
         if(macdBuffer[currentExtremum-1]>macdBuffer[lastExtremum] && 
            low[currentExtremum-1]<low[lastExtremum])
           {
            isBullishDivergence=true;
            divergenceMsg="Classical bullish divergence on: ";
            divergenceStyle=STYLE_SOLID;
           }
         //--- 
         if(macdBuffer[currentExtremum-1]<macdBuffer[lastExtremum] && 
            low[currentExtremum-1]>low[lastExtremum])
           {
            isBullishDivergence=true;
            divergenceMsg="Reverse bullish divergence on: ";
            divergenceStyle=STYLE_DOT;
           }
         //--- Обнаружена бычья дивергенция
         if(isBullishDivergence)
           {
            bullishDivergence[currentExtremum]=macdBuffer[currentExtremum]-ARROWS_DISPLACEMENT;
            //---
            if(drawPriceTrendLines==true)
               DrawTrendLine(TRENDLINE_MAIN,time[currentExtremum-1],time[lastExtremum],low[currentExtremum-1],low[lastExtremum],Green,divergenceStyle);
            //---
            if(drawIndicatorTrendLines==true)
               DrawTrendLine(TRENDLINE_INDICATOR,time[currentExtremum-1],time[lastExtremum],macdBuffer[currentExtremum-1],macdBuffer[lastExtremum],Green,divergenceStyle);
            //---
            if(displayAlert==true && shift>=rates_total-3 && time[currentExtremum-1]!=lastAlertTime)
               DisplayAlert(divergenceMsg,time[currentExtremum-1]);
           }
        }
      //--- Поймать медвежье расхождение
      isBearishDivergence=false;

      if(macdBuffer[shift-1]>=macdBuffer[shift-2] && 
         macdBuffer[shift-1]>macdBuffer[shift-3] && 
         macdBuffer[shift-1]>macdBuffer[shift])
         //--- если текущий macd main является вершиной (выше, чем 2 предыдущих и 1 следующий)
        {
         currentExtremum=shift;
         lastExtremum=GetIndicatorLastPeak(shift);
         //--- 
         if(macdBuffer[currentExtremum-1]<macdBuffer[lastExtremum] && 
            high[currentExtremum-1]>high[lastExtremum])
           {
            isBearishDivergence=true;
            divergenceMsg="Classical bearish divergence on: ";
            divergenceStyle=STYLE_SOLID;
           }
         if(macdBuffer[currentExtremum-1]>macdBuffer[lastExtremum] && 
            high[currentExtremum-1]<high[lastExtremum])
           {
            isBearishDivergence=true;
            divergenceMsg="Reverse bearish divergence on: ";
            divergenceStyle=STYLE_DOT;
           }
         //--- Обнаружена медвежья дивергенция
         if(isBearishDivergence)
           {
            bearishDivergence[currentExtremum]=macdBuffer[currentExtremum]+ARROWS_DISPLACEMENT;
            //---
            if(drawPriceTrendLines==true)
               DrawTrendLine(TRENDLINE_MAIN,time[currentExtremum-1],time[lastExtremum],high[currentExtremum-1],high[lastExtremum],Red,divergenceStyle);
            //---
            if(drawIndicatorTrendLines==true)
               DrawTrendLine(TRENDLINE_INDICATOR,time[currentExtremum-1],time[lastExtremum],macdBuffer[currentExtremum-1],macdBuffer[lastExtremum],Red,divergenceStyle);
            //---
            if(displayAlert==true && shift>=rates_total-3 && time[currentExtremum-1]!=lastAlertTime)
               DisplayAlert(divergenceMsg,time[currentExtremum-1]);
           }
        }
     }
//--- возвращаем значение prev_calculated для следующего вызова
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Поиск последней впадины|
//+------------------------------------------------------------------+
int GetIndicatorLastTrough(int shift)
  {
   for(int i=shift-6; i>=2; i--)
     {
      if(signalBuffer[i] <= signalBuffer[i-1] && signalBuffer[i] <= signalBuffer[i-2] &&
         signalBuffer[i] <= signalBuffer[i+1] && signalBuffer[i] <= signalBuffer[i+2])
        {
         for(int j=i; j>=2; j--)
           {
            if(macdBuffer[j] <= macdBuffer[j-1] && macdBuffer[j] < macdBuffer[j-2] &&
               macdBuffer[j] <= macdBuffer[j+1] && macdBuffer[j] < macdBuffer[j+2])
               return(j);
           }
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| Поиск последнего пика|
//+------------------------------------------------------------------+
int GetIndicatorLastPeak(int shift)
  {
   for(int i=shift-6; i>=2; i--)
     {
      if(signalBuffer[i] >= signalBuffer[i-1] && signalBuffer[i] >= signalBuffer[i-2] &&
         signalBuffer[i] >= signalBuffer[i+1] && signalBuffer[i] >= signalBuffer[i+2])
        {
         for(int j=i; j>=2; j--)
           {
            if(macdBuffer[j] >= macdBuffer[j-1] && macdBuffer[j] > macdBuffer[j-2] &&
               macdBuffer[j] >= macdBuffer[j+1] && macdBuffer[j] > macdBuffer[j+2])
               return(j);
           }
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| ENUM_TRENDLINE_TYPE используется в DrawTrendLine |
//+------------------------------------------------------------------+

Vraja Sudhakar 2021.12.16 05:40 #49

Vladimir Karputov #:

когда дивергенция нулевая линия ниже также ценообразование HL дно (цена, если не сделано снова LL) гистограмма любой другой 5 30 60 240 тф 3 тф подписаны на плодотворный

Tony Sampietro 2022.05.27 01:19 #50

Здравствуйте, Ален,

Большое спасибо за этот замечательный индикатор!

Я пытаюсь использовать значения Data Window этого индикатора внутри советника (см. вложение).

Я использую ту же логику для всех четырех индексов, но мне удается получить правильные значения только для двух последних (Main и Signal).

Для первых двух я всегда вижу фиксированное число

в то время как, согласно приложенному примеру, один из них должен иметь правильное значение, а другой - 0/пустой

Вы знаете, почему у меня такая проблема?

Спасибо

Файлы:

Screenshot.PNG 85 kb

Советники: Virtual Trailing Stop Как кодировать? Обсуждение статьи "Библиотека для

Индикаторы: MACD Divergence - страница 5