FórumSeções

Bibliotecas: MT4Orders - página 18

Novo comentário

É possível escrever funções de negociação em fórmulas sintéticas.

Tomemos como exemplo a arbitragem triangular. Criamos esse símbolo em um minuto manualmente por meio da GUI ou em um segundo por meio de um script


E executamos a arbitragem TS nele.

// Arbitrage Advisor na fórmula synetics
#include <MT4Orders.mqh>

#define Bid SymbolInfoDouble(_Symbol, SYMBOL_BID)
#define Ask SymbolInfoDouble(_Symbol, SYMBOL_ASK)

void OnTick()
{
  if (Bid > 1)
    OrderSend(_Symbol, OP_SELL, 1, Bid, 0, 0, 0);
  else if (Ask < 1)
    OrderSend(_Symbol, OP_BUY, 1, Ask, 0, 0, 0);    
}
Fechamento rápido de posições de símbolo via CloseBy

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Fechamento de várias negociações de uma só vez

fxsaber, 2017.12.07 09:01

// Código MQL4&5
#include <MT4Orders.mqh> // https://www.mql5.com/pt/code/16006

#property strict

string CorrectSymbol( string &Symb )
{
  return(Symb = ((Symb == NULL) || (Symb == "")) ? _Symbol: Symb);
}

bool PlaceHedge( const string Symb )
{
  double Lots = 0;
    
  for (int i = OrdersTotal() - 1; i >= 0; i--)
    if (OrderSelect(i, SELECT_BY_POS) && (OrderType() <= OP_SELL) && (OrderSymbol() == Symb))
      Lots += OrderType() ? OrderLots() : -OrderLots();
      
  Lots = NormalizeDouble(Lots, 2);    
      
  return(((Lots > 0) && (OrderSend(Symb, OP_BUY, Lots, SymbolInfoDouble(Symb, SYMBOL_ASK), 100, 0, 0, "HEDGE") > 0)) ||
         ((Lots < 0) && (OrderSend(Symb, OP_SELL, -Lots, SymbolInfoDouble(Symb, SYMBOL_BID), 100, 0, 0, "HEDGE") > 0)) || !Lots);
}

bool CloseAll( string Symb = NULL )
{
  int Type = 0;
  long Ticket = 0;
  
  bool Res = PlaceHedge(CorrectSymbol(Symb));
  
  for (int i = OrdersTotal() - 1; !IsStopped() && Res && (i >= 0); i--)
    if (OrderSelect(i, SELECT_BY_POS) && (OrderType() <= OP_SELL) && (OrderSymbol() == Symb))
    {
      if (!Ticket)
      {
        Ticket = OrderTicket();
        Type = OrderType();
      }
      else if ((OrderType() != Type) && (Res = OrderCloseBy(Ticket, OrderTicket()) && PlaceHedge(Symb)))
      {
        Ticket = 0;       
        
        i = OrdersTotal();
      }
    }

  return(Res);
}

void OnStart()
{
  CloseAll();
}
fxsaber:

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Bibliotecas: MT4Orders

fxsaber, 2017.09.26 09:56 pm.

Erros de digitação


#define MODE_DIGITS    SYMBOL_TRADE_STOPS_LEVEL
#define MODE_DIGITS    SYMBOL_DIGITS



Kirill Belousov:

Um erro de digitação

Sim, há um erro de digitação nesse exemplo. Não posso corrigi-lo agora, pois o mecanismo do fórum não permite isso.

Obviamente, o erro de digitação no exemplo não afeta a biblioteca em si.

fxsaber:

Sim, há um erro de digitação nesse exemplo. Não posso corrigi-lo agora - o mecanismo do fórum não permite isso.

corrigido

o_o:

corrigido.

Obrigado!

No incluidor mql4_to_mql5.mqh.

double MarketInfo(const string Symb,const int Type)
  {
   switch(Type)
     {
      case MODE_BID:
         return(::SymbolInfoDouble(Symb, ::SYMBOL_BID));
      case MODE_ASK:
         return(::SymbolInfoDouble(Symb, ::SYMBOL_ASK));
      case MODE_DIGITS:
         return((double)::SymbolInfoInteger(Symb, ::SYMBOL_DIGITS));
      case MODE_SPREAD:
         return((double)::SymbolInfoInteger(Symb, ::SYMBOL_SPREAD));
      case MODE_STOPLEVEL:
         return((double)::SymbolInfoInteger(Symb, ::SYMBOL_TRADE_STOPS_LEVEL));
      case MODE_LOTSIZE:
         return(::SymbolInfoDouble(Symb, ::SYMBOL_TRADE_CONTRACT_SIZE));
     }

   return(-1);
  }
   return(0);
Kirill Belousov:

No compartimento mql4_to_mql5.mqh

#include <MQL4_to_MQL5.mqh> // apenas para este exemplo

Esse é exatamente um exemplo, relevante apenas para a conversão de alguns EAs na descrição. Nesta discussão, as bibliotecas se mostraram muito melhores do que a MarketInfo e a solução de outros.

Há uma observação muito importante na descrição, destacada pelo moderador (não por mim)

Aviso.

A biblioteca está contida em apenas um arquivo - MT4Orders.mqh. Todos os outros arquivos estão anexados como exemplos de uso da biblioteca. Esses arquivos não são necessários para trabalhar com a biblioteca.

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Bibliotecas: MT4Orders

fxsaber, 2017.09.03 18:52

// Lista de modificações:
// 03.09.2017:
// Adicionar: Adicionado OrderTicketOpen() - Ticket MT5 da transação de abertura de posição
// OrderOpenReason() - motivo da transação de abertura do MT5 (motivo para abrir uma posição)
// OrderCloseReason() - motivo da transação de fechamento do MT5 (motivo para fechar a posição)

Exemplo de aplicativo

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Duas últimas ordens

fxsaber, 2017.12.23 11:02

#include <MT4Orders.mqh>

// Retornar tíquetes das últimas transações de valor fechadas devido ao motivo Razão
int GetLastHistoryPositions( long &Tickets[], int Amount = INT_MAX, const ENUM_DEAL_REASON Reason = DEAL_REASON_SL )
{
  int Count = ArrayResize(Tickets, 0);
  
  for (int i = OrdersHistoryTotal() - 1; (i >= 0) && (Count < Amount); i--)
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY) && (OrderCloseReason() == Reason))
      Tickets[ArrayResize(Tickets, ++Count) - 1] = OrderTicket();
  
  return(Count);
}

void OnStart()
{
  long Tickets[];
  
  // Os dois últimos negócios foram fechados no SL
  for (int i = GetLastHistoryPositions(Tickets, 2) - 1; i >= 0; i--)
    Print(Tickets[i]);
}

Olá! A descrição diz: "Consequentemente, o OrderSelect no modo SELECT_BY_TICKET no MT5, em casos raros (no testador), pode não selecionar o que foi planejado no MT4. "Você pode escrever em detalhes em quais casos?

1...111213141516171819202122232425...95
Novo comentário