イベントの流れ イベントの制御やアイドリングストップはどのように行うのですか？(+解決済み)

Yedelkin 2011.11.02 19:47 #51

sergeev:

そして、新しい質問はもうされましたか？

司会者が洪水を起こすのは適切ではありません。明確にすること。ユーザー（モデレーターを含む）がスレッドに新しい投稿を追加する場合、それを「返信」と呼ぶのが一般的です。たとえ、それが皮肉な内容の再質問であったとしても。

したがって、もう一度、明確にしておきます。もし、サーカスのようだと感じられたら、ご自由に削除していただくか、そのメリットについて新たにメッセージを出してみてください。一方、不正確な情報は、ユーザーに誤解を与える可能性があります。

追加すること。もし、ユーザーイベントが旧ルールに従ってキューを埋めることが公式に判明したら（判明するのを手伝ってくれたら）、私は真っ先にあなたに感謝します。

Rashid Umarov 2011.11.02 19:55 #52

Yedelkin:

追加します。カスタムイベントが旧ルールに従ってキューを埋めることが公式に判明したら（調べるのを手伝ってくれたら）、真っ先にお礼を言うよ。

大雑把に言えば、イベントの扱いが変わることはなかった。ただ、当初はヘルプの書き方が悪かっただけなんです。

Yedelkin 2011.11.02 19:57 #53

Rosh:
大雑把に言えば、イベントの扱いはこれまでと変わらない。もともとヘルプに正しく書かれていなかったというだけのことです。

ありがとうございます。それは残念なことです。だから、ハンドブックにある古いルールは間違っているのです。ご迷惑をおかけして申し訳ありません。

Anatoli Kazharski 2012.02.02 04:36 #54

sergeev:

...

もう、何事もなかったかのように、問題は発生しないのです。アレックス、時間があれば、オフィス内を見てくれないか？つまり、あなたのアドオンがある場合とない場合で、現在どのように動作するかということです。

--- 2012.02.02 06:52 #55

私は、各アプリケーションで作成したアイドルメッセージを積極的に利用しています。すべてがうまくいく。

Anatoli Kazharski 2012.02.02 07:04 #56

sergeev:

私は、各アプリケーションで作成したアイドルメッセージを積極的に利用しています。すべてがうまくいっている。

以前のように12文字ではなく、3文字のテストをするようになったので、問題がなくなったのかもしれません。依存関係がわかったら書きます。ありがとうございます。

Anatoli Kazharski 2012.02.19 21:14 #57

sergeev:

虫を捕まえてしまった。

Expert Advisor から自分自身に EventChartCustom イベントが送信されるために発生します。このイベントの送信により、メインウィンドウがチャートを更新する（ChartRedraw）ことが判明しました。

//---

このようなエキスパートを作って御社のソリューションをテストすると同時に、OBJ_EDIT オブジェクトの編集中に文字が超頻繁にちらつく問題の解決も試みました。

//---

//+------------------------------------------------------------------+
//|                                                 OnChartEvent.mq5 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2010, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
//---
long chart_id=0;
string OnOff_event_idle="On/Off event_idle++";
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   chart_id=ChartID();
//---
   if(!GlobalVariableCheck(OnOff_event_idle)) { GlobalVariableSet(OnOff_event_idle,1); }
//---
   Create_Edit(chart_id,0,"Edit_Area","HELLO",CORNER_LEFT_UPPER,"Arial",7,clrWhite,38,18,95,4,1,clrBlack);
   Create_Button(chart_id,0,"Start_event_idle","START event_idle++",ANCHOR_RIGHT_UPPER,CORNER_LEFT_UPPER,"Arial",8,clrWhite,clrFireBrick,clrNONE,130,26,4,28,1);
//---
   Comment("id: ",0,"\n",
           "event_idle++: ",event_idle
           );
//---
   return(0);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
   ObjectsDeleteAll(chart_id,-1,-1);
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
bool bidle=false;
ushort VM_IDLE=500;
ulong event_idle=0; // счётчик событий
//---
void OnChartEvent(const int     id,
                  const long   &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(GlobalVariableGet(OnOff_event_idle)==1)
     {
      if(id==CHARTEVENT_CUSTOM+VM_IDLE)
        {
         // Если последнее посланное больше, чем пришедшее, то сразу выходим
         if(event_idle>(ulong)lparam || bidle)
           {
            bidle=event_idle>(ulong)lparam;
            //---
            if(bidle) { return; }
            //---
            event_idle=0;
           }
         //---
         event_idle++; // увеличили счётчик событий
         //---
         Comment("id: ",id,"\n",
                 "event_idle++: ",event_idle
                 );
         //---
         EventChartCustom(chart_id,VM_IDLE,(long)event_idle,0,""); return; // отправили событие с указанием последнего счетчика
        }
      //---
      EventChartCustom(chart_id,VM_IDLE,(long)event_idle,0,""); // отправили событие с указанием последнего счетчика
     }
//+------------------------------------------------------------------+
//| СОБЫТИЕ_CHARTEVENT_CLICK                                         |
//+------------------------------------------------------------------+
   if(id==CHARTEVENT_CLICK)
     {
      Print("Reset. Event_idle: ",event_idle);
      //---
      event_idle=0;
      //---
      Comment("id: ",id,"\n",
              "event_idle++: ",event_idle
              );
     }
//+------------------------------------------------------------------+
//| СОБЫТИЕ_CHARTEVENT_OBJECT_CLICK                                  |
//+------------------------------------------------------------------+
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      if(sparam=="Edit_Area")
        {
         if((int)GlobalVariableGet(OnOff_event_idle)==0) { GlobalVariableSet(OnOff_event_idle,1); }
         if((int)GlobalVariableGet(OnOff_event_idle)==1) { GlobalVariableSet(OnOff_event_idle,0); }
        }
      //---
      if(sparam=="Start_event_idle")
        {
         if((int)GlobalVariableGet(OnOff_event_idle)==0) { GlobalVariableSet(OnOff_event_idle,1); ChartRedraw(); return; }
         if((int)GlobalVariableGet(OnOff_event_idle)==1) { GlobalVariableSet(OnOff_event_idle,0); ChartRedraw(); return; }
        }
     }
//+------------------------------------------------------------------+
//| CHARTEVENT_OBJECTS_ENDEDIT                                       |
//+------------------------------------------------------------------+
   if(id==CHARTEVENT_OBJECT_ENDEDIT)
     {
      if(ObjectGetInteger(chart_id,"Start_event_idle",OBJPROP_STATE)) { GlobalVariableSet(OnOff_event_idle,1); }
     }
  }
//+------------------------------------------------------------------+
//| СОЗДАНИЕ_ОБЪЕКТА_BUTTON                                          |
//+------------------------------------------------------------------+
void Create_Button(long   chrt_id,   // id графика
                   int    nmb_win,   // номер окна
                   string lable_nm,  // имя объекта
                   string rename,    // отображаемое имя
                   long   anchor,    // точка привязки
                   long   corner,    // угол привязки
                   string font_bsc,  // шрифт
                   int    font_size, // размер шрифта
                   color  font_clr,  // цвет шрифта
                   color  bg_color,  // цвет фона
                   color  brd_color, // цвет рамки
                   int    xsize,     // ширина
                   int    ysize,     // высота
                   int    x_dist,    // координата по шкале X
                   int    y_dist,    // координата по шкале Y
                   long   zorder)    // приоритет
  {
   if(ObjectCreate(chrt_id,lable_nm,OBJ_BUTTON,nmb_win,0,0)) // создание объекта
     {
      ObjectSetString(chrt_id,lable_nm,OBJPROP_TEXT,rename);             // установка имени
      ObjectSetString(chrt_id,lable_nm,OBJPROP_FONT,font_bsc);           // установка шрифта
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_COLOR,font_clr);         // установка цвета шрифта
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_BGCOLOR,bg_color);       // установка цвета фона
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_BORDER_COLOR,brd_color); // установка цвета фона
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_ANCHOR,anchor);          // установка точки привязки
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_CORNER,corner);          // установка угола привязки
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_FONTSIZE,font_size);     // установка размера шрифта
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_XSIZE,xsize);            // установка ширины X
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_YSIZE,ysize);            // установка высоты Y
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_XDISTANCE,x_dist);       // установка координаты X
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_YDISTANCE,y_dist);       // установка координаты Y
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_SELECTABLE,false);       // нельзя выделить объект, если FALSE
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_ZORDER,zorder);         // Приоритет выше/ниже
      ObjectSetString(chrt_id,lable_nm,OBJPROP_TOOLTIP,"\n");            // нет всплывающей подсказки, если "\n"
     }
  }
//+------------------------------------------------------------------+
//| СОЗДАНИЕ_ОБЪЕКТА_EDIT                                            |
//+------------------------------------------------------------------+
void Create_Edit(long   chrt_id,   // id графика
                 int    nmb_win,   // номер окна (подокна)
                 string lable_nm,  // имя объекта
                 string text,      // отображаемый текст
                 long   corner,    // угол привязки
                 string font_bsc,  // шрифт
                 int    font_size, // размер шрифта
                 color  font_clr,  // цвет шрифта
                 int    xsize,     // ширина
                 int    ysize,     // высота
                 int    x_dist,    // координата по шкале X
                 int    y_dist,    // координата по шкале Y
                 long   zorder,    // приоритет
                 color  clr)       // цвет фона
  {
   if(ObjectCreate(chrt_id,lable_nm,OBJ_EDIT,nmb_win,0,0)) // создание объекта
     {
      ObjectSetString(chrt_id,lable_nm,OBJPROP_TEXT,text);            // установка имени
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_CORNER,corner);       // установка угла привязки
      ObjectSetString(chrt_id,lable_nm,OBJPROP_FONT,font_bsc);        // установка шрифта
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_FONTSIZE,font_size);  // установка размера шрифта
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_COLOR,font_clr);     // цвет шрифта
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_BGCOLOR,clr);        // цвет фона
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_XSIZE,xsize);        // ширина
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_YSIZE,ysize);        // высота
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_XDISTANCE,x_dist);    // установка координаты X
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_YDISTANCE,y_dist);    // установка координаты Y
      ObjectSetInteger(chrt_id,lable_nm,OBJPROP_SELECTABLE,false);    // нельзя выделить объект, если FALSE
      ObjectSetInteger(chart_id,lable_nm,OBJPROP_ZORDER,zorder);      // Приоритет выше/ниже
      ObjectSetString(chrt_id,lable_nm,OBJPROP_TOOLTIP,"\n");         // нет всплывающей подсказки, если "\n"
     }
  }
//+------------------------------------------------------------------+

//---

Expert Advisor を起動すると、左上のチャートに以下のように表示されます。

//---

START event_idle++」 ボタンをクリックすると、あなたの（Alex）ソリューションにアクセスします。チャート上では、event_idle++の カウンタが正しくインクリメントされているのがわかる。

ボタンが押されている間は、あなたのコードは動作します。しかし、それには多くのリソースを消費します。CPU負荷（デュアルコアでテスト）は、〜90％から 〜100％の範囲です。CPUの負荷は、起動前またはボタンを離したときに5％～ 10％の範囲になります。グラフ上でクリック（左クリック）すると、カウンターはゼロにリセットされます。

入力フィールドにテキストを入力してもフリッカーが発生しないのは、入力の瞬間にあなたのコードがグローバル変数"On/Off event_idle++" によって無効化されるからです。もちろん松葉づえですが、一時的な解決策としては、簡単なものであれば問題ないでしょう。

CPUの負荷だけが問題ではありません。カウンターが動作しているとき、取引端末のウィンドウはすぐに開きますが、ウィンドウのサイズ変更はかなり顕著に遅くなります。いつもではないけれど、そういう瞬間はある。

ファイル:

OnChartEvent.mq5 10 kb

Anatoli Kazharski 2012.02.19 21:54 #58

tol64:

CPUの負荷だけが問題ではありません。カウンターの実行中は、取引端末のウィンドウはすぐに開きますが、ウィンドウのリサイズはかなり遅くなります。いつもではありませんが、そういう瞬間があります。

CPU負荷の問題は、以下のように解決することができます。イベントカウンターを1秒に1回更新することを指定する。以下のコードを追加します。

OnInit()内。

EventSetTimer(1);

//---

プログラム本体に

//+------------------------------------------------------------------+
//| ТАЙМЕР                                                           |
//+------------------------------------------------------------------+
long countSecond=0;
//---
void OnTimer()
  {
   if(GlobalVariableGet(OnOff_event_idle)==1)
     {
      countSecond++;
     }
  }

//---

