Implementações alternativas de funções/abordagens padrão - página 4

Novo comentário
 
fxsaber:

Uma variante do CopyTicks, que às vezes é várias ordens de magnitude mais rápida do que a original (de > 0)

Build 1432 - A alternativa CopyTicks não é mais relevante.
 
fxsaber:
Build 1432 - a alternativa CopyTicks não é mais relevante.

De onde veio o 1432? Eu tenho o último 1430 em MetaQuotes-Demo

 
Alexey Volchanskiy:

De onde veio o 1432? Recebi o último 1430 em MetaQuotes-Demo.

Ele conseguiu através de um favor...
 
prostotrader:
Ele conseguiu através de um suborno...

Você não deve rir. Eu recebi um uma vez.

 
Alexey Viktorov:

Você não deve rir. Uma vez me foi dado um.

O que o faz pensar que eu estou rindo?
 
prostotrader:
O que o faz pensar que eu estou rindo?
Parecia ser assim.
 

Fórum sobre comércio, sistemas automatizados de comércio e teste de estratégias comerciais

Características da linguagem mql5, sutilezas e truques

fxsaber, 2018.04.16 13:23

Muito mais rápido esta opção (Release, não Debug)

double StringToDouble2( const string Str, const uint StartPos = 0 )
{
  const uint Size = StringLen(Str);
  
  bool Sign = false;  
  uint i = StartPos;
  
  while (i < Size)
  {
    const int Digit = Str[i];

    if ((Digit != ' ') && (Digit != '\t') && (Digit != '\n') && (Digit != '\r'))
    {
      if ((Sign = (Digit == '-')) || (Digit == '+'))
        i++;
      
      break;
    }
      
    i++;
  }

  long Res = 0;
  int point = 0;
  
  while (i < Size)
  {
    const int Digit = Str[i];
    
    if (!point && (Digit == '.'))
      point = 1;
    else if (((Digit >= '0') && (Digit <= '9')))
    {
      Res = Res * 10 + Digit - '0';
      
      if (point)
        point *= 10;
    }
    else
      break;
      
    i++;
  }
  
  if (Sign)
    Res = -Res;
  
  return((point > 1) ? Res / (double)point : Res); // Возможна потеря точности при делении
}

Ao analisar dados volumosos, você obtém uma velocidade significativa.

 
Voltamos à idéia de incorporar a massa de funções simples do sistema nativamente no código MQL5 resultante, o que nos permitiu acelerá-las muitas vezes, utilizando-as na otimização global do código resultante.

Isto se aplica a funções como NormalizeDouble, operações de cordas, etc.

Para estar disponível nos próximos betas após o lançamento na próxima semana.
 
Renat Fatkhullin:
Voltamos à idéia de incorporar uma massa de funções simples do sistema nativamente no código MQL5 resultante, o que nos permitiu acelerá-las muitas vezes, utilizando-as na otimização global do código resultante.

OK.

 
fxsaber:

OK.

Bem-vindo de volta!

GráficoXYToTimePreço analógico

Não é um análogo completo (em termos de parâmetros), mas esta variante me parece ainda mais conveniente e prática. Também é mais rápido (por um par de ordens de grandeza).
Por funcionalidade é totalmente analógico e ainda mais, porque retorna (ao contrário da função original) o número da sub janela, na qual há X, Y (cursor), se -1, então fora da janela (sub janela).

Este analógico não contém parâmetros de entradachart_id esub_window, pois não consigo ver como esta função pode ser usada fora da janela atual. Além disso, o parâmetrosub_janela é até pouco claro, uma vez que a função original opera exatamente da mesma forma, independentemente de seus valores.



// Fast Analog ChartXYToTimePrice function (https://www.mql5.com/ru/docs/chart_operations/chartxytotimeprice)
int XYToTimePrice(int x,int y,datetime &time,double &price,int id=0) // возвращает номер подокна в котором находится X,Y (курсор), если -1 - то вне окна
  {
   static int left_bar; // номер самого левого бара на экране
   static int Wid;
   static int Hei[10];
   static double y_min[10];
   static double y_max[10];
   static int PerSec=PeriodSeconds();
   static bool ChartChange=true;
   static int windowsTotal=(int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
   static int Cur_wind=-1;
   static int WidthBar=int(1<<ChartGetInteger(0,CHART_SCALE));
   if(id==CHARTEVENT_CHART_CHANGE) if(!ChartChange) {ChartChange=true; return(Cur_wind);}
   if(ChartChange) // если было изменение чатра после последнего вычисления
     {
      windowsTotal=(int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
      if(windowsTotal>10) {Print("Too many subwindows"); return(-1);}
      for(int i=0;i<windowsTotal;i++) if(i>0) Hei[i]=(int)ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,i)+Hei[i-1]+2;
      else Hei[0]=(int)ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0);
      left_bar=(int)ChartGetInteger(0,CHART_FIRST_VISIBLE_BAR, 0);        // номер самого левого бара на экране
      Wid=(int)ChartGetInteger(0,CHART_WIDTH_IN_PIXELS, 0);               // ширина экрана в пикселях
      WidthBar=int(1<<ChartGetInteger(0,CHART_SCALE));                    // растояние между барами в пикселях
                                                                          
      for(int i=0;i<windowsTotal;i++)
        {
         y_min[i]=ChartGetDouble(0,CHART_PRICE_MIN, i);                         // макс. цена на экране
         y_max[i]=ChartGetDouble(0,CHART_PRICE_MAX, i);                         // мин. цена на экране
        }
     }
   if(x>(Wid+1) || x<0 || y<0 || y>=(Hei[windowsTotal-1]+1)) return(-1);  // выходим если точка (x,y) за пределами экрана
   Cur_wind=-1;
   if(y>=0 && y<=Hei[0]) Cur_wind=0;
   else if(windowsTotal>1) for(int i=1;i<windowsTotal;i++) if(y>(Hei[i-1]+1) && y<=Hei[i]) { Cur_wind=i; break; }
   if(Cur_wind>=0)
     {
      if(Cur_wind>0) y=y-Hei[Cur_wind-1]-2;
      int hh=Hei[Cur_wind];
      if(Cur_wind>0) hh-=Hei[Cur_wind-1]+2;
      price=y_min[Cur_wind]+(hh-y)*(y_max[Cur_wind]-y_min[Cur_wind])/hh;

      double NrBar=left_bar-(double)x/(double)WidthBar;
      datetime TT[2];
      if(NrBar>0) { CopyTime(NULL,0,(int)NrBar,2,TT); time=TT[0]+(datetime)((TT[1]-TT[0])*(1.0-NrBar+(int)NrBar)); }
      else        { CopyTime(NULL,0,0,1,TT);          time=TT[0]+(datetime)(fabs(NrBar)*PerSec); }
     }
   ChartChange=false;

   return(Cur_wind);
  }


Esta função pode ser executada em qualquer lugar sem o parâmetro id, mas deve estar sempre presente no OnChartEvent (com o parâmetro id) para descobrir se é necessário atualizar as variáveis internas desta função.

Por exemplo, se a função não for usada da OnChartEvent, uma linha deve ser adicionada ao corpo da OnChartEvent para que ela funcione corretamente:

if (id==CHARTEVENT_CHART_CHANGE) { double p=0; datetime t=0; XYToTimePrice(0,0,t,p,id);}
Este análogo dá um benefício notável quando esta função é utilizada com bastante freqüência.
Não há sentido em utilizar este análogo para aplicações únicas.
Arquivos anexados:
TestSpeedXY.mq5  15 kb
1234567891011...13
Novo comentário