Хорошие индикаторы по теории Демарка

Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий
Forex Trader
114496
Forex Trader  
HELP! Помогите переписать под МТ4..

http://forum.viac.ru/viewtopic.php?t=2966
Forex Trader
114496
Forex Trader  
Вы знаете сколько есть "хороших" индикаторов?
Но к сожалению ВСЕ они не работают ... :))
Forex Trader
114496
Forex Trader  
HELP! Помогите переписать под МТ4..

http://forum.viac.ru/viewtopic.php?t=2966


Я не зарегистрирован на виаке, отвечу тут (если модератор не против).
1. Поставь закрывающие скобки во всех if (после условий).
2. Что за команда "for n = shiftofMaximum[1,1]; "? Как выглядит в оригинале? И что за бесконечный цикл далее?
Forex Trader
114496
Forex Trader  
Евгений, я не программист, поэтому затрудняюсь ответить на твои вопросы. Я просто брал одинаковые индикаторы для МТ3 и МТ4 и по образу и подобию пытался переписать ниже представленный.



/*[[
Name := DMTrendLines&PricesUp
Author := Copyright © 2003, Company
Link := http://www.company.com/
Separate Window := No
First Color := Blue
First Draw Type := Line
First Symbol := 217
Use Second Data := No
Second Color := Red
Second Draw Type := Line
Second Symbol := 218
]]*/

Variable : shift(0);
Variable : KUp(0), BUp(0), n(0),MinPrice(0),TargetPriceUp(0);
Array : TrendPriceUp[2,1](0);
Arrays : Maximum[2,1](0), TimeofMaximum[2,1](0), shiftofMaximum[2,1](0);

SetLoopCount(0);
// loop from first bar to current bar (with shift=0)
For shift = Bars-1 Downto 1 Begin
{

TrendPriceUp[1,1] = TrendPriceUp[2,1];

TrendPriceUp[2,1] = KUp*(shift) + BUp;
SetIndexValue(shift, TrendPriceUp[2,1]);

If High[shift] > High[shift - 1] AND High[shift] >= High[shift + 1]
Then {Maximum[1,1] = Maximum[2,1]; TimeofMaximum[1,1] = TimeofMaximum[2,1];
shiftofMaximum[1,1] = shiftofMaximum[2,1];
shiftofMaximum[2,1] = shift;
Maximum[2,1] = High[shift];
TimeofMaximum[2,1] = Time[shift];

KUp = (Maximum[2,1]-Maximum[1,1])/(shiftofMaximum[2,1]-shiftofMaximum[1,1]);
BUp = Maximum[1,1] - KUp*shiftofMaximum[1,1];

TrendPriceUp[2,1] = KUp*(shift) + BUp;

If Maximum[1,1] >= Maximum[2,1]
Then {For n = shiftofMaximum[1,1] DownTo shiftofMaximum[2,1] Begin
{
TrendPriceUp[2,1] = KUp*(n) + BUp;
SetIndexValue(n, TrendPriceUp[2,1]);
};
End;

MoveObject("UpTrend", OBJ_TRENDLINE, TimeofMaximum[1,1], Maximum[1,1], TimeofMaximum[2,1], Maximum[2,1], Blue, 1, STYLE_SOLID);
};
};

If Close[shift] > TrendPriceUp[2,1] AND Close[shift+1] <= TrendPriceUp[1,1]
AND TrendPriceUp[1,1] >= TrendPriceUp[2,1]
Then {MinPrice = Low[Lowest(MODE_LOW, shiftofMaximum[1,1], shiftofMaximum[1,1] - shift)];
TargetPriceUp = (TrendPriceUp[2,1] - MinPrice) + TrendPriceUp[2,1];

MoveObject("TargetPriceUp"+Mod(shift,1), OBJ_HLINE, TimeofMaximum[1,1], TargetPriceUp, TimeofMaximum[2,1], TargetPriceUp, Blue, 1, STYLE_DOT);

};
};
End;
Forex Trader
114496
Forex Trader  
/*[[
Name := DMTrendLines&PricesDown
Author := Copyright © 2003, Company
Link := http://www.company.com/
Separate Window := No
First Color := Red
First Draw Type := Line
First Symbol := 217
Use Second Data := No
Second Color := Red
Second Draw Type := Line
Second Symbol := 218
]]*/

Variable : shift(0);
Variable : KDown(0), BDown(0), MaxPrice(0),TargetPriceDown(0),n(0);
Array : TrendPriceDown[2,1](0);
Arrays : Minimum[2,1](0), TimeofMinimum[2,1](0), shiftofMinimum[2,1](0);

SetLoopCount(0);
// loop from first bar to current bar (with shift=0)
For shift = Bars - 1 DownTo 1 Begin
{
TrendPriceDown[1,1] = TrendPriceDown[2,1];

TrendPriceDown[2,1] = KDown*(shift) + BDown;
SetIndexValue(shift, TrendPriceDown[2,1]);

If Low[shift] < Low[shift - 1] AND Low[shift] <= Low[shift + 1]
Then {Minimum[1,1] = Minimum[2,1]; TimeofMinimum[1,1] = TimeofMinimum[2,1];
shiftofMinimum[1,1] = shiftofMinimum[2,1];
shiftofMinimum[2,1] = shift;
Minimum[2,1] = Low[shift];
TimeofMinimum[2,1] = Time[shift];

KDown = (Minimum[2,1]-Minimum[1,1])/(shiftofMinimum[2,1]-shiftofMinimum[1,1]);
BDown = Minimum[1,1] - KDown*shiftofMinimum[1,1];

TrendPriceDown[2,1] = KDown*(shift) + BDown;

If Minimum[1,1] <= Minimum[2,1]
Then {For n = shiftofMinimum[1,1] DownTo shiftofMinimum[2,1] Begin
{
TrendPriceDown[2,1] = KDown*(n) + BDown;
SetIndexValue(n, TrendPriceDown[2,1]);
};
End;

MoveObject("DownTrend", OBJ_TRENDLINE, TimeofMinimum[1,1], Minimum[1,1], TimeofMinimum[2,1], Minimum[2,1], Red, 1, STYLE_SOLID);
};
};

If Close[shift] < TrendPriceDown[2,1] AND Close[shift+1] >= TrendPriceDown[1,1]
AND TrendPriceDown[1,1] <= TrendPriceDown[2,1]
Then {MaxPrice = High[Highest(MODE_HIGH, shiftofMinimum[1,1], shiftofMinimum[1,1] - shift)];
TargetPriceDown = TrendPriceDown[2,1] - (MaxPrice - TrendPriceDown[2,1]);

MoveObject("TargetPriceDown"+Mod(shift,1), OBJ_HLINE, TimeofMinimum[1,1], TargetPriceDown, TimeofMinimum[2,1], TargetPriceDown, Red, 1, STYLE_DOT);

};

};
End;
Forex Trader
114496
Forex Trader  
Зайдите на паук - я там выкладывал рабочие индюки под МТ3 и МТ4 с кодамии и учетом квалификаторов пробоя. А то что написано здесь - даже не часть алгоритма. Где-то там есть и секвента.

Удачи.
Forex Trader
114496
Forex Trader  
Vladislav, VG и ты - одно лицо, насколько я понял?
Forex Trader
114496
Forex Trader  
Зайдите на паук - я там выкладывал рабочие индюки под МТ3 и МТ4 с кодамии и учетом квалификаторов пробоя. А то что написано здесь - даже не часть алгоритма. Где-то там есть и секвента.

Удачи.



Владислав, а что такое секвента?
Паук - это viac или иной форум ?
Ты не этот индюк имеешь ввиду: Ind-TD-DeMark-3-1? Если да, то они здорово отличаются, по крайней мере зрительно, соответственно, иначе интерпретируются.
Forex Trader
114496
Forex Trader  
VG у Пола - это я. Вот индикатор

//+------------------------------------------------------------------+
//|                                        TD_Points&Lines_mgtd1.mq4 |
//|                                           Vladislav Goshkov (VG) |
//|                                                      4vg@mail.ru |
//+------------------------------------------------------------------+
#property copyright "Vladislav Goshkov (VG)"
#property link      "4vg@mail.ru"

#property indicator_chart_window

extern int SetPoint=0;
extern int StepBack=0;
extern int Qw1=1;
extern int Qw2=1;
extern int Qw3=1;

int i=1,NP=0,D=0,
    iB_Up=0,iB_Dn=0,
    S1=0,
    S2=0,
    UpLev=0,
    DownLev=0,
    iP_Up=0,
    iP_Dn=0,
    value=0,
    CurPeriod=0,
    shift=0;

datetime  nTime=0;

double UpV=0,
       DownV=0,
       iP=0,
       target = 0,
       UpP[2]={0,0},
       DownP[2]={0,0},
       PP1=0,PP2=0,PP3=0;

int    DownBT[2]={0,0}, // Bar Time
       UpBT[2]={0,0},
       UpB[2]={0,0},    // Bar Num
       DownB[2]={0,0};
string buff_str = "";
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- TODO: add your code here
Comment(" ");   
ObjectDelete("TD_Up");
ObjectDelete("TD_Dn");
ObjectDelete("Target");
ObjectDelete("Break_Sig_Up");
ObjectDelete("Break_Sig_Dn");
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   //int    counted_bars=IndicatorCounted();
//---- TODO: add your code here
if ( (nTime!=Time[0]) || (CurPeriod!=Period()) ) {
   UpP[0] = 0;
   UpP[1] = 0;

//=================================================
//******** Поиск опорных точек предложения ********
//=================================================
   for(i=2+StepBack,D=2,NP=0; (NP<D)&&(i<Bars); i++) {//Begin
       if (High[i]!= High[i+1]) { 
          if( (High[i]>High[i+1] && High[i]>High[i-1] && High[i]>Close[i+2] ) 
              && High[i]> UpP[0] ) {
	     	 UpB[NP]  = i;
		    UpBT[NP] = Time[i];
		    UpP[NP]  = High[i];
		    NP++;
		    }
		  }

    if (High[i]== High[i+1])  { 
       if ( (High[i]>High[i+2] && High[i]>High[i-1] && High[i]>Close[i+3] ) && High[i]> UpP[0] ) {
	     	 UpB[NP]  = i;
		    UpBT[NP] = Time[i];
		    UpP[NP]  = High[i];
		    NP++;
		    }
		  }
     if(i == (Bars-2) ) {
	     	 UpB[NP]  = i;
		    UpBT[NP] = Time[i];
		    UpP[NP]  = High[i];
		    break;
		    }
     }//for(i=2+StepBack,D=2,NP=0; NP<D; ) {//End;

//=================================================
//********** Поиск опорных точек спроса ***********
//=================================================
   DownP[0] = 1000000000;
   DownP[1] = 1000000000;
   for(i=2+StepBack,D=2,NP=0; (NP<D)&&(i<Bars); i++) {//Begin
    if (Low[i]!= Low[i+1])  { 
       if ( (Low[i]<Low[i+1] && Low[i]<Low[i-1] && Low[i]<Close[i+2] ) && Low[i]< DownP[0] ){
	  	    DownB[NP] = i;
		    DownBT[NP]= Time[i];
		    DownP[NP] = Low[i];
		    NP++;
		    }
		  //i++;
		  };
    if (Low[i]== Low[i+1])  { 
       if ( (Low[i]<Low[i+2] && Low[i]<Low[i-1] && Low[i]<Close[i+3] ) && Low[i]< DownP[0] ){
	  	    DownB[NP] = i;
		    DownBT[NP]= Time[i];
		    DownP[NP] = Low[i];
		    NP++;
		    }
		  //i++;
		  };
     if (i == (Bars-2) ) { 
	  	    DownB[NP] = i;
		    DownBT[NP]= Time[i];
		    DownP[NP] = Low[i];
		    break;
		    };
     }//End;
     

UpV = (UpP[1]-UpP[0])/(UpB[0]-UpB[1]);
DownV = (DownP[1]-DownP[0])/(DownB[0]-DownB[1]);

//=================================================
//****       Рисуем  TD-линии                  ****
//=================================================
   buff_str = "TD_Up";
   if(ObjectFind(buff_str) == -1) {
      ObjectCreate(buff_str, OBJ_TREND, 0, UpBT[1], UpP[1],UpBT[0], UpP[0]);
      ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
      ObjectSet(buff_str, OBJPROP_COLOR, Blue);
      //ObjectMove(buff_str, 0, UpBT[1], UpP[1],UpBT[0], UpP[0]);
      }
   else {
      ObjectMove(buff_str, 1, UpBT[0], UpP[0]);
      ObjectMove(buff_str, 2, UpBT[1], UpP[1]);
      }

   buff_str = "TD_Dn";
   if(ObjectFind(buff_str) == -1) {
      ObjectCreate(buff_str, OBJ_TREND, 0, DownBT[1], DownP[1],DownBT[0], DownP[0]);
      ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
      ObjectSet(buff_str, OBJPROP_COLOR, Red);
      //ObjectMove(buff_str, 0, UpBT[1], UpP[1],UpBT[0], UpP[0]);
      }
   else {
      ObjectMove(buff_str, 1, DownBT[0], DownP[0]);
      ObjectMove(buff_str, 2, DownBT[1], DownP[1]);
      }

   CurPeriod = Period();
   nTime = Time[0];
   }//if (nTime <> Time[0]) {
//----
   target = 0;

	for( i=UpB[0]; i>=StepBack; i--){
	   if( (Close[i]>UpP[0]+UpV*(UpB[0]-i)) && (Close[i+1]<UpP[0]+UpV*(UpB[0]-(i+1))) ) {
		    iB_Up=i; 
		    iP=UpP[0]+UpV*(UpB[0]-i);
		    iP_Up = iP; 
		    S1=Lowest(NULL,0,MODE_LOW,UpB[1],i);
		    S2=Lowest(NULL,0,MODE_CLOSE,UpB[1],i);

	       PP1=iP+((UpP[1]+UpV*(UpB[1]-S1))-Low[S1]);
	       PP2=iP+((UpP[1]+UpV*(UpB[1]-S2))-Low[S2]);
          PP3=iP+((UpP[1]+UpV*(UpB[1]-S1))-Close[S1]);
		    if((Qw1!=0 && Close[2]>Close[1])
          || (Qw2!=0 && Open[0]> iP)
          || (Qw3!=0 && (Close[0]+(Close[0]-MathMin(Low[0],Close[1])))<iP) ) {
             target = (PP1+PP2+PP3)/3;
             buff_str = "Break_Sig_Up";
             if(ObjectFind(buff_str) == -1) {
                ObjectCreate(buff_str, OBJ_ARROW,0, Time[iB_Up], iP+2*Point );
                ObjectSet(buff_str, OBJPROP_ARROWCODE, 164);
                ObjectSet(buff_str, OBJPROP_COLOR, Red);
                }
             else {
                ObjectMove(buff_str, 0, Time[iB_Up], iP+2*Point );
                }
             }
		    }
	   }

   for( i=DownB[0]; i>=StepBack;i--) {
	   if( (Close[i]<DownP[0]+DownV*(DownB[0]-i)) && (Close[i+1]>DownP[0]+DownV*(DownB[0]-(i+1))) ) {
	       iB_Dn=i; 
		    iP=DownP[0]+DownV*(DownB[0]-i);
		    iP_Dn = iP;
		    S1=Highest(NULL,0,MODE_HIGH,DownB[1],i);
		    S2=Highest(NULL,0,MODE_CLOSE,DownB[1],i);

          PP1=iP-(High[S1]-(DownP[1]+DownV*(DownB[1]-S1)));
	       PP2=iP-(High[S2]-(DownP[1]+DownV*(DownB[1]-S2)));
	       PP3=iP-(Close[S1]-(DownP[1]+DownV*(DownB[1]-S1)));
    		 if((Qw1!=0 && Close[1]<Close[0] )
          || (Qw2!=0 && Open[0] < iP )
		    || (Qw3!=0 && (Close[0]+(Close[0]-MathMax(High[0],Close[1])))>iP) ) {
             target = (PP1+PP2+PP3)/3;
             buff_str = "Break_Sig_Dn";
             if(ObjectFind(buff_str) == -1) {
                ObjectCreate(buff_str, OBJ_ARROW,0, Time[iB_Dn], iP+2*Point );
                ObjectSet(buff_str, OBJPROP_ARROWCODE, 164);
                ObjectSet(buff_str, OBJPROP_COLOR, Blue);
                }
             else {
                ObjectMove(buff_str, 0, Time[iB_Dn], iP+2*Point );
                }
             }
 		    }
		}//for( i=DownB[1]; i>=StepBack;i--) {

   buff_str = "Target";
   if(ObjectFind(buff_str) == -1) {
      ObjectCreate(buff_str, OBJ_HLINE,0, Time[0], target );
      ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
      ObjectSet(buff_str, OBJPROP_COLOR, Blue);
      //ObjectMove(buff_str, 0, UpBT[1], UpP[1],UpBT[0], UpP[0]);
      }
   else {
      ObjectMove(buff_str, 0, Time[0], target );
      }



//----
   return(0);
  }
//+------------------------------------------------------------------+


Этот индикатор работает по точкам Демарка первого порядка - при желании легко модифицируется (если интересует как - на пауке были коды под МТ3 для этого индикатора и точек Демарка более высокого порядка. Ввиду отсутствия необходимости я те не переводил, но по аналогии там работы максимум на пару часов). Названый Вами индикатор тоже работает по точкам Демарка, при условии, что Вы не задавали там фракталы и прочая. Если Ваш индикатор работает не так, то его показания нельзя рассматривать с точки зрения рекомендаций Демарка - нужно проводить свои статистические исследования.
Секвента - установочный набор. Описано там же - "Технический Анализ - новая наука"
Форум Пола http://forex.kbpauk.ru/

Удачи.

Forex Trader
114496
Forex Trader  
Vladislav, спасибо за индикатор, посмотрю. Он в точности соответствует теории Демарка?

Те индикаторы, которые я здесь выложил, как я понимаю, написаны так. Находятся все TD-точки, не совершая их отбора и не проверяя на истинность. Расчет прорыва рассчитывается по одному из трех вариантов расчета. Я так и не смог понять, соответствует ли он теории Демарка.

Владислав, у меня огромная просьба. Я привык использовать эти индикаторы в своей работе. Напиши их, пожалуйста, на МТ4. Это по сути упрощенная версия теории Демарка. Если не трудно, с описанием операций, тогда я смог бы поэкспериментировать в доработке.

Я совсем чуть-чуть знаком с программированием в Editorе и не понимая некоторых операций в этих индикаторах мне не удается работать над их совершенствованием.
Forex Trader
114496
Forex Trader  
Vladislav, спасибо за индикатор, посмотрю. Он в точности соответствует теории Демарка?

Те индикаторы, которые я здесь выложил, как я понимаю, написаны так. Находятся все TD-точки, не совершая их отбора и не проверяя на истинность. Расчет прорыва рассчитывается по одному из трех вариантов расчета. Я так и не смог понять, соответствует ли он теории Демарка.

Владислав, у меня огромная просьба. Я привык использовать эти индикаторы в своей работе. Напиши их, пожалуйста, на МТ4. Это по сути упрощенная версия теории Демарка. Если не трудно, с описанием операций, тогда я смог бы поэкспериментировать в доработке.

Я совсем чуть-чуть знаком с программированием в Editorе и не понимая некоторых операций в этих индикаторах мне не удается работать над их совершенствованием.


В том, что Вы выложили неверный отбор ТД точек - верхняя линия может идти только сверху вниз, а нижняя снизу вверх. Так, что просто переписать будет неправильно, а искать ошибку в том алгоритме - желания не очень много, хотя примерно представляю где она может находиться. Работайте тем, что я выложил - он работает правильно. Да, если не срабатывают квалификаторы пробоя, то при пересечении линии ценой у Вас не появится значок пробоя (кружок с точкой внутри) и не будут проецироваться цели. Если это не удобно - вполне можно поправить код, чтобы цели рисовались всегда - просто в исходнике перенесите расчет и отрисовку целей за соответствующий иф.

Удачи.
Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий