Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 1207

[Vladpedro]

mql5 (хедж)

Как реализовать  алгоритм закрытия позиций по двум  условиям?

1 случай.  Если открыто 2 позиции, то закрыть ту где прибыль больше чем...   2 случай.  Если открыто 2 и более позиций, то закрыть по усреднению на значение...

Сейчас у меня закрытие таких позиций происходит по двум методам,

для 1 случая сравнение позиций по профиту и закрытие той, чей профит больше, для 2 случая  закрытие всех позиций по усреднению, по Эквити.

В отдельности эти методы хорошо работают, но вместе ни как,  из-за того что одно из двух событий попадает под раздачу обеих методов.

И у меня ни как их не получается развести. В результате оба случая закрываются преимущественно по Эквити с закрытием всех позиций. Это приводит к тому, что в первом случае удаляется нужная позиция и открывается заново.

В результате. Двойной спрэд, двойная комиссия. Это огорчает)))

Схема установки ордеров и позиций выглядит так:   Для SELL (и далее только для SELL)

Лимитный ордер. SELL_LIMIT

позиция.                  SELL   (всегда между ордерами)

Стоповый ордер.  SELL_STOP

Графическую схему прилагаю.

 Закрытие позиций.

1. если сработал стоповый ордер, то есть одновременно  появились две или более поз, то нужно закрыть одну позицию, ту чей  профит больше чем... (20)

2. если сработал лимитный ордер, то есть открыто одновременно две или более поз, то нужно закрыть их по усреднению (по эквити) на значение...(15)

 Вопрос. Как развести два этих метода, что бы они обрабатывали только своё событие?

Быть может есть какой то другой метод как обработать два этих условия?

Примеры используемых мной методов.

//+---------------------------------------------------------------------+
//|  -- ЗАКРЫВАЕМ ОДНУ ИЗ ДВУХ ПОЗИЦИЙ С НИЗУ, ГДЕ ПРОФИТ БОЛЬШЕ ЧЕМ ---|
//+---------------------------------------------------------------------+ 
ulong ticket_n=ULONG_MAX;  double profit=DBL_MIN;

     if(invert_close == true) //Проверка на наличие 2х и более поз.
     {
     int positions=PositionsTotal();
     for(int i=PositionsTotal()-1; i>=0; i--)
     {
     ulong tmp_ticket=PositionGetTicket(i);
     if(ticket_n!=0)
     {
     double tmp_profit=PositionGetDouble(POSITION_PROFIT);
     if(tmp_profit>profit+Prof_eqw_niz)// допустим 20
     {
     ticket_n=tmp_ticket;
     profit=tmp_profit;
     }
     }
     }
//-----------
     if(ticket_n!=ULONG_MAX)
     m_trade.PositionClose(ticket_n);
     invert_close = false;
     Print("------  ЗАКРЫЛИ ТОЛСТУЮ ---------");
     }       

//+---------------------------------------------------------------------+
//|                     Э К В И Т И   ДЛЯ SELL_LIMIT                    |
//+---------------------------------------------------------------------+
   npos_ALL=0; NPos_ALL(npos_ALL);
   if (npos_ALL>=Metod_Eqw && m_account.Equity()>= m_account.Balance()+Prof_eqw)//Допустим 15
   {
   CloseAllPositions();
   Print("------  ЗАКРЫЛИ ВСЕ ---------");
   }

[Vladimir Karputov]

Vladpedro:

Позиции открываются по символу на котором работает советник? Magic number используется?

[Vladpedro]

Vladimir Karputov:
Позиции открываются по символу на котором работает советник? Magic number используется

Да, по текущему символу.  Да магик используется.

[Vladimir Karputov]

Vladpedro:

Да, по текущему символу.  Да магик используется.

Объясните второе условие, что это значит? (Если открыто 2 и более позиций, то закрыть по усреднению на значение...)

[Vladpedro]

Vladimir Karputov:

Объясните второе условие, что это значит? (Если открыто 2 и более позиций, то закрыть по усреднению на значение...)

Это значит:  Если открыто две или более позиций и сумма по Эквити больше баланса на какое то значение, (допустим 15) то закрываются все позиции. 

Например. открылись три позиции.  на первой текущий убыток -10, на второй -5, на третей профит +30 в сумме +15 можно закрывать все. 

Если усреднённый профит + 15 не был достигнут, то позиции закроются по своим собственным предустановленным  SL или ТР. (это вроде как третье условие закрытия позиций, но с ним проблем не возникает, по тому я о нём умолчал.)

[Vladimir Karputov]

Vladpedro:

Это значит:  Если открыто две или более позиций и сумма по Эквити больше баланса на какое то значение, (допустим 15) то закрываются все позиции. 

Например. открылись три позиции.  на первой текущий убыток -10, на второй -5, на третей профит +30 в сумме +15 можно закрывать все. 

Если усреднённый профит + 15 не был достигнут, то позиции закроются по своим собственным предустановленным  SL или ТР. (это вроде как третье условие закрытия позиций, но с ним проблем не возникает, по тому я о нём умолчал.)

Вот полный код для двух условий:

//+------------------------------------------------------------------+
//|                                       Closing Two conditions.mq5 |
//|                              Copyright © 2020, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020, Vladimir Karputov"
#property version   "1.00"
/*
   barabashkakvn Trading engine 3.116
*/
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
//---
CPositionInfo  m_position;                   // object of CPositionInfo class
CTrade         m_trade;                      // object of CTrade class
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
//--- input parameters
input double   InpProfitTarget      = 15;       // Profit target, in deposit money (if Positions > 2)
input ulong    InpDeviation         = 10;       // Deviation, in points (1.00045-1.00055=10 points)
input ulong    InpMagic             = 200;      // Magic number
//---
bool     m_need_close_all           = false;    // close all positions
ulong    m_need_close_ticket        = ULONG_MAX;// close one position
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
//---
   m_trade.SetExpertMagicNumber(InpMagic);
   m_trade.SetMarginMode();
   m_trade.SetTypeFillingBySymbol(m_symbol.Name());
   m_trade.SetDeviationInPoints(InpDeviation);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(m_need_close_all)
     {
      if(IsPositionExists())
        {
         CloseAllPositions();
         return;
        }
      else
         m_need_close_all=false;
     }
//---
   if(m_need_close_ticket!=ULONG_MAX)
     {
      //--- close one position
      if(m_position.SelectByTicket(m_need_close_ticket))
        {
         m_trade.PositionClose(m_need_close_ticket); // close a position
         return;
        }
      else
         m_need_close_ticket=ULONG_MAX;
     }
//--- calculate all positions
   int total=0;
   for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            total++;

   if(total==2)
     {
      //--- conditon 1
      ulong tmp_ticket=ULONG_MAX;
      double tmp_profit=DBL_MIN;
      for(int i=PositionsTotal()-1; i>=0; i--)
         if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
            if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
              {
               double profit=m_position.Commission()+m_position.Swap()+m_position.Profit();
               if(profit>tmp_profit)
                 {
                  tmp_profit=profit;
                  tmp_ticket=m_position.Ticket();
                 }
              }
      //---
      if(tmp_ticket!=ULONG_MAX)
         m_need_close_ticket=tmp_ticket;
     }
   else
     {
      if(total>2)
        {
         //--- conditon 2
         double profit=0;
         for(int i=PositionsTotal()-1; i>=0; i--)
            if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
               if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
                  profit+=m_position.Commission()+m_position.Swap()+m_position.Profit();
         //---
         if(profit>=InpProfitTarget)
            m_need_close_all=true;
        }
     }
  }
//+------------------------------------------------------------------+
//| Is position exists                                               |
//+------------------------------------------------------------------+
bool IsPositionExists(void)
  {
   for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            return(true);
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Close all positions                                              |
//+------------------------------------------------------------------+
void CloseAllPositions(void)
  {
   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            m_trade.PositionClose(m_position.Ticket()); // close a position by the specified m_symbol
  }
//+------------------------------------------------------------------+

[Vladpedro]

Vladimir Karputov:

Вот полный код для двух условий:

Спасибо Владимир. попытаюсь разобраться.

Я пытался решить это по своему, я понимаю как можно развести два этих условия.

Например.

Объявим три логические переменные.

Поз_1;

Поз_2_Clos_1;

Поз_2_Clos_All;

1. Проводим проверку на количество открытых позиций.

Если у  нас открыта только 1 позиция SELL присваиваем  значение: 

Поз_1=true;    Поз_2_Clos_1=false;      Поз_2_Clos_All=false;

Если открыто 2 позиции и сумма по эквити положительная (это может возникнуть только при срабатывания ордера SELL_STOP) то присваиваем этому событию логическое значение

Поз_1=false;    Поз_2_Clos_1=true;      Поз_2_Clos_All=false;

Если открыто 2 позиции и сумма по эквити отрицательная (это может возникнуть только при срабатывания ордера SELL_LIMIT) то

Поз_1=false;    Поз_2_Clos_1=false;      Поз_2_Clos_All=true;

Вот вроде бы и всё...  Можно запускать проверку на логические переменные и назначать им свой метод закрытия, но у меня почему то это не сработало...

Программист то я пока никудышный, возможно где то ошибся...

Спасибо за помощь)

[Vladpedro]

Vladimir Karputov:

Владимир.  Что то у меня не получается.  При срабатывании SELL_STOP ордеров - всё в порядке.  Закрывается только одна позиция, у которой профит больше,

а вот при срабатывании SELL_LIMIT закрытие происходит неправильно, не по сумме профита всех открытых позиций, а похоже закрывается позиция, у которой профит больше.

У меня до этого была схожая ошибка.  Сейчас уже начинаю думать, что возможно это у меня какой то косяк, может я как то не так считаю позы и открываю их.

Посмотрите пожалуйста мой готовый к проверке кусок кода, может увидите ошибку.  Но возможно и в Вашем коде несоответствие условиям.  Или я их как то не так объяснил.., что такое для меня усреднённый профит.

Я сейчас начал разбираться с алгоритмом и понял, что он несколько сложнее в последствиях чем я сказал Вам ранее.

Третье условие закрытия позиции по собственному SL возможно приводит к ошибкам в алгоритме первых двух первых условий.

Я ещё раз опишу полный алгоритм закрытия позиций только для случая SELL_LIMIT, так как случай SEL_STOP выполняется как надо. Оставим его пока.

1. У нас изначально есть одна открытая позиция SELL у неё установлен свой SL но он стоит выше чем SELL_LIMIT, а это значит что SL не сработает раньше, чем SELL_LIMIT. 

2. Сработал SELL_LIMIT и появилась вторая позиция SELL со своим SL, который так же не сможет сработать раньше чем очередной SELL_LIMIT

3. Если ордер SELL_LIMIT сработал, то устанавливается новый ордер SELL_LIMIT. (всегда)

4. Количество открытых позиций SELL может быть 1-3 и больше, всё зависит от того, как далеко стоят их SL. Рассмотрим случай если их максимум три. (я могу это ограничить SL)

Теперь сценарии закрытия позиций.

Если открытых поз. 2, то возможны только два сценария закрытия одной или всех позиций

1. По Эквити, если он больше баланса на 15 (закрываются все позиции), (m_account.Equity()>= m_account.Balance()+15) Я это имел ввиду закрыть несколько поз. по усреднению. 

2. По собственному SL (закрывается одна позиция). 

3. Оставшаяся одна позиция, теперь должна быть очищена от условий закрытия если они были заданы ранее,  так как мы не знаем  какое условие к ней применить.

Она может повторить сценарий  SELL_LIMIT или же спуститься к SEL_STOP и пойти по другому условию закрытия.  (обнуляем для неё условия)

4. Если позиций было три, то так же закрываем их  (m_account.Equity()>= m_account.Balance()+15) или у одной из них сработает SL и останется две позиции.

Применяем это правило, до тех пор пока не останется одна позиция, у которой условия закрытия не определены...

[Vladimir Karputov]

Vladpedro:

Vladimir Karputov:

Владимир.  Что то у меня не получается.  При срабатывании SELL_STOP ордеров - всё в порядке.  Закрывается только одна позиция, у которой профит больше,

а вот при срабатывании SELL_LIMIT закрытие происходит неправильно, не по сумме профита всех открытых позиций, а похоже закрывается позиция, у которой профит больше.

У меня до этого была схожая ошибка.  Сейчас уже начинаю думать, что возможно это у меня какой то косяк, может я как то не так считаю позы и открываю их.

Посмотрите пожалуйста мой готовый к проверке кусок кода, может увидите ошибку.  Но возможно и в Вашем коде несоответствие условиям.  Или я их как то не так объяснил.., что такое для меня усреднённый профит.

Вообще без разницы какой отложенный ордер сработал - ведь в итоге получаем позицию и далее считаем прибыль позиции.

[Vladpedro]

Vladimir Karputov:

Вообще без разницы какой отложенный ордер сработал - ведь в итоге получаем позицию и далее считаем прибыль позиции

Да без разницы. У меня возникло подозрение в разнице, потому что я при выставлении ордеров и позиций присваивал им "коменты" для позиций свои, для ордеров свои. В результате когда ордер переходит в позицию он наследует коментарий ордера.

Потом при проверке позиций через комментарии  возникла путаница... комментарии то у них разные получились.  Ну это я поправил.

У Вас в коде, я вообще не нашёл или не понял, как закрываются позиции для условия сработал SELL_LIMIT.  по Эквити. 

if(total==2)
   {
//-------------------------------------------------------- conditon 1
      ulong tmp_ticket=ULONG_MAX;
      double tmp_profit=DBL_MIN;
      for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
      if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
      {
      double profit=m_position.Commission()+m_position.Swap()+m_position.Profit();
      if(profit>tmp_profit)
      {
      tmp_profit=profit;
      tmp_ticket=m_position.Ticket();
      }
      }
      //---
      if(tmp_ticket!=ULONG_MAX)
      m_need_close_ticket=tmp_ticket;
      }
      else
      {
      if(total==2)
        {
//--------------------------------------------------------- conditon 2
        double profit=0;
        for(int i=PositionsTotal()-1; i>=0; i--)
        if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
        if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
        profit+=m_position.Commission()+m_position.Swap()+m_position.Profit();
//--------
       if(profit>=InpProfitTarget)
        m_need_close_all=true;
        }
        }

Вроде бы выполнено проверка на возможность закрытие всех позиций и установлен по ней флаг

но в блоке CloseAllPositions();  

if(m_need_close_all)
   {
   if(IsPositionExists())
   {
   CloseAllPositions();
   return;
   }
   else
   m_need_close_all=false;
   }

отсутствует что то типа. 

 if(m_account.Equity()>= m_account.Balance()+15)

По которому нужно закрыть все позиции для случая - сработал сработал SELL_LIMIT

Возможно у Вас это же m_account.Equity()>= m_account.Balance()+15 реализовано как то иначе?

Или оно у Вас действительно не выполняется?  Быть может из-за того что я не так объяснил что такое усреднение в моём понимании.