Caratteristiche del linguaggio mql5, sottigliezze e tecniche - pagina 105

[TheXpert]

fxsaber:

template <typename T1, typename T2>
bool More(const T1& first, const T2& second)
{
   return first > second;
}

bool More(const MqlTick& first, const MqlTick& second)
{
   return first.bid > second.bid;
}

// Простая сортировка
template <typename T1, typename T2> // T2 - по какому правилу сортируем
void Sort( T1 &Array[] )
{
  const int Size = ArraySize(Array);
  
  for (int i = 0; i < Size - 1; i++)
  {
    T2 Min = Array[i];
    int Pos = i;
    
    for (int j = i + 1; j < Size; j++)
      if (More(Min, Array[j]))
      {
        Min = Array[j];
        Pos = j;        
      }
      
    if (Pos != i)
    {
      Array[Pos] = Array[i];
      Array[i] = Min;
    }
  }
}

Comunque, sono andato un po' fuori tema

[fxsaber]

// Возвращает TimeLocal даже в Тестере
datetime GetTimeLocal( void )
{ 
  static const bool IsTester = MQLInfoInteger(MQL_TESTER);
  static uint TickCount = 0;
  static datetime InitTimeLocal = 0;
  
  datetime Res = 0;
  
  if (IsTester)
  {
    if (InitTimeLocal)
      Res = InitTimeLocal + (GetTickCount() - TickCount) / 1000;
    else
    {
      int Array[];    
      const string FileName = __FUNCTION__;  
      
      if (FileSave(FileName, Array))
      {
        TickCount = GetTickCount();
        
        Res = InitTimeLocal = (datetime)FileGetInteger(FileName, FILE_MODIFY_DATE);
      }
    }
  }
  else
    Res = TimeLocal();
    
  return(Res);
}

Applicazione

void OnInit()
{
  Print(GetTimeLocal());  
}

double OnTester()
{
  Print(GetTimeLocal());
  
  return(0);
}

HH C'è un modo più semplice per trovare l'ora locale del PC nel Tester?

[Stanislav Korotky]

fxsaber:

Applicazione

HH C'è un modo più semplice per ottenere l'ora locale del PC nel Tester?

Attraverso una variabile globale (GlobalVariableTemp, GlobalVariableTime).

[fxsaber]

Stanislav Korotky:

Attraverso una variabile globale (GlobalVariableTemp, GlobalVariableTime).

Non funzionerà.

[Stanislav Korotky]

fxsaber:

Non funzionerà.

Funziona da molto tempo e funziona correttamente.

[fxsaber]

Stanislav Korotky:

Ha funzionato correttamente per molto tempo.

Allora cosa sto facendo di sbagliato?

datetime GetTimeLocal( const bool FlagDelete = false )
{ 
  static const bool IsTester = MQLInfoInteger(MQL_TESTER);
  static const string Name = __FILE__;

  return(IsTester && GlobalVariableTemp(Name) ? GlobalVariableTime(Name) : TimeLocal());
}

double OnTester()
{
  Print(GetTimeLocal());
  
  return(0);
}

[TheXpert]

fxsaber:

Allora cosa sto facendo di sbagliato?

Sospetto che il problema sia il tuo amore per la concatenazione. prova attraverso if.

[fxsaber]

TheXpert:

Sospetto che il problema sia il tuo amore per la laconicità. prova se.

Provato

datetime GetTimeLocal()
{ 
  static const string Name = __FILE__;

  datetime Res = 0;
  
  if (GlobalVariableTemp(Name))
    Res = GlobalVariableTime(Name);
  
  return(Res);
}

Non funziona.

[Alain Verleyen]

fxsaber:

Provato

Non funziona.

Non funziona perché la variabile globale è emulata con MT5 Tester. Anche loro usano TimeCurrent ().

[Stanislav Korotky]

fxsaber:

Provato

Non funziona.

Funziona come previsto per me...

PS. Errore mio - funziona in MT4 ma non in MT5.