Любые вопросы новичков по MQL4 и MQL5, помощь и обсуждение по алгоритмам и кодам - страница 3

Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий
mila.com
167
mila.com  
Artyom Trishkin:
Нужно глубже искать...

Глубже, это где?

Все попытки, с новым индикатором, приводят к зависанию.

А с индикатором, который без изменений, кратковременное торможение.

Какое может быть решение?

Artyom Trishkin
Модератор
43743
Artyom Trishkin  
mila.com:

Глубже, это где?

Все попытки, с новым индикатором, приводят к зависанию.

А с индикатором, который без изменений, кратковременное торможение.

Какое может быть решение?

В вашем индикаторе - вместо использования в нём данных других кастомных индикаторов, в частности - поиск фракталов любой размерности, просто сделать функции поиска таких фракталов и с ними работать.
mila.com
167
mila.com  
Artyom Trishkin:
просто сделать функции поиска таких фракталов и с ними работать.

Это для вас, просто сделать)

а для меня непосильная задача.

Вот такую функцию ?


bool isDnFractal(int bar,int max,const double &low[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && low[bar]>low[bar-i])    return(false);
      if(i<=rightSide && low[bar]>=low[bar+i])  return(false);
      }
//---
   return(true);
  }

Это нижний фрактал.

Как её использовать?

Artyom Trishkin
Модератор
43743
Artyom Trishkin  
mila.com:

Это для вас, проще сделать)

а для меня непосильная задача.

Как вживить функцию из того индикатора в мой?


bool isDnFractal(int bar,int max,const double &low[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && low[bar]>low[bar-i])    return(false);
      if(i<=rightSide && low[bar]>=low[bar+i])  return(false);
      }
//---
   return(true);
  }

Ну вам же нужно чтобы он возвращал цену фрактала на требуемом баре. Вот, накидал простенький индикатор. В нём есть две функции, которые вы можете вытащить их него, и использовать в своём - специально их как функции организовал - с проверками недопустимых значений.

//+------------------------------------------------------------------+
//|                                             iFreeNumFractals.mq4 |
//|              Copyright 2016, Artem A. Trishkin, Skype artmedia70 |
//|                       https://login.mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, Artem A. Trishkin, Skype artmedia70"
#property link      "https://login.mql5.com/ru/users/artmedia70"
#property version   "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpperFractal
#property indicator_label1  "UpperFractal"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot LowerFractal
#property indicator_label2  "LowerFractal"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrSteelBlue
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input          int      LeftNum=2;     // Количество баров слева
int leftNum;     // Количество баров слева
input          int      RightNum=2;    // Количество баров справа
int rightNum;    // Количество баров справа
//--- indicator buffers
double         BufferUpperFractal[];
double         BufferLowerFractal[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,BufferUpperFractal);
   SetIndexBuffer(1,BufferLowerFractal);
//--- setting a code from the Wingdings charset as the property of PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,159);
   PlotIndexSetInteger(1,PLOT_ARROW,159);
   SetIndexArrow(0,217);
   SetIndexArrow(1,218);
//---
   leftNum=(LeftNum<1?1:LeftNum);
   rightNum=(RightNum<1?1:RightNum);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   if(rates_total<leftNum+rightNum) return(0);
   int limit=rates_total-prev_calculated;
   if(limit>0) {
      ArrayInitialize(BufferUpperFractal,0.0);
      ArrayInitialize(BufferUpperFractal,0.0);
      limit=rates_total-leftNum-1;
      }
   //---
   for(int i=limit; i>rightNum; i--) {
      if(GetFreeUpperFractal(i,limit,high,leftNum,rightNum)>0) BufferUpperFractal[i]=high[i];
      if(GetFreeLowerFractal(i,limit,low ,leftNum,rightNum)>0) BufferLowerFractal[i]=low[i];
      }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+----------------------------------------------------------------------------+
double GetFreeLowerFractal(int shift,const int limit,const double &low[],int left_dimension=2,int right_dimension=2) {
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>limit-1) return(-1);
   for(int i=shift; i>shift-right_dimension; i--) if(low[i]>low[i-1]) return(-1);
   for(int i=shift; i<shift+left_dimension; i++)  if(low[i]>low[i+1]) return(-1);
   return(low[shift]);
}
//+----------------------------------------------------------------------------+
double GetFreeUpperFractal(int shift,const int limit,const double &high[],int left_dimension=2,int right_dimension=2) {
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>limit-1) return(-1);
   for(int i=shift; i>=shift-right_dimension; i--) if(high[i]<high[i-1]) return(-1);
   for(int i=shift; i<=shift+left_dimension; i++)  if(high[i]<high[i+1]) return(-1);
   return(high[shift]);
}
//+----------------------------------------------------------------------------+
Artyom Trishkin
Модератор
43743
Artyom Trishkin  

Чтобы совсем отвязать от индикатора функции получения произвольных фракталов, нужно не передавать в них по ссылке массивы high[] и low[] и значение limit, а получать требуемые значения тоже функциями.

Раз мы делаем код максимально приближенным к MQL5, то от функций High[], Low[], iHigh(), iLow() придётся отказаться, а получать нужные цены своими функциями. Вот так это будет выглядеть в этом же индикаторе:

//+------------------------------------------------------------------+
//|                                             iFreeNumFractals.mq4 |
//|              Copyright 2016, Artem A. Trishkin, Skype artmedia70 |
//|                       https://login.mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, Artem A. Trishkin, Skype artmedia70"
#property link      "https://login.mql5.com/ru/users/artmedia70"
#property version   "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpperFractal
#property indicator_label1  "UpperFractal"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot LowerFractal
#property indicator_label2  "LowerFractal"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrSteelBlue
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input          int      LeftNum=2;     // Количество баров слева
int leftNum;     // Количество баров слева
input          int      RightNum=2;    // Количество баров справа
int rightNum;    // Количество баров справа
//--- indicator buffers
double         BufferUpperFractal[];
double         BufferLowerFractal[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,BufferUpperFractal);
   SetIndexBuffer(1,BufferLowerFractal);
//--- setting a code from the Wingdings charset as the property of PLOT_ARROW
   // PlotIndexSetInteger(0,PLOT_ARROW,217);
   // PlotIndexSetInteger(1,PLOT_ARROW,218);
   SetIndexArrow(0,217);
   SetIndexArrow(1,218);
//---
   leftNum=(LeftNum<1?1:LeftNum);
   rightNum=(RightNum<1?1:RightNum);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   if(rates_total<leftNum+rightNum) return(0);
   int limit=rates_total-prev_calculated;
   if(limit>0) {
      ArrayInitialize(BufferUpperFractal,0.0);
      ArrayInitialize(BufferUpperFractal,0.0);
      limit=rates_total-leftNum-1;
      }
   //---
   for(int i=limit; i>rightNum; i--) {
      if(GetFreeUpperFractal(Symbol(),PERIOD_CURRENT,i,leftNum,rightNum)>0) BufferUpperFractal[i]=high[i];
      if(GetFreeLowerFractal(Symbol(),PERIOD_CURRENT,i,leftNum,rightNum)>0) BufferLowerFractal[i]=low[i];
      }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+----------------------------------------------------------------------------+
double GetFreeLowerFractal(const string symbol_name,ENUM_TIMEFRAMES timeframe,int shift,int left_dimension=2,int right_dimension=2) {
   int bars=Bars(symbol_name,timeframe);
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>bars-1) return(-1);
   for(int i=shift; i>shift-right_dimension; i--) if(GetPriceLow(symbol_name,timeframe,i)>GetPriceLow(symbol_name,timeframe,i-1)) return(-1);
   for(int i=shift; i<shift+left_dimension; i++)  if(GetPriceLow(symbol_name,timeframe,i)>GetPriceLow(symbol_name,timeframe,i+1)) return(-1);
   return(GetPriceLow(symbol_name,timeframe,shift));
}
//+----------------------------------------------------------------------------+
double GetFreeUpperFractal(const string symbol_name,ENUM_TIMEFRAMES timeframe,int shift,int left_dimension=2,int right_dimension=2) {
   int bars=Bars(symbol_name,timeframe);
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>bars-1) return(-1);
   for(int i=shift; i>=shift-right_dimension; i--) if(GetPriceHigh(symbol_name,timeframe,i)<GetPriceHigh(symbol_name,timeframe,i-1)) return(-1);
   for(int i=shift; i<=shift+left_dimension; i++)  if(GetPriceHigh(symbol_name,timeframe,i)<GetPriceHigh(symbol_name,timeframe,i+1)) return(-1);
   return(GetPriceHigh(symbol_name,timeframe,shift));
}
//+----------------------------------------------------------------------------+
double GetPriceHigh(const string symbol_name, ENUM_TIMEFRAMES timeframe, int shift){
   double array[1];
   if(CopyHigh(symbol_name,timeframe,shift,1,array)==1) return(array[0]);
   return(-1);
}
//+----------------------------------------------------------------------------+
double GetPriceLow(const string symbol_name, ENUM_TIMEFRAMES timeframe, int shift){
   double array[1];
   if(CopyLow(symbol_name,timeframe,shift,1,array)==1) return(array[0]);
   return(-1);
}
//+----------------------------------------------------------------------------+
Правда нужно ещё делать проверки на получение -1 из функций GetPriceHigh() и GetPriceLow()
strongflex
14
strongflex  
Добрый день подскажите как сделать чтобы советник используя 15 минутный тайм фрейм проверял значения каждые 20 минут допустим в 9-20, 9-40 следил за пересечением RSI и в случае пересечения уровня через двадцать минут проверял изменение цены. Вот то что мне нужно исправить:
if (Hour()==9 && (Minute() == 20) && (RSI>70))
Price2==Bid;
     {
      if (Hour()==9 && (Minute() == 40) && (Bid<Price2))
  
         {
          ticket=OrderSend(Symbol(),OP_SELL, Lts, Bid, SP,0,0, NULL, Magic, 0, Blue);
          return(0);
         }
     }

     
То есть допустим в 9-20 произошло пересечение RSI. Нужно чтобы советник запомнил цену в 9-20 и в 9-40 проверил как закрылись последние 20 минут относительно цены в 9-20. Если вниз то открывает шорт. За ранее благодарю
Artyom Trishkin
Модератор
43743
Artyom Trishkin  
strongflex:
Добрый день подскажите как сделать чтобы советник используя 15 минутный тайм фрейм проверял значения каждые 20 минут допустим в 9-20, 9-40 следил за пересечением RSI и в случае пересечения уровня через двадцать минут проверял изменение цены. Вот то что мне нужно исправить:
if (Hour()==9 && (Minute() == 20) && (RSI>70))
Price2==Bid;
     {
      if (Hour()==9 && (Minute() == 40) && (Bid<Price2))
  
         {
          ticket=OrderSend(Symbol(),OP_SELL, Lts, Bid, SP,0,0, NULL, Magic, 0, Blue);
          return(0);
         }
     }

     
То есть допустим в 9-20 произошло пересечение RSI. Нужно чтобы советник запомнил цену в 9-20 и в 9-40 проверил как закрылись последние 20 минут относительно цены в 9-20. Если вниз то открывает шорт. За ранее благодарю

:)

А если вы советник запустите в 9.22 ?

А если сбой системы или терминала? Цена-то потеряется запомненная.

Т.е., нужно искать то, что было 20 минут назад тогда, когда наступает время этой проверки. Наступило время, в котором минуты больше или равны кратно двадцати - проверили состояние RSI на баре, который был 20 минут назад. Если там есть нужное пересечение, то дальше действуем по плану...

Правда, на тф М15 точное время пересечения и точную цену вы не определите, но можно поглядеть цену на М1 - по крайней мере точнее в 15 раз.

strongflex
14
strongflex  
Artyom Trishkin:

:)

А если вы советник запустите в 9.22 ?

А если сбой системы или терминала? Цена-то потеряется запомненная.

Т.е., нужно искать то, что было 20 минут назад тогда, когда наступает время этой проверки. Наступило время, в котором минуты больше или равны кратно двадцати - проверили состояние RSI на баре, который был 20 минут назад. Если там есть нужное пересечение, то дальше действуем по плану...

Правда, на тф М15 точное время пересечения и точную цену вы не определите, но можно поглядеть цену на М1 - по крайней мере точнее в 15 раз.

Хорошо я так понял мне это не осилить))) ребят кто сможет написать эту часть кода? заплачу 1000 рублей
Alekseu Fedotov
1544
Alekseu Fedotov  
strongflex:
Хорошо я так понял мне это не осилить))) ребят кто сможет написать эту часть кода? заплачу 1000 рублей
double rci20 = iRSI(NULL,PERIOD_M1,14,PRICE_CLOSE,20);//RCI 20 минут назад.
   Comment("RSI = ",rci20);

И где тыща?

(шутка)

strongflex
14
strongflex  
Alekseu Fedotov:
double rci20 = iRSI(NULL,PERIOD_M1,14,PRICE_CLOSE,20);//RCI 20 минут назад.
   Comment("RSI = ",rci20);

И где тыща?

(шутка)

RSI нужен 15 минутный. Нужно чтобы советник проверял его каждые 20 минут с открытия рынка (9-00, 9-20, 9-40 и т.д.) допустим в 10-20 произошло пересечении снизу  вверх уровня 70 он запоминает цену и в 10-40 проверят если цена ниже чем в 10-20 он открывает шорт. 
Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий