В MQL5 позиция формируется после срабатывания ордера, важно подождать подтверждения.

fxsaber 2019.07.21 22:29 #10981

Artyom Trishkin:

Да, бывало.

Интересны сценарии.

Artyom Trishkin 2019.07.21 22:34 #10982

fxsaber:

Интересны сценарии.

Давно не торгую. Прям д а в н о.

Но было на робофорекс, что после отправки запроса на сервер советник тупо висел в ожидании реквоты, и ничегошеньки уже не делал. А хотелось и на другом символе работать.

Чемпионат Automated Trading Championship То работает, то не Любые вопросы новичков по

fxsaber 2019.07.21 22:42 #10983

Artyom Trishkin:

было на робофорекс, что после отправки запроса на сервер советник тупо висел в ожидании реквоты, и ничегошеньки уже не делал. А хотелось и на другом символе работать.

Это называется несколько независимых логик в одном советнике. Народ такие по разным чартам разбрасывает.

Artyom Trishkin 2019.07.21 22:45 #10984

fxsaber:

Это называется несколько независимых логик в одном советнике. Народ такие по разным чартам разбрасывает.

В одном всё было. Случай когда чиф с ума сошёл когда его отвязали от доллара. Пришлось по другим символам руками работать. Но из возможного профита смог словить только 60 долларов. Не висел бы советник в ожидании реквоты - раза в три больше бы словил скорее всего.

Машинное обучение в трейдинге: Напишу советник бесплатно Ошибки, баги, вопросы

EgorKim 2019.07.22 07:10 #10985

Не получается получить данные индикатора со старшего таймфрейма из советника.

2019.07.22 07:23:02.556 Core 1  2017.10.05 07:00:00   Не удалось скопировать значения индикатора. Error =4806,  copied =-1

Причем при оптимизации работает. Начинаешь запускать в визуализаторе вываваливается эта ошибка.

Что не так с индикатором ?

Файлы:

ind.mq5 11 kb

Vladimir Karputov 2019.07.22 08:55 #10986

EgorKim:

Не получается получить данные индикатора со старшего таймфрейма из советника.

Причем при оптимизации работает. Начинаешь запускать в визуализаторе вываваливается эта ошибка.

Что не так с индикатором ?

А код советника где?

Вероятная причина - в пути где лежит индикатор (прописанный путь к индикатору в советнике через iCustom). Также в одной папке должен быть и mq5 и ex5 файл индикатора.

Vladimir Karputov 2019.07.22 09:08 #10987

EgorKim:

Не получается получить данные индикатора со старшего таймфрейма из советника.

Причем при оптимизации работает. Начинаешь запускать в визуализаторе вываваливается эта ошибка.

Что не так с индикатором ?

Итак, Ваш индикатор находится в папке [date folder]\MQL5\Indicators\ind.mq5 , там же лежит и скомпилированный файл.

Пример советника, который обращается в индикаторному буферу "0" - "Means":

//+------------------------------------------------------------------+
//|                                                         Test.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.00"
//--- input parameters
input int      Input1=9;
//---
int    handle_iCustom;              // variable for storing the handle of the iCustom indicator /*
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create handle of the indicator iCustom
   handle_iCustom=iCustom(Symbol(),Period(),"ind");
//--- if the handle is not created 
   if(handle_iCustom==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code 
      PrintFormat("Failed to create handle of the iCustom indicator for the symbol %s/%s, error code %d",
                  Symbol(),
                  EnumToString(Period()),
                  GetLastError());
      //--- the indicator is stopped early 
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   double means[];
   ArraySetAsSeries(means,true);
   int start_pos=0,count=3;
   if(!iGetArray(handle_iCustom,0,start_pos,count,means))
      return;

   string text="Means:"+"\n";
   for(int i=count-1;i>=0;i--)
     {
      text=text+"#"+IntegerToString(i)+": "+DoubleToString(means[i],Digits())+"\n";
     }
   Comment(text);
  }
//+------------------------------------------------------------------+
//| Get value of buffers                                             |
//+------------------------------------------------------------------+
double iGetArray(const int handle,const int buffer,const int start_pos,const int count,double &arr_buffer[])
  {
   bool result=true;
   if(!ArrayIsDynamic(arr_buffer))
     {
      Print("This a no dynamic array!");
      return(false);
     }
   ArrayFree(arr_buffer);
//--- reset error code 
   ResetLastError();
//--- fill a part of the iBands array with values from the indicator buffer
   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);
   if(copied!=count)
     {
      //--- if the copying fails, tell the error code 
      PrintFormat("Failed to copy data from the indicator, error code %d",GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated 
      return(false);
     }
   return(result);
  }
//+------------------------------------------------------------------+