ライブラリ: エキスパート

fxsaber 2017.09.08 14:45 #1

この説明

fxsaber, 2017.09.08 13:52

ChartApplyTemplateを使用する場合、強制同期が必要ですが、私はバイブルで以下のようにしています。

  static bool TemplateApply( const long Chart_ID, const string &Str, const bool Sync = true )
  {
    string TmpStr = Str;

    const bool SyncFlag = (Sync && Chart_ID && (Chart_ID != ::ChartID()) && !::IsStopped());

    if (SyncFlag)
    {
      const color ColorStopLevel = (color)::ChartGetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL);

      if ((bool)(ColorStopLevel >> 24))
        ::ChartSetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, ColorStopLevel & 0xFFFFFF);

      const int NewColorStopLevel = (int)EXPERT::StringBetween(TmpStr, EXPERT_STOPLEVEL, STRING_END) | (0x01 << 24);

      TmpStr = Str;
      EXPERT::StringReplace(TmpStr, EXPERT_STOPLEVEL, STRING_END, EXPERT_STOPLEVEL + (string)NewColorStopLevel + STRING_END);
    }

    short Data[];
    const bool Res = ::StringToShortArray(TmpStr, Data, 0, ::StringLen(TmpStr)) &&
                     ::FileSave(FILENAME, Data) && ::ChartApplyTemplate((ulong)Chart_ID, FILENAME);

    if (Res && SyncFlag)
    {
      long Value;

      while ((!::IsStopped() && ::ChartGetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, 0, Value) && (!(bool)((int)Value >> 24))))
        ::Sleep(0);

      ::ChartSetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, (int)Value & 0xFFFFFF);
    }

    return(Res);
  }

ChartApplyはすぐにはトリガーされません。そして、それ以降のアクションはトリガー後にのみ実行できます。

テンプレートが適用されたことを理解するには、テンプレート自体を変更し（バイブルでは、チャートの特性の1つである4バイト目（透明度を担当）の色を変更する）、この値がチャートのプロパティになるのをスリープ（ChartGetInterger）を通して待つ必要がある。その後、ChartSetIntegerで通常の値を設定する。

スクリプトが投げられた同じチャートでExpert Advisorを実行する必要がある場合は、新しいチャートを開き、テンプレートを通じて同じ（スクリプト）を実行する必要があります。これはExpertLoader_Example.mq5 によって実行される。

fxsaber 2017.09.11 15:13 #2

может быть полезна при написании различных управляющих панелей чартами/советниками и т.п.

ライブラリーはDLLなしで動作し、市場の要求を完全に満たしている。

fxsaber 2017.10.31 01:27 #3

ちょっとしたハック - OBJ_CHART-オブジェクト上でEA/スクリプトを実行する。

そのため、起動したExpert Advisorsはハングアップし、何も実行されません。しかし、スクリプトは完全に動作します。したがって、これはいくつかの可能性を開きます。

例えば、すでにExpert Advisorが動作しているチャートに、インジケーターからOrder-functionを使用することができます。また、新たに補助チャートを開く必要もない。

スクリプト ScriptsOrderSend.mq5 をコンパイルします。

#include <MT4Orders.mqh>       //https://www.mql5.com/ja/code/16006
#include <GlobalVariables.mqh> //https://www.mql5.com/ru/forum/189649#comment_4854618

struct ORDERSEND
{
  int Type;
  double Volume;
  double Price;
  int SlipPage;
  double SL;
  double TP;
  long Magic;
  datetime Expiration;
  color Arrow_Color;
};

void OrderSend()
{
  const ORDERSEND Order = _GlobalVariableGet<ORDERSEND>("ORDERSEND");
  const string Symb = _GlobalVariableGet<string>("Symbol");
  const string comment = _GlobalVariableGet<string>("Comment");
      
  _GlobalVariableSet(__FUNCTION__, OrderSend(Symb, Order.Type, Order.Volume, Order.Price, Order.SlipPage, Order.SL, Order.TP, comment, Order.Magic, Order.Expiration, Order.Arrow_Color));
  
  _GlobalVariableDel("ORDERSEND");
  _GlobalVariableDel("Symbol");
  _GlobalVariableDel("Comment");  
}

void OnStart()
{
  OrderSend();
}

そして「取引できる」インジケータを実行する。

#include <fxsaber\Expert.mqh>  //https://www.mql5.com/ja/code/19003
#include <GlobalVariables.mqh> //https://www.mql5.com/ru/forum/189649#comment_4854618

struct ORDERSEND
{
  int Type;
  double Volume;
  double Price;
  int SlipPage;
  double SL;
  double TP;
  long Magic;
  datetime Expiration;
  color Arrow_Color;
};

template <typename T>
long _GlobalVariableGet2( const string Name, const ulong MaxTime = 1 e6 )
{
  const ulong StartTime = GetMicrosecondCount();
  
  while (!IsStopped() && !GlobalVariableCheck(Name) && (GetMicrosecondCount() - StartTime < MaxTime))
    Sleep(0);
      
  return(_GlobalVariableGet<T>(Name));
}

// Expert Advisorを使用しているチャート上でも、インジケーターから機能します。
long OrderSend( string Symb, const int Type, const double dVolume, const double Price, const int SlipPage, const double SL, const double TP,
                string comment = NULL, const long magic = 0, const datetime dExpiration = 0, color arrow_color = clrNONE )
{
  MqlParam Params[1];    
  Params[0].string_value = "Scripts\\OrderSend.ex5";

  ORDERSEND Order;

  Order.Type = Type;
  Order.Volume = dVolume;
  Order.Price = Price;
  Order.SlipPage = SlipPage;
  Order.SL = SL;
  Order.TP = TP;
  Order.Magic = magic;
  Order.Expiration = dExpiration;
  Order.Arrow_Color = arrow_color;

  const long Res = ObjectCreate(0, __FILE__, OBJ_CHART, 0, 0, 0) && _GlobalVariableSet("ORDERSEND", Order) &&
                   _GlobalVariableSet("Symbol", Symb) && _GlobalVariableSet("Comment", comment) &&
                   EXPERT::Run(ObjectGetInteger(0, __FILE__, OBJPROP_CHART_ID), Params) &&
                   ObjectDelete(0, __FILE__) ? _GlobalVariableGet2<long>(__FUNCTION__) : -1;  
  
  _GlobalVariableDel(__FUNCTION__);

  return(Res);
}

void OnInit()
{  
  Print(OrderSend(_Symbol, ORDER_TYPE_BUY, 1, SymbolInfoDouble(_Symbol, SYMBOL_ASK), 100, 0, 0, "From Indicator", 9));
}

int OnCalculate( const int, const int, const int, const double &[] )
{
  return(0);
}

fxsaber 2018.01.30 15:13 #4

MT4でも動作するように、ライブラリをクロスプラットフォーム状態に改良することを許さない技術的制限はありません。

fxsaber 2018.02.07 20:02 #5

取引、自動取引システム、取引戦略のテストに関するフォーラム

グローバルアルゴリズムによるエキスパートアドバイザーの管理

Totosha16, 2018.02.07 18:57

ExpertRemoveスクリプトが実行されたチャート以外のすべてのチャート上のExpert Advisorを閉じる。その方法を教えてください。

#include <fxsaber\Expert.mqh> //https://www.mql5.com/ja/code/19003

void OnStart()
{    
  const long CurrentChart = ChartID();  
  long Chart = ChartFirst();

  while (Chart != -1)
  {
    if (Chart != CurrentChart)
      EXPERT::Remove(Chart);

    Chart = ChartNext(Chart);
  }
}

fxsaber 2018.02.09 12:49 #6

取引、自動取引システム、取引戦略のテストに関するフォーラム

エラー、バグ、質問

Vladislav Andruschenko, 2018.02.09 10:14 AM

Expert Advisorの内部で外部変数のリストを取得する方法を教えてください。

取引、自動取引システム、取引戦略のテストに関するフォーラム。

エラー、バグ、質問

fxsaber, 2018.02.09 12:44.

#include <fxsaber\Expert.mqh> //https://www.mql5.com/ja/code/19003

input string Input1 = "Hello World!";
input int Input2 = 123;

string GetExpertData( const ulong Chart = 0 ) 
{ 
  string Str = NULL; 

  MqlParam Parameters[]; 
  string Names[]; 

  if (EXPERT::Parameters(Chart, Parameters, Names)) 
  { 
    Str += "\n" + ChartSymbol(Chart) + " " + EnumToString(ChartPeriod(Chart)) + " " + Parameters[0].string_value + "\n"; 

    const int Amount = ArraySize(Names); 

    for (int i = 0; i < Amount; i++) 
      Str += (string)i + ": "+ Names[i] + " = " + Parameters[i + 1].string_value + "\n"; 
  } 

  return(Str); 
}

void OnInit()
{
  Print(GetExpertData());
}

結果

0: Input1 = Hello World!
1: Input2 = 123

またはこのような

#include <fxsaber\Expert.mqh> //https://www.mql5.com/ja/code/19003

input string Input1 = "Hello World!";
input int Input2 = 123;

void OnInit()
{
  MqlParam Parameters[];
  string Names[];   
  
  if (EXPERT::Parameters(0, Parameters, Names))
    ArrayPrint(Parameters);
}

結果

    [type] [integer_value] [double_value]      [string_value]
[0]    ...               0        0.00000 "Experts\Test2.ex5"
[1]    ...               0        0.00000 "Hello World!"     
[2]    ...             123      123.00000 "123"

fxsaber 2018.02.23 00:38 #7

取引、自動取引システム、取引戦略のテストに関するフォーラム

エラー、バグ、質問

fxsaber, 2018.02.22 23:53

インジケーターから任意の長さのサウンドファイルを再生する。

ScriptsPlaySound.mq5スクリプト。

#include <GlobalVariables.mqh> //https://www.mql5.com/ru/forum/189649#comment_4854618

void OnStart()
{
  const string SoundName = "SOUND";

  if (GlobalVariableCheck(SoundName))
  {
    PlaySound(_GlobalVariableGet<string>(SoundName));
  
    _GlobalVariableDel(SoundName);
  }
}

インジケーター

#property indicator_chart_window

#property indicator_buffers 0
#property indicator_plots indicator_buffers

#include <fxsaber\Expert.mqh>  //https://www.mql5.com/ja/code/19003
#include <GlobalVariables.mqh> //https://www.mql5.com/ru/forum/189649#comment_4854618

class PLAYER
{
public:
  const string Name;
  const long Chart;
  const long chartID;
  
  PLAYER( const long iChart = 0 ) : Name(__FILE__), Chart(iChart ? iChart : ::ChartID()),
                                    chartID(::ObjectCreate(this.Chart, this.Name, OBJ_CHART, 0, 0, 0)   &&
                                            ::ObjectSetInteger(this.Chart, this.Name, OBJPROP_XSIZE, 0) &&
                                            ::ObjectSetInteger(this.Chart, this.Name, OBJPROP_YSIZE, 0) ?
                                            ::ObjectGetInteger(this.Chart, this.Name, OBJPROP_CHART_ID) : this.Chart)
  {
  }
  
  ~PLAYER()
  {
    if (this.chartID != this.Chart)
      ::ObjectDelete(this.Chart, this.Name);
  }
  
  void PlaySound( string FileName, const string ScriptName = "Scripts\\PlaySound.ex5" ) const
  {
    static const string SoundName = "SOUND";
    
    if (_GlobalVariableSet(SoundName, FileName))
    {
      MqlParam Params[1];
      
      Params[0].string_value = ScriptName;
      
      if (!EXPERT::Run(this.chartID, Params))      
        _GlobalVariableDel(SoundName);
    }    
  }
};

int OnCalculate( const int rates_total , const int prev_calculated, const int, const double& [] )
{  
  if (!prev_calculated)
  {
    const PLAYER Player;
    
    Player.PlaySound("email.wav");
  }

  return(rates_total);
}

Andrey Khatimlianskii 2018.02.24 00:47 #8

MT4には、FileSaveとFileLoad（それぞれ3行で記述されている）以上のものが欠けていることが判明した：

CHART_EXPERT_NAMEがない（そして、他のすべてのニュアンス、つまり名前タグを修正した後を除いて、それを置き換えるものがない）。
私が理解する限りでは、Frontal FileLoadは、保存されたテンプレートのANSIエンコーディングのため、適していません。
、テキストモードでファイルを読み込むTemplateToStringのアナログを書かなければなりませんでした。
STRING_ENDは空でなければならない。
MT4の<expert>タグはインジケーターにも使用されるので、これらの編集を行った後でも、EAが最後に指定されるという事実を頼りにしてのみ、インジケーターがどこにあり、EAがどこにあるかを知ることができます（そして、それは常にそうなのでしょうか？）さて、そしてあなたはそれに到達する必要があります。

総じて、非常に必要で便利なもので、実装に感謝します！

fxsaber 2018.03.06 18:53 #9

Andrey Khatimlianskii:

MT4の<expert>タグはインジケーターにも使われているので、これだけ編集しても、インジケーターがどこにあるのか、Expert Advisorがどこにあるのかは、Expert Advisorが最後に指定されていることを頼りにするしかない（いつもそうなのか？）さて、そしてあなたはそれに到達する必要があります。

このソース・コードはその疑問を理解するのに役立つかもしれない。

取引、自動取引システム、取引戦略のテストに関するフォーラム。

インジケーターのラインの現在の色を調べるには？

fxsaber, 2017.05.12 13:45

#property strict

#property indicator_chart_window
#property indicator_buffers 2

#define  PATH "MQL4\\indicators\\"

#include <TypeToBytes.mqh> //https://www.mql5.com/ja/code/16280

string GetIndicatorName( void )
{
  const string StrName = ::MQLInfoString(MQL_PROGRAM_PATH);
  const int Pos = ::StringFind(StrName, PATH) + ::StringLen(PATH);
  
  return(::StringSubstr(StrName, Pos, ::StringLen(StrName) - Pos - 4));
}

void SeekToString( const int handle, const string Str )
{
  while (!::FileIsEnding(handle))
    if (::FileReadString(handle) == Str)
      break;
  
  return;
}  

struct BUFFER_STRUCT
{
  int Shift;
  int Type;
  color Color;
  ENUM_LINE_STYLE Style;
  int Width;
};

const BUFFER_STRUCT GetBufferProperties( const uint Num = 0, const bool FlagSave = true )
{
  BUFFER_STRUCT Res = {0};
  
  const string FileName = ::WindowExpertName() + ".tpl";

  if (FlagSave ? ::ChartSaveTemplate(0, "..\\MQL4\\Files\\" + FileName) : true)
  {
    const int handle = ::FileOpen(FileName, ::FILE_READ|::FILE_CSV);

    if (handle > 0)
    {
      ::SeekToString(handle, "name=" + ::GetIndicatorName());
      
      if (Num == 0)
        ::SeekToString(handle, "</expert>");
      else
      {
        const string TmpStr = "weight_" + (string)(Num - 1);
        
        while (!::FileIsEnding(handle))
          if (::StringFind(::FileReadString(handle), TmpStr) == 0)
            break;
      }
            
      if (!::FileIsEnding(handle))
      {
        static const string Property[] = {"shift", "draw", "color", "style", "weight"};
        const string StrNum = "_" + (string)Num + "=";
              
        for (int i = 0; i < ::ArraySize(Property); i++)
          _W(Res)[i * sizeof(int)] = (int)::StringToInteger(::StringSubstr(::FileReadString(handle), ::StringLen(Property[i] + StrNum)));
      }
      
      ::FileClose(handle);
    }
  }
  
  return(Res);
}  

void OnInit()
{  
  string Str = "Colors:";
  
  for (int i = 0; i < indicator_buffers; i++)
    Str += " " + (string)i + "-" + (string)::GetBufferProperties(i).Color;
    
  Alert(Str);
}

void start()
{
}

Andrey Khatimlianskii 2018.03.07 03:10 #10

fxsaber:

このソースは、この問題を理解するのに役立つかもしれない。

ありがとう！いつものように、私が望むよりも少し複雑だ ;)

あなたのコードには否定できない利点があります。しかし、その中で何かを微調整するのはかなり難しい、それが欠点だ。