Базовые индикаторы, применяемые к кастомному инструменту

Запуск индикатора на кастомном символе.

#include <Symbol.mqh> // https://www.mql5.com/ru/code/18855

void OnStart()
{
  const SYMBOL Symb(_Symbol + "_custom"); // Создали символ

  Symb = _Symbol; // Скопировали с основного символа все свойства и баровую историю - клон
  
  const int handle = iMA(Symb.Name, PERIOD_CURRENT, 1, 0, MODE_SMA, PRICE_CLOSE); // индикатор на кастомных данных
  
  double Buffer[];  
  const int Amount = CopyBuffer(handle, 0, 0, 1, Buffer);
  
  Print(Buffer[Amount - 1]);
}

В МТ5 у стандартных индикаторов можно указать цену или хэндл другого индикатора. Применится к нулевому буферу. 

Можно называть это костылем, но это штатный способ. ;-). На английском форуме ответили примерно то же самое. Но на великом и могучем конечно же можно обсудить более понятно и для Вас, и для нас.

Может эти классы подойдут?

Если это нужно сделать внутри своего индикатора, то проще всего сделать входной параметр bool CustomData, который сигналирует, вычислять ли кастомную дату (в нулевой буфер) или работать в нормальном режиме. Соответственно, в нормальном режиме вызывать iCustom самого себя с CusomData = true и полученный хэндл запихивать, куда хочется.

// МАшка на кастомных данных
#property indicator_separate_window 
#property indicator_buffers 1 
#property indicator_plots   1 

#property indicator_type1   DRAW_LINE 
#property indicator_color1  clrRed 
#property indicator_style1  STYLE_SOLID 
#property indicator_width1  1 

input bool CustomData = false; // true - кастомный режим для iCustom
input int MAPeriod = 1e3;      // Период МАшки

string GetMyName( void )
{
  const int Length = StringLen(TerminalInfoString(TERMINAL_DATA_PATH) + "\\MQL5\\Indicators\\");
  const string Path = MQLInfoString(MQL_PROGRAM_PATH);
  
  return(StringSubstr(Path, Length, StringLen(Path) - Length - 4));
}

double Buffer[];
const bool Init = SetIndexBuffer(0, Buffer, INDICATOR_DATA);

const int handleMA = CustomData ? INVALID_HANDLE
                                : iMA(NULL, PERIOD_CURRENT, MAPeriod, 0, MODE_SMA, iCustom(_Symbol, PERIOD_CURRENT, GetMyName(), true));

int OnCalculate( const int rates_total,      // размер входных таймсерий 
                 const int prev_calculated,  // обработано баров на предыдущем вызове
                 const datetime& time[],     // Time 
                 const double& open[],       // Open 
                 const double& high[],       // High 
                 const double& low[],        // Low 
                 const double& close[],      // Close 
                 const long& tick_volume[],  // Tick Volume 
                 const long& volume[],       // Real Volume 
                 const int& spread[] )       // Spread 
{
  if (CustomData)
    for (int i = prev_calculated; i < rates_total; i++)
      Buffer[i] = MathRand(); // Подготовили данные
  
  return(CustomData ? rates_total : prev_calculated + CopyBuffer(handleMA, 0, prev_calculated, rates_total - prev_calculated, Buffer));
}

Да, начал пробовать этот вариант, когда Вы еще без кода сообщение написали. Не знал, что такой вариант рекурсии возможен. То, что надо! Премного благодарен.

Всем спасибо за идеи.

Таким способом можно достать только нулевой буфер? Или я что-то не так делал?

Любой.

Сделай пожалуйста пример, что-то у меня CopyBuffer первого буфера даёт ошибку 4806 "Запрошенные данные не найдены".

Возможно, мы неправильно поняли друг друга. Это имел в виду

// МАшка на двух кастомных данных
#property indicator_separate_window 
#property indicator_buffers 2
#property indicator_plots   2 

#property indicator_type1   DRAW_LINE 
#property indicator_color1  clrRed 
#property indicator_style1  STYLE_SOLID 
#property indicator_width1  1 

#property indicator_type2   DRAW_LINE 
#property indicator_color2  clrYellow
#property indicator_style2  STYLE_SOLID 
#property indicator_width2  1 

input int CustomData = WRONG_VALUE; // Для кастомного режима iCustom
input int MAPeriod = 1e2;           // Период МАшки

string GetMyName( void )
{
  const int Length = StringLen(TerminalInfoString(TERMINAL_DATA_PATH) + "\\MQL5\\Indicators\\");
  const string Path = MQLInfoString(MQL_PROGRAM_PATH);
  
  return(StringSubstr(Path, Length, StringLen(Path) - Length - 4));
}

const bool FlagCustomData = (CustomData != WRONG_VALUE);

double Buffer0[], Buffer1[];
const bool Init = SetIndexBuffer(0, Buffer0, INDICATOR_DATA) && (!FlagCustomData) && SetIndexBuffer(1, Buffer1, INDICATOR_DATA);

const int handleMA0 = FlagCustomData ? INVALID_HANDLE
                                     : iMA(NULL, PERIOD_CURRENT, MAPeriod, 0, MODE_SMA, iCustom(_Symbol, PERIOD_CURRENT, GetMyName(), 0));
const int handleMA1 = FlagCustomData ? INVALID_HANDLE
                                     : iMA(NULL, PERIOD_CURRENT, MAPeriod, 0, MODE_SMA, iCustom(_Symbol, PERIOD_CURRENT, GetMyName(), 1));

int OnCalculate( const int rates_total,      // размер входных таймсерий 
                 const int prev_calculated,  // обработано баров на предыдущем вызове
                 const datetime& time[],     // Time 
                 const double& open[],       // Open 
                 const double& high[],       // High 
                 const double& low[],        // Low 
                 const double& close[],      // Close 
                 const long& tick_volume[],  // Tick Volume 
                 const long& volume[],       // Real Volume 
                 const int& spread[] )       // Spread 
{
  if (FlagCustomData)
    for (int i = prev_calculated; i < rates_total; i++)
      Buffer0[i] = MathRand() * (CustomData + 1); // Подготовили данные
  
  return(FlagCustomData ? rates_total : prev_calculated + MathMin(CopyBuffer(handleMA0, 0, prev_calculated, rates_total - prev_calculated, Buffer0),
                                                                  CopyBuffer(handleMA1, 0, prev_calculated, rates_total - prev_calculated, Buffer1)));
}

Стандартные индикаторы, конечно, считают только нулевые буферы в режиме хэндла. Поэтому для каждого буфера нужно делать свой хэндл.