MQL5 向导 - 基于 3 乌鸦/3 白兵 + Stochastic - MetaTrader 5EA

MQL5 向导 可创建现成的交易程序，此程序基于客户端附带的 标准类库（参见 在 MQL5 向导中创建现成交易程序 具体内容）。它可以快速验证您的交易想法，所有您需要做的就是创建您自己的交易信号类。这个类的结构及用例可参阅文章 MQL5 向导：如何创建交易信号模块。

通常做法如下：交易信号子类由 CExpertSignal衍生出来，之后，必须用您自己的方法重写类中的 LongCondition() 和 ShortCondition() 虚方法。

有本书 "Strategies of best traders（交易者最佳策略）"（俄语版），书中论述了许多交易策略，我们将注意力集中在反转 K 线形态上，并用 Stochastic, CCI, MFI 和 RSI 振荡指标来确认。

最佳途径是创建分离的子类，此类由 CExpertSignal 中衍生，用于检查 K 线的形态结构。用于验证 K 线形态生成的交易信号，写一个 CCandlePattern 的衍生子类就足够了，并加入必要的特性（如，振荡指标确认）。

此处我们讨论的信号，基于 "3 乌鸦/3 白兵" 反转 K 线形态，确认则依赖 Stochastic 指标。这个交易信号模块基于 CCandlePattern 类，这是一个利用 K 线形态创建交易信号的简单例子。

1. "3 乌鸦" 和 3 "白兵" 反转形态

1.1. “3 乌鸦”形态

一个熊市形态，用于预示当前上升趋势将要反转。这个形态由三根连续长实体的 K 线组成，每根线都收阴，且收盘价都低于前一天的收盘价。

图例. 1. "3 乌鸦" 形态

识别 "3 乌鸦" 形态已经在 CCandlePattern 类的 CheckPatternThreeBlackCrows 方法中实现：

//+------------------------------------------------------------------+
//| Checks formation of "3 Black Crows" candlestick pattern          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeBlackCrows()
  {
//--- 3 乌鸦 
   if((Open(3)-Close(3)>AvgBody(1)) && // (长阴)
      (Open(2)-Close(2)>AvgBody(1)) &&
      (Open(1)-Close(1)>AvgBody(1)) && 
      (MidPoint(2)<MidPoint(3))     && // (低于中点)
      (MidPoint(1)<MidPoint(2)))       
      return(true);
//---
   return(false);
  }

1.2. “3 白兵”形态

一个牛市形态，用于预示当前下降趋势将要反转。这个形态由三根连续长实体的 K 线组成，每根线都收阳，且收盘价都高于前一天的收盘价。

此形态是否有效，要求第二根线长度与前一根线近似，开盘价高于前一根线日内高度的一半偏上，且收盘价靠近日内高点，没有上影线，或上影线较短。三根线都要符合要求。

图例 2. "3 白兵" 形态

这是识别 "3 白兵" 形态的方法：

//+------------------------------------------------------------------+
//| Checks formation of "3 White Soldiers" candlestick pattern       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeWhiteSoldiers()
  {
   //--- 3 白兵
   if((Close(3)-Open(3)>AvgBody(1)) && // 长阳
      (Close(2)-Open(2)>AvgBody(1)) &&
      (Close(1)-Open(1)>AvgBody(1)) &&
      (MidPoint(2)>MidPoint(3))     && // 高于中点
      (MidPoint(1)>MidPoint(2)))
      return(true);
//---
   return(false);
  }

2. Stochastic 指标确认交易信号

采用交易信号来开多单或空单，必须用 Stochastic 指标来确认。信号 %D 线必须高于/低于相应的临界水平 (30 or 70)。

已建仓位的平仓同样依靠 %D 指标线的值。可分 2 种情况完成：

1. 如果 %D 指标线已经到达反向临界水平 (80 为多单，以及 20 为空单）
2. 如果反转信号未被确认（当 %D 指标线到达如下水平：20 为多单，以及 80 为空单）
   

图例. 3. "3 白兵" 形态, 由 Stochastic 指标确认

以下两个方法中实现了检测交易进场、出场条件：

• int CBC_WS_Stoch::LongCondition() - 检测开多单条件（返回 80） 以及平空仓（返回 40）；
  
• int CBC_WS_Stoch::ShortCondition() - 检测开空单条件（返回 80） 以及平多仓（返回 40）。

2.1. 开多单/平空仓

1. 这个 "3 白兵" 形态的形状必须由 Stochastic 指标确认：StochSignal(1)<30 （最后完整的 Stochastic 信号线值必须小于 30）。

2. 空单必须被平仓如果 Stochastic 指标信号线已经向上穿越临界水平 20 或 80。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBC_WS_Stoch::LongCondition()
  {
   int result=0;
//--- idx 可用于检测交易程序工作模式
//--- idx=0 - EA 在每个即时价格都检查交易条件
//--- idx=1 - EA 仅在每个新柱线建立时检查交易条件
   int idx   =StartIndex();
//--- 检查开多单条件
//--- 3 白兵形态形状及信号线<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) && (StochSignal(1)<30))
     result=80;
//--- 检查平空仓条件
//--- 信号线交叉超买/超卖 (下穿 20, 上穿 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- 返回结果
   return(result);
  }

2.2. 开空单/平多仓

1. 这个 "3 乌鸦" 形态的形状必须由 Stochastic 指标确认：StochSignal(1)>70 （最后完整的 Stochastic 信号线值必须大于 70）。

2. 多单必须被平仓如果 Stochastic 指标信号线已经向下穿越临界水平 80 或 20。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBC_WS_Stoch::ShortCondition()
  {
   int result=0;
//--- idx 可用于检测交易程序工作模式
//--- idx=0 - EA 在每个即时价格都检查交易条件
//--- idx=1 - EA 仅在每个新柱线建立时检查交易条件
   int idx   =StartIndex();
//--- 检查开空单条件
//--- 3 乌鸦形态形状及信号线>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) && (StochSignal(1)>70))
     result=80;
//--- 检查平多仓条件
//--- 信号线交叉超买/超卖 (下穿 80, 上穿 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- 返回结果
   return(result);
  }

2.3. 使用 MQL5 向导创建交易程序

为创建交易程序，启动 MQL5 向导:

图例. 4. 使用 MQL5 向导创建交易程序

为交易程序起个特别名称：

图例. 5. 交易程序的一般属性

之后我们要选择交易信号将会使用的模块。

图例. 6. 交易程序的信号属性

在我们的案例中，我们仅使用交易信号的一个模块。

加入 "基于 3 乌鸦/3 白兵 信号 由 Stochastic 指标确认" 信号模块：

图例. 7. 交易程序的信号属性

交易信号模块被加入：

图例. 8. 交易程序的信号属性

您可以选择任何移动属性，但是我们选择 "不使用移动止损"：

图例. 9. 交易程序的移动属性

关注资金管理属性，我们将使用 "固定手数交易"：

图例. 10. 交易程序的资金管理属性

通过点击 "完成" 按钮，我们将会得到生成的交易程序代码，名为 Expert_ABC_WS_Stoch.mq5, 它会被保存在 客户端目录\MQL5\Experts\。

交易程序生成的省缺输入参数：

//--- 主信号线输入参数
input int            Signal_ThresholdOpen   =10;     // 开单信号阀值 [0...100]
input int            Signal_ThresholdClose  =10;     // 平单信号阀值 [0...100]
input double         Signal_PriceLevel      =0.0;    // 执行订单价位
input double         Signal_StopLevel       =50.0;   // 止损位 (点数)
input double         Signal_TakeLevel       =50.0;   // 止盈位 (点数)

必须替换为：

//--- 主信号线输入参数
input int            Signal_ThresholdOpen   =40;     // 开单信号阀值 [0...100]
input int            Signal_ThresholdClose  =20;     // 平单信号阀值 [0...100]
input double         Signal_PriceLevel      =0.0;    // 执行订单价位
input double         Signal_StopLevel       =0.0;    // 止损位 (点数)
input double         Signal_TakeLevel       =0.0;    // 止盈位 (点数)

这个 Signal_ThresholdOpen/Signal_ThresholdClose 输入参数允许设置特殊的开、平单阀值。

在交易信号类 LongCondition() 和 ShortCondition() 方法的代码中，我们有固定的阀值：

• 开单: 80；
• 平仓: 40。
  

Signal_StopLevel 和 Signal_TakeLevel 输入参数的值设为 0，它意味着无需止盈、止损，仅当平仓条件为真时才会平仓。

2.4. 历史回测结果

我们来讨论交易程序基于历史数据的回测（EURUSD H1，测试周期：2010.01.01-2011.02.02, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5）。

创建交易程序时我们采用固定手数（固定交易手数, 0.1），移动止损算法未采用（不使用移动止损）。

图例. 11. 交易程序的测试结果，基于 3 乌鸦/3 白兵 + Stochastic""

最佳输入参数集合可借助 MetaTrader 5 客户端的 策略测试员 发现。

由 MQL5 向导创建的交易程序代码，附加在 expert_abc_ws_stoch.mq5。