Download MetaTrader 5

Watch how to download trading robots for free

Interesting script?
So post a link to it -
let others appraise it

You liked the script? Try it in the MetaTrader 5 terminal

2011.03.21 14:10
Experts

MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man + RSI - expert for MetaTrader 5

| English Русский 中文 Español Deutsch 日本語 Português

Views:
5973
Rating:
votes: 20
\MQL5\Include\Expert\Signal\MySignals\
ach_hm_rsi.mqh (7.93 KB)view

The MQL5 Wizard allows creating ready-made Expert Advisors based on the Standard library classes delivered together with the client terminal (see Creating Ready-Made Expert Advisors in MQL5 Wizard for the details). It allows to check your trade ideas quickly, all you need is to create your own trading signals class. The structure of this class and example can be found in the article MQL5 Wizard: How to Create a Module of Trading Signals.

The generic idea is the following: the class of trading signals is derived from CExpertSignal, the next, it's necessary to override the LongCondition() and ShortCondition() virtual methods with your own methods.

There is a book "Strategies of best traders" (in Russian), there are many trading strategies are considered there, we will focus on reversal candlestick patterns, confirmed by Stochastic, CCI, MFI and RSI oscillators.

The best way is to create the separate class, derived from CExpertSignal for checking of formation of candlestick patterns. For confirmation of trade signals, generated by candlestick patterns, it's sufficient to write the class, derived from CCandlePattern and add the necessary features (for example, confirmation by oscillators) there.

Here we will consider the signals, based on "Hammer/Hanging Man" reversal candlestick pattern, confirmed by CCI indicator. The module of trade signals is based on the CCandlePattern class, it's simple example of its use for creation of trade signals with candlestick patterns.


1. "Hammer" and "Hanging Man" reversal candlestick patterns

1.1. Hammer

The "Hammer" is a candlestick with a small body and long lower wick, formed after downward price movement. The "Hammer" pattern indicates the end of a bearish trend.

The color of a candlestick body isn't important, but bullish hammer indicates higher bullish potential. The body of the "Hammer" pattern often formed near the mininum of the previous candle. The longer lower wick and shorter upper wick leads to higher potential of the reversal pattern.

Fig. 1. "Hammer" candlestick pattern

Fig. 1. "Hammer" candlestick pattern

The recognition of "Hammer" pattern is implemented in CheckPatternHammer() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Hammer" candlestick pattern                 |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- Hammer
   if((MidPoint(1)<CloseAvg(2))                                 && // down trend
      (MathMin(Open(1),Close(1))>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // body gap
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) method of CCandlePattern class is used to check formation of "Hammer" candlestick pattern.


1.2. Hanging Man

The "Hanging Man" is a candlestick with a small body and long lower wick, formed after upward price movement. The "Hanging Man" pattern indicates the end of a bullish trend.

The color of a candlestick body isn't important, but bearish candle indicates higher bearish potential. The body of the "Hanging Man" pattern often formed near the maxinum of the previous candle. The longer lower wick and shorter upper wick leads to higher potential of the reversal pattern.

Fig. 2. "Hanging Man" candlestick pattern

Fig. 2. "Hanging Man" candlestick pattern

The recognition of "Hanging Man" pattern is implemented in CheckPatternHangingMan() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Hanging Man" candlestick pattern            |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- Hanging man
   if((MidPoint(1)>CloseAvg(2))                                && // up trend
      (MathMin(Open(1),Close(1)>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)>Close(2)) && (Open(1)>Open(2))))                  // body gap
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) method of CCandlePattern class is used to check formation of "Hanging Man" candlestick pattern.



2. Trade signals, confirmed by RSI indicator

The trading signals to open long or short position must be confirmed by RSI indicator. The value of RSI must be lower/greater than critical levels (40 for long position and 60 for short position).

The closing of opened position depends on the values of RSI. It can be done in 2 cases:

  1. if RSI has reached the opposite critical level (70 for long position and 30 for short position)
  2. if the reverse signal isn't confirmed (when RSI reaches the following levels: 30 for long position and 70 for short position)

Fig. 3. "Harami" pattern, confirmed by RSI indicator

Fig. 3. "Harami" pattern, confirmed by RSI indicator


  • int CH_HM_RSI::LongCondition() - checks conditions to open long position (returns 80) and close of the short position (returns 40);
  • int CH_HM_RSI::ShortCondition() - checks conditions to open short position (returns 80) and close of the long position (returns 40).

2.1. Open long position/Close short position

  1. The formation of "Hammer" pattern must be confirmed by RSI indicator: RSI(1)<40 (the value of the RSI of the last completed bar must be less than 40).

  2. The short position must be closed if RSI indicator has crossed upward the critical levels 70 or 30.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CH_HM_RSI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Hammer pattern and RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (RSI(1)<40))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (upward 30, upward 70)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- return result
   return(result);
  }