アレックスの コードへ（赤でマーク）。

   if(GlobalVariableGet(OnOff_event_idle)==1)
     {
      if(id==CHARTEVENT_CUSTOM+VM_IDLE && countSecond>0)
        {
         // Если последнее посланное больше, чем пришедшее, то сразу выходим
         if(event_idle>(ulong)lparam || bidle)
           {
            bidle=event_idle>(ulong)lparam;
            //---
            if(bidle) { return; }
            //---
            event_idle=0;
           }
         //---
         event_idle++; // увеличили счётчик событий
         //---
         Comment("id: ",id,"\n",
                 "event_idle++: ",event_idle
                 );
         //---
         // Отправили событие с указанием последнего счетчика
         EventChartCustom(chart_id,VM_IDLE,(long)event_idle,0,""); countSecond=0; return;
        }
      //---
      // Отправили событие с указанием последнего счетчика
      EventChartCustom(chart_id,VM_IDLE,(long)event_idle,0,""); countSecond=0;
     }

//---

CHARTEVENT_CLICK イベントハンドラーブロック（赤色で表示）内。

//+------------------------------------------------------------------+
//| СОБЫТИЕ_CHARTEVENT_CLICK                                         |
//+------------------------------------------------------------------+
   if(id==CHARTEVENT_CLICK)
     {
      Print("Reset. Event_idle: ",event_idle);
      //---
      event_idle=0;
      countSecond=0;
      //---
      Comment("id: ",id,"\n",
              "event_idle++: ",event_idle
              );
     }

//---

CHARTEVENT_OBJECT_CLICK イベントハンドラーブロックを以下のように編集する必要があります + ボタンの状態をすべてチェックする必要があります。時々、「間違って」押した場合でも、以前はそのようになっていたのに、ブロック内の残りのコードはうまくいき、混乱が始まります。

//+------------------------------------------------------------------+
//| СОБЫТИЕ_CHARTEVENT_OBJECT_CLICK                                  |
//+------------------------------------------------------------------+
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      if(sparam=="Edit_Area")
        {
         if((int)GlobalVariableGet(OnOff_event_idle)==0) { GlobalVariableSet(OnOff_event_idle,1); }
         if((int)GlobalVariableGet(OnOff_event_idle)==1) { GlobalVariableSet(OnOff_event_idle,0); }
        }
      //---
      if(sparam=="Start_event_idle")
        {
         if((int)GlobalVariableGet(OnOff_event_idle)==0)
           {
            countSecond=0;
            GlobalVariableSet(OnOff_event_idle,1);
            ObjectSetInteger(chart_id,"Start_event_idle",OBJPROP_STATE,true);
            //---
            ChartRedraw(); return;
           }
         //---
         if((int)GlobalVariableGet(OnOff_event_idle)==1)
           {
            countSecond=0;
            GlobalVariableSet(OnOff_event_idle,0);
            ObjectSetInteger(chart_id,"Start_event_idle",OBJPROP_STATE,false);
            //---
            ChartRedraw(); return;
           }
        }
     }

//---

今度はもっと面白くなる。:)

//---

追伸：秒数が多い場合は、GetTickCount()をいじってみるとよいでしょう。

--- 2012.02.20 09:00 #59

なんて言ったらいいんだろう

1.CPUに負担をかけることになる。外せば静かになる。

2.アイドルループ自体は、CPUに顕著な影響を与えません。

3.edithのちらつきの問題は、0-chart単体の問題ではありません。オブジェクト-chartにイベントを送る際の問題です。これにより、メインの0チャートが再描画され、フリッカーが発生します。

Anatoli Kazharski 2012.02.20 17:12 #60

sergeev:

なんて言ったらいいんだろう

1.CPUに負担をかけることになる。外せば静かになる。

2.アイドルループ自体は、CPUに顕著な影響を与えません。

3.edithのちらつきは、0-chart単体の問題ではなく、オブジェクト-chartへのイベント送信の問題です。これにより、メインの0チャートが再描画され、フリッカーが発生します。

分かりやすい説明ありがとうございます。調べてみます。

イベントの流れ イベントの制御やアイドリングストップはどのように行うのですか？(+解決済み) - ページ 6

イベントの流れイベントの制御やアイドリングストップはどのように行うのですか？(+解決済み) - ページ 6