Библиотеки: Expert - страница 13

Новый комментарий
 
fxsaber #:

Если есть проблема, прошу дать готовые mq5-файлы для воспроизведения.

#define MT4ORDERS_LIBRARY
#include "../../utils/MT4Orders.mqh" 
// #define REPORT_BROWSER      // Создание отчета с запуском браузера - требует разрешения DLL.
#define TESTER_CUSTOM // Запуск советника в пользовательском Тестере
#include "../../utils/fxsaber/Tester/Tester.mqh" // https://www.mql5.com/ru/code/24848

#define Bid SymbolInfoDouble(_Symbol, SYMBOL_BID)
#define Ask SymbolInfoDouble(_Symbol, SYMBOL_ASK)

#define KEY_B 66
#define KEY_S 83
#define KEY_C 67

input int In1 = 1;
input group "label1"
input double In2 = 2.0;
// 
void OnChartEvent( const int id, const long &lparam, const double &dparam, const string &sparam ) {
  if (id == CHARTEVENT_KEYDOWN) {
    switch ((int)lparam) {
    case KEY_B: // buy
      OrderSend(_Symbol, OP_BUY, 1, Ask, 100, 0, 0);
      break;
    case KEY_S: // sell
      OrderSend(_Symbol, OP_SELL, 1, Bid, 100, 0, 0);
      break;
    case KEY_C: // close
      for (int i = OrdersTotal() - 1; i >= 0; i--)
        if (OrderSelect(i, SELECT_BY_POS) && (OrderType() <= OP_SELL))
          OrderClose(OrderTicket(), OrderLots(), OrderClosePrice(), 100);
    }
  }
}


void OnTick() {
  //Print(_Symbol, " ", SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE));
}
void OnTimer() { /* Comment(REPORT::OrdersToString(_Symbol, 0, 5)); */ }
int OnInit() {
  Print(_Symbol, " ", SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE));
  Print(_Symbol, " In2 = ", In2);
  return(INIT_SUCCEEDED);
}
//
void OnDeinit( const int ) {}
//
void OnTradeTransaction(const MqlTradeTransaction& trans, const MqlTradeRequest& request, const MqlTradeResult& result) {

}
//+------------------------------------------------------------------+

В примере кода используется код вашей библиотеки Tester. После запуска переменная In2 равна 0, а не 2. То есть все входные параметры после группы не могут быть получены.
 
hini #:

Кажется, эта ситуация не рассматривается. Когда параметр является группой, конкретного значения нет, и полученное значение будет нулевым, поэтому параметры после группы не будут получены.

Следующий код показывает, что все обрабатывается правильно.

input int In1 = 1;
input group "label1"
input double In2 = 2.0;

#include <fxsaber\Expert.mqh> // https://www.mql5.com/ru/code/19003

int GetAmountExperts()
{
  int Res = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    Res += (ChartGetString(Chart, CHART_EXPERT_NAME) != "");
    
  return(Res);
}

void OnInit()
{
  if (GetAmountExperts() < 2)
  {
    MqlParam Params[];
    string Names[];
            
    const int Size = EXPERT::Parameters(0, Params, Names) - 1;
    
    ArrayPrint(Params);
    ArrayPrint(Names);
    
    for (uint i = Size; (bool)i--;)
      EXPERT::AddInputName(Params[i + 1], Names[i]);
            
    Params[Size].string_value = "7";
    EXPERT::Run(ChartOpen(_Symbol, _Period), Params);
  }
}


Результат.

    [type] [integer_value] [double_value]      [string_value]
[0]     14               0           0.00 "Scripts\Test6.ex5"
[1]     14               1           1.00 "1"                
[2]     14               0           0.00 null               
[3]     14               2           2.00 "2.0"              
"In1" null  "In2"


Запущенный через Expert.mqh советник.

  
input bool InRun = true;
input group "label1"
input double In2 = 2.0;

#include <fxsaber\Expert.mqh> // https://www.mql5.com/ru/code/19003


int GetAmountExperts()
{
  int Res = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    Res += (ChartGetString(Chart, CHART_EXPERT_NAME) != "");
    
  return(Res);
}

void OnInit()
{
  if (InRun)
  {
    MqlParam Params[];
    string Names[];
            
    const int Size = EXPERT::Parameters(0, Params, Names) - 1;
    
    ArrayPrint(Params);
    ArrayPrint(Names);
    int nameSize = ArraySize(Names);
    for (int i = nameSize-1; i >= 0; i--) {
      if (Names[i] == "InRun")
        Params[i+1].string_value = "false";
      EXPERT::AddInputName(Params[i + 1], Names[i]);
    }  
            
    ArrayPrint(Params);
    ArrayPrint(Names);
    //Params[Size].string_value = "7";
    EXPERT::Run(ChartOpen(_Symbol, _Period), Params);
    return;
  }
  Print("In2 = ", In2);
}

Функция GetAmountExperts по неизвестной причине выполняется очень долго без результата. Я немного изменил код - пожалуйста, запустите его снова. Не следует присваивать значение 7 параметру In2 (вы увидите, что там 0, а не 2).


 
hini #:

Я немного изменил код - пожалуйста, запустите его снова.

Это образцовый баг-репорт: запустил лаконичный код, который сразу показал ошибку.

Внес исправление, спасибо.

 
fxsaber #:

Это образцовый баг-репорт: запустил лаконичный код, который сразу показал ошибку.

Внес исправление, спасибо.

Ясно, в случае проблем буду оформлять отчёты в таком же формате.
 

Если скрипт загружен, похоже, что входные параметры изменить невозможно.

 //Test1.ex5
#property script_show_inputs
input string str = "test1" ;
//void OnInit() {
void OnStart () {
   Print (str);
}
 // Запуск советника с заданными входными параметрами
#property script_show_inputs

#include "Expert.mqh"

input bool CurrentChart = false ; // Запустить советник на текущем(true)/новом(false) чарте

string GetMyName( void ) {
   return ( StringSubstr ( MQLInfoString ( MQL_PROGRAM_PATH ), StringLen ( TerminalInfoString ( TERMINAL_DATA_PATH ) + "\\MQL5\\" )));
}

bool RunExpert( const long Chart ) {
   MqlParam Params[ 2 ];
  Params[ 0 ].string_value = "Experts\\Advisors\\Test1.ex5" ;
   // Первый входной параметр советника
  Params[ 1 ].type = TYPE_STRING ;
  Params[ 1 ].string_value = "Hello World!" ;
   return (EXPERT::Run(Chart, Params));
}

#define NAME __FILE__

void OnStart () {
   union UNION {
     double Double;
     long Long;
  } Chart;
   if (CurrentChart) {
    Chart.Long = ChartID ();
     GlobalVariableSet (NAME, Chart.Double);
     MqlParam Params[ 1 ];
     // Путь к себе (скрипт)
    Params[ 0 ].string_value = GetMyName();
     // На новом чарте запускаем себя
    EXPERT::Run( ChartOpen ( _Symbol , _Period ), Params);
  } else if ( GlobalVariableCheck (NAME)) {
    Chart.Double = GlobalVariableGet (NAME);
     GlobalVariableDel (NAME);
    RunExpert(Chart.Long);
     ChartClose ();
  } else // Проше всего запустить советник (с параметрами не по-умолчанию) не на текущем чарте
    RunExpert( ChartOpen ( _Symbol , _Period ));
}
//+------------------------------------------------------------------+
 
hini #:

Если скрипт загружен, похоже, что входные параметры изменить невозможно.

Такова архитектура MT5, что для скриптов нельзя задать значения входных параметров и нельзя их прочитать.

Библиотека имеет красноречивое название.

 
fxsaber #:

Такова архитектура MT5, что для скриптов нельзя задать значения входных параметров и нельзя их прочитать.

Библиотека имеет красноречивое название.

ok
 
Еще на тему фреймового режима, когда запускается оптимизация без задания интервалов оптимизации. 
#include <fxsaber\Expert.mqh> // https://www.mql5.com/ru/code/19003

input group "Params"
input int inRange1 = 0;
input double inRange2 = 0;

// Проверяет, заданы ли интервалы оптимизации.
bool OptimizationIsCorrect()
{
  bool Res = false;
  
  if (MQLInfoInteger(MQL_FRAME_MODE))
  {    
    MqlParam Parameters[];
    string Names[];

    EXPERT::Parameters(0, Parameters, Names);
  
    for (uint i = ArraySize(Names); !Res && (bool)i--;)
    {
      long S[4];
      
      ParameterGetRange(Names[i], Res, S[0], S[1], S[2], S[3]);
    }
  }
      
  return(Res);
}

void OnTesterInit()
{
  if (!OptimizationIsCorrect())
  {
    Alert("no optimized parameter selected, please check input(s) to be optimized and set start, step and stop values");
    
    ChartClose();
  }
}

void OnTesterDeinit() {}
Без такого решения остается висеть на чарте советник во фреймовом режиме. Особенно критично при автоматизации Тестера.
1...678910111213
Новый комментарий