2.2. Open short position/Close long position

  1. The formation of "Hanging Man" pattern must be confirmed by RSI indicator: RSI(1)>60 (the value of the RSI indicator of the last completed bar must be greater than 60).

  2. The long position must be closed if RSI indicator has crossed downward the critical levels 70 or 30.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CH_HM_RSI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Hanging Man pattern and RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (RSI(1)>60))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 70, downward 30)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- return result
   return(result);
  }


2.3. Creating Expert Advisor using MQL5 Wizard

The CH_HM_RSI class isn't included in the Standard Library classes, to use it, it's necessary to download the ach_hm_rsi.mqh file (see attachments) and save it to the client_terminal_data\folder\MQL5\Include\Expert\Signal\MySignals. The same should be done with the candlepatterns.mqh file. You can use it in MQL5 Wizard after restart of the MetaEditor.

To create an Expert Advisor launch MQL5 Wizard:

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Let's specify the name of the Expert Advisor:

Fig. 5. General properties of the Expert Advisor

Fig. 5. General properties of the Expert Advisor

After that we need to select the modules of trade signals used.

Fig. 6. Signal properties of the Expert Advisor

Fig. 6. Signal properties of the Expert Advisor

In our case we use only one module of trade signals.

Adding the "Signals based on Hammer/Hanging Man confirmed by RSI" module of trading signals:

Fig. 7. Signal properties of the Expert Advisor

Fig. 7. Signal properties of the Expert Advisor

Module of trade signals added:

Fig. 8. Signal properties of the Expert Advisor

Fig. 8. Signal properties of the Expert Advisor

You can select any trailing properties, but we will use "Trailing Stop not used":

Fig. 9. Trailing properties of the Expert Advisor

Fig. 9. Trailing properties of the Expert Advisor

Concerning the money management properties, we will use "Trading with fixed trade volume":

Fig. 10. Money management properties of the Expert Advisor

Fig. 10. Money management properties of the Expert Advisor

By pressing the "Finish" button, we will get the code of the generated Expert Advisor, located in Expert_AH_HM_RSI.mq5, it will be saved in terminal_data_folder\MQL5\Experts\.

The default input parameters of the generated Expert Advisor:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

must be replaced to:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

The Signal_ThresholdOpen/Signal_ThresholdClose input parameters allow to specify threshold levels for open and close of positions.

In code of the LongCondition() and ShortCondition() methods of the trade signals class we have specified the fixed values of the threshold:

  • Open position: 80;
  • Close position: 40.

The Expert Advisor, generated by MQL5 Wizard open and close position using the "votes" from the modules of trade signals. The vote of the main module (as container, it consist of all the modules added) is also used, but its LongCondition() and ShortCondition() methods always return 0.

The vote results of the main module is also used in "votes" averaging. In our case we have:  main module + 1 module of trade signals, so we need to take this fact into account when setting of the threshold values. Because of this fact the ThresholdOpen and ThresholdClose must be set as 40=(0+80)/2 and 20=(0+40)/2.

The values of  Signal_StopLevel and Signal_TakeLevel input parameters is set to 0, it means that closing of the positions will be done only when closing conditions will be true.


2.4. History backtesting results

Let's consider backtesting of the Expert Advisor on historical data (EURUSD H1, testing period:  2010.01.01-2011.03.03, PeriodRSI=33, MA_period=2).

In creation of Expert Advisor we used the fixed volume (Trading Fixed Lot, 0.1), Trailing Stop algorithm is not used (Trailing not used).

Fig. 11. Testing results of the Expert Advisor, based on Hammer/Hanging Man + RSI

Fig. 11. Testing results of the Expert Advisor, based on Hammer/Hanging Man + RSI


The best set of input parameters can be found using the Strategy Tester of MetaTrader 5 client terminal.

The code of the Expert Advisor, created by MQL5 Wizard is attached in expert_ah_hm_rsi.mq5.


Translated from Russian by MetaQuotes Software Corp.
Original code: https://www.mql5.com/ru/code/317

MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man + MFI MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man + MFI

Trade signals based on "Hammer/Hanging Man" candlestick pattern, confirmed by Market Facilitation Index (MFI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man  CCI MQL5 Wizard - Trade Signals Based on Hammer/Hanging Man CCI

Trade signals based on "Hammer/Hanging Man" candlestick pattern, confirmed by Commodity Channel Index (CCI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Bullish/Bearish Meeting Lines + Stochastic MQL5 Wizard - Trade Signals Based on Bullish/Bearish Meeting Lines + Stochastic

Trade signals based on "Bullish/Bearish Meeting Lines" candlestick pattern, confirmed by Stochastic indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Bullish/Bearish Meeting Lines + CCI MQL5 Wizard - Trade Signals Based on Bullish/Bearish Meeting Lines + CCI

Trade signals based on "Bullish/Bearish Meeting Lines" candlestick pattern, confirmed by Commodity Channel Index (CCI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.