Bibliotheken: TypeToBytes - Seite 5

Neuer Kommentar
 
fxsaber:
Zwei Zeilen mit demselben Ergebnis
ArrayCompare(Array1, Array2) == 0
_R(Array1) == Array2
  
// Lesen/Schreiben privater Felder von einfachen Strukturen

#include <TypeToBytes.mqh>

template <typename T>
struct STRUCT
{
private:
  T Data; // privates Feld
  
public:
  T GetData( void ) const
  {
    return(this.Data);
  }
};

void OnStart()
{    
  STRUCT<int> Struct = {0};  
  
  _W(Struct) = 2;          // Schreibzugriff auf privates Feld
  Print(Struct.GetData()); // Vergewissern Sie sich, dass es sich um
  
  Print(_R(Struct)[0]);    // Lesezugriff auf privates Feld
}
 
Die Bibliothek schreibt eine Containerklasse vor, die Variablen und Arrays von beliebigen anderen einfachen Typen in einem Array eines bestimmten Typs speichert.
// Beispiel für die Arbeit mit einem Container
#include <TypeToBytes.mqh>

#define  PRINT(A) Print(#A + " = " + (string)(A));

void OnStart()
{
  // Beliebige Daten für das Beispiel
  string Str[] = {"123", "Hello World!"};
  double Num = 5;
  MqlTick Tick = {0};
  Tick.bid = 1.23456;
  
  CONTAINER<long> Container;  // Erstellen eines Containers - alles wird in einem Array eines einfachen Typs gespeichert (in diesem Beispiel wird long gewählt)
  
  // Füllen Sie den Container mit verschiedenen Daten
  Container[0] = Str;
  Container[1] = Num;
  Container[2] = Tick;
  
  ArrayPrint(Container.Data); // Ausgabe des Inhalts des Arrays, in dem der Container alle Daten speichert
  
  // Drucken der im Container gespeicherten Datentypen
  for (int i = 0; i < Container.GetAmount(); i++)
    PRINT(Container[i].GetType())
    
  // Holen wir uns die Daten selbst 
  string Str2[];
  Container[0].Get(Str2);                // Ich habe das Array
  ArrayPrint(Str2);
  
  PRINT(Container[1].Get<double>())      // Wir haben eine Nummer
  PRINT(Container[2].Get<MqlTick>().bid) // Wir haben die Struktur
  
  Container[1] = "Replace";   // Ersetzte Daten durch Index
  
  // Überprüfen, ob die Ersetzung stattgefunden hat 
  PRINT(Container[1].GetType())
  PRINT(Container[1].Get<string>())
}
 
fxsaber:
Die Bibliothek enthält eine Containerklasse, die Variablen und Arrays von beliebigen anderen einfachen Typen in einem Array eines bestimmten Typs speichert.

Beispiel einer praktischen Anwendung in der Report-Bibel

Senden eines Frames mit verschiedenen Daten

        string Str;
        REPORT::ToString(Str);

        double Balance[];
        REPORT::GetBalanceHistory(Balance);

      #ifdef __TYPETOBYTES__
        CONTAINER<uchar> Container;

        Container[0] = Str;     // den Berichtsstring in den Container legen
        Container[1] = Balance; // Hinzufügen eines doppelten Arrays mit der Historie der Saldenänderungen zum Container

        ::FrameAdd(NULL, 0, ::AccountInfoDouble(ACCOUNT_BALANCE), Container.Data); // Senden eines Rahmens mit String-Bericht und Saldo-Array
      #else  // __TYPETOBYTES__

Empfangen eines Rahmens mit anderen Daten

 CONTAINER<uchar> Container;

    while (::FrameNext(Pass, Name, ID, Value, Container.Data))
    {
        string Str;
        Container[0].Get(Str);     // Abrufen der Berichtszeichenfolge aus dem Rahmen

        double Balance[];
        Container[1].Get(Balance); // Abrufen des entsprechenden Double-Arrays aus dem Rahmen

// .....
Report
Report
  • 2017.07.19
  • fxsaber
  • www.mql5.com
Библиотека для MetaTrader 4/5, которая позволяет формировать отчеты по истории торгов.
 
Ein weiteres Beispiel für eine Container-Anwendung

Forum über Handel, automatisierte Handelssysteme und das Testen von Handelsstrategien

Fragen von MQL5 MT5 MetaTrader 5 Anfängern

fxsaber, 2017.08.23 14:10

Sie müssen den Frame-Modus verwenden, um die Daten der Agents in eine Datei zu schreiben.

// Beispiel für die Aufzeichnung von Agentendaten (einschließlich Cloud-Agenten) in einer Datei
input int Range = 0;

void OnTick()
{
// ....
}

// Öffnen Sie die Datei nur im Einzellauf- oder Frame-Modus.
const int handle = ((MQLInfoInteger(MQL_TESTER) && !MQLInfoInteger(MQL_OPTIMIZATION)) || MQLInfoInteger(MQL_FRAME_MODE)) ?
                   FileOpen(__FILE__, FILE_WRITE | FILE_TXT) : INVALID_HANDLE;

// Datenaufbereitung
void GetData( string &Str, MqlTick &Ticks[], double &Balance )
{
  Str = "Hello World!";
  
  CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, 0, 2); // Die letzten zwei Ticks (Beispiel)
  
  Balance = AccountInfoDouble(ACCOUNT_BALANCE);
}

// Daten schreiben
void SaveData( const string &Str, const MqlTick &Ticks[], const double Balance )
{
  FileWrite(handle, Str);
  
  for (int i = 0; i < ArraySize(Ticks); i++)
    FileWrite(handle, Ticks[i].bid);
    
  FileWrite(handle, Balance);
}

void OnTesterDeinit()
{
  if (handle != INVALID_HANDLE)  
    FileClose(handle);
    
  ChartClose();
}

#include <TypeToBytes.mqh> // https://www.mql5.com/de/code/16280

double OnTester()
{
  string Str;
  MqlTick Ticks[];
  double Balance;
  
  GetData(Str, Ticks, Balance); // Daten für die Aufzeichnung vorbereiten

  if (MQLInfoInteger(MQL_OPTIMIZATION)) // Optimierung
  {
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
    
    Container[0] = Str;
    Container[1] = Ticks;
    Container[2] = Balance;
  
    FrameAdd(NULL, 0, 0, Container.Data); // Gesendete Daten vom Agenten an das Terminal
  }
  else // Einzelner Lauf
  {    
    if (handle != INVALID_HANDLE)
      SaveData(Str, Ticks, Balance); // Die Daten werden in den Ordner MQL5\Files des Agenten geschrieben (nicht in das Terminal)
    
    FileClose(handle);
  }
  
  return(0);
}

void OnTesterPass()
{    
  if (handle != INVALID_HANDLE)
  {
    ulong Pass;
    string Name;
    long ID;
    double Value;
  
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
  
    while (FrameNext(Pass, Name, ID, Value, Container.Data))
    {
      string Str;
      MqlTick Ticks[];
      double Balance;
      
      // Empfangene Daten vom Agenten
      Container[0].Get(Str);
      Container[1].Get(Ticks);
      Container[2].Get(Balance);
      
// FileWrite(handle, Pass); // Wenn Sie die Nummer der Passage schreiben wollen
      SaveData(Str, Ticks, Balance); // Die Daten werden in den Ordner MQL5\Files des Terminals (nicht des Agenten) geschrieben
    }
  }
}
 
Beispiel für Standarddatencodierung (rot - Bibliotheksnutzung)

Forum zum Thema Handel, automatisierte Handelssysteme und Testen von Handelsstrategien

Neue Version von MetaTrader 5 build 1640: Erstellen und Testen von eigenen Finanzinstrumenten

fxsaber, 2017.10.10 07:51

// Wie stark die MqlRates-Daten und die Pack-/Entpackgeschwindigkeit gequetscht werden
#include <TypeToBytes.mqh> // https://www.mql5.com/de/code/16280

#define  TOSTRING(A) #A + " = " + (string)(A) + "\n"

void OnStart()
{
  MqlRates Rates[];
  uchar Tmp[];  
  
  const int Amount = CopyRates(_Symbol, PERIOD_CURRENT, 0, Bars(_Symbol, PERIOD_CURRENT), Rates) * sizeof(MqlRates);  
  
  // Archivierung
  const ulong StartTime1 = GetMicrosecondCount();
  const int AmountZIP = CryptEncode(CRYPT_ARCH_ZIP, _R(Rates).Bytes, Tmp, Tmp);
  
  Print(TOSTRING(Amount) + TOSTRING(AmountZIP) + TOSTRING((double)Amount / AmountZIP) + TOSTRING(GetMicrosecondCount() - StartTime1));
  
  uchar Tmp2[];
  
  // Entpacken
  const ulong StartTime2 = GetMicrosecondCount();
  CryptDecode(CRYPT_ARCH_ZIP, Tmp, Tmp2, Tmp2);
  Print(TOSTRING(GetMicrosecondCount() - StartTime2));
  
  Print(TOSTRING(_R(Rates) == Tmp2)); // Stimmen die Daten überein?
}
 
Verwendung der Bibliothek, um beliebige Daten in/aus einer Zeichenkette zu speichern/abzurufen
// Plattformübergreifendes Beispiel für die Übergabe beliebiger Daten über ein benutzerdefiniertes Ereignis

#include <fxsaber\HistoryTicks\Data_String.mqh> // https://www.mql5.com/de/code/20298

// Beliebige Daten drucken
template <typename T>
bool MyPrint( const T &Value )
{
  T Array[1];
  
  Array[0] = Value;
  
  ArrayPrint(Array, _Digits, NULL, 0, WHOLE_ARRAY, ARRAYPRINT_HEADER | ARRAYPRINT_ALIGN);
  
  return(true);
}

void OnChartEvent( const int id, const long &lparam, const double&, const string &sparam )
{
  // Drucken der erhaltenen Daten
  if ((id == CHARTEVENT_CUSTOM) &&
      (lparam ?  MyPrint(DATA_STRING::FromString<MqlDateTime>(sparam)) // MqlDateTime erhalten
              : !MyPrint(DATA_STRING::FromString<MqlTick>(sparam))))   // MqlTick bekommen
    ExpertRemove(); // Aus dem Beispiel heraus
}

void OnInit()
{
  MqlTick Tick;  
  MqlDateTime DateTime;
  
  // Ausfüllen der Werte
  SymbolInfoTick(_Symbol, Tick);  
  TimeCurrent(DateTime);

  // Weitergegeben
  EventChartCustom(0, 0, 0, 0, DATA_STRING::ToString(Tick));     // Übergebener MqlTick
  EventChartCustom(0, 0, 1, 0, DATA_STRING::ToString(DateTime)); // Übergebene MqlDateTime
}
 
Ein einfaches Beispiel für die Anwendung

Forum zum Thema Handel, automatisierte Handelssysteme und Testen von Handelsstrategien

Beta-Version von MetaTrader 5 build 1995: Wirtschaftskalender, MQL5-Programme als Dienste und API für die Sprache R

fxsaber, 2019.02.18 16:36

#include <TypeToBytes.mqh> // https://www.mql5.com/de/code/16280

int StringToShortArray2( const string Str, ushort &Array[], const int = 0, const int = 0 )
{
  const int Size = ArrayResize(Array, StringLen(Str));
  
  for (int i = 0; i < Size; i++)
    _W(Array[i]) = Str[i];
  
  return(Size);
}
 

Hallo. Es klappt also.

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
  };

#include <Exchange_Data.mqh>

#define  AMOUNT 100

EXCHANGE_DATA<Message>ExchangeTicks(AMOUNT,true);
//+------------------------------------------------------------------+
//| Benutzerdefinierte Initialisierungsfunktion für Indikatoren |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Zuordnung von Indikatorpuffern
   static Message Ticks[1];
   Ticks[0].cnt=1;
   Ticks[0].res=true;
   Ticks[0].ter=1;
   ExchangeTicks.DataSave(Ticks);
//---
   return(INIT_SUCCEEDED);
  }

Und so funktioniert es.

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
   string            str;
  };

#include <Exchange_Data.mqh>

#define  AMOUNT 1000

EXCHANGE_DATA<Message>ExchangeTicks(AMOUNT,true);
//+------------------------------------------------------------------+
//| Benutzerdefinierte Initialisierungsfunktion für Indikatoren |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Zuordnung von Indikatorpuffern
   static Message Ticks[1];
   Ticks[0].cnt=1;
   Ticks[0].res=true;
   Ticks[0].ter=1;
   Ticks[0].str = "SDf";
   ExchangeTicks.DataSave(Ticks);
//---
   return(INIT_SUCCEEDED);
  }

Ich habe es von hier für MT4

https://www.mql5.com/ru/forum/5905/page11#comment_6134460
 
Aleksei Beliakov:

Das ist so.

#define  DEFINE_STRING(A)                        \
  struct STRING##A                              \
  {                                             \
  private:                                      \
    short Array[A];                             \
                                                \
  public:                                       \
    void operator =( const string Str )         \
    {                                           \
      ::StringToShortArray(Str, this.Array);    \
                                                \
      return;                                   \
    }                                           \
                                                \
    string operator []( const int = 0 ) const   \
    {                                           \
      return(::ShortArrayToString(this.Array)); \
    }                                           \
  };                                            
  
DEFINE_STRING(128) // Ein Analogon zu einer Zeichenkette mit maximal 128 Zeichen.

#undef  DEFINE_STRING

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
   STRING128         str;
  };
1234567
Neuer Kommentar