Bibliotecas: TypeToBytes - página 5

Nuevo comentario
 
fxsaber:
Dos líneas con el mismo resultado
ArrayCompare(Array1, Array2) == 0
_R(Array1) == Array2
  
// Lectura/Escritura de campos privados de estructuras simples

#include <TypeToBytes.mqh>

template <typename T>
struct STRUCT
{
private:
  T Data; // campo privado
  
public:
  T GetData( void ) const
  {
    return(this.Data);
  }
};

void OnStart()
{    
  STRUCT<int> Struct = {0};  
  
  _W(Struct) = 2;          // Acceso de escritura al campo privado
  Print(Struct.GetData()); // asegúrese de que es
  
  Print(_R(Struct)[0]);    // Acceso de lectura a campo privado
}
 
La biblioteca prescribe una clase contenedora que almacena variables y matrices de cualquier otro tipo simple en una matriz de un tipo determinado.
// Ejemplo de trabajo con un contenedor
#include <TypeToBytes.mqh>

#define  PRINT(A) Print(#A + " = " + (string)(A));

void OnStart()
{
  // Datos arbitrarios para el ejemplo
  string Str[] = {"123", "Hello World!"};
  double Num = 5;
  MqlTick Tick = {0};
  Tick.bid = 1.23456;
  
  CONTAINER<long> Container;  // Crear un contenedor - todo será almacenado en un array de un tipo simple (long es el elegido en el ejemplo)
  
  // Llenar el contenedor con datos diferentes
  Container[0] = Str;
  Container[1] = Num;
  Container[2] = Tick;
  
  ArrayPrint(Container.Data); // Salida del contenido del array en el que el contenedor almacena todos los datos
  
  // Imprimir los tipos de datos almacenados en el contenedor
  for (int i = 0; i < Container.GetAmount(); i++)
    PRINT(Container[i].GetType())
    
  // Obtengamos los datos propiamente dichos 
  string Str2[];
  Container[0].Get(Str2);                // Obtenido el array
  ArrayPrint(Str2);
  
  PRINT(Container[1].Get<double>())      // Tenemos un número
  PRINT(Container[2].Get<MqlTick>().bid) // Tenemos la estructura
  
  Container[1] = "Replace";   // Datos sustituidos por índice
  
  // Verificar que se ha producido la sustitución 
  PRINT(Container[1].GetType())
  PRINT(Container[1].Get<string>())
}
 
fxsaber:
La biblioteca contiene una clase contenedora que almacena variables y matrices de cualquier otro tipo simple en una matriz de un tipo determinado.

Ejemplo de aplicación práctica en Report-bible

Enviar una trama con datos diferentes

        string Str;
        REPORT::ToString(Str);

        double Balance[];
        REPORT::GetBalanceHistory(Balance);

      #ifdef __TYPETOBYTES__
        CONTAINER<uchar> Container;

        Container[0] = Str;     // poner la cadena del informe en el contenedor
        Container[1] = Balance; // añadimos también al contenedor un array doble con el histórico de cambios de saldo

        ::FrameAdd(NULL, 0, ::AccountInfoDouble(ACCOUNT_BALANCE), Container.Data); // Envió de un marco con informe de cadena y matriz de saldo
      #else  // __TYPETOBYTES__

Recibir una trama con datos diferentes

 CONTAINER<uchar> Container;

    while (::FrameNext(Pass, Name, ID, Value, Container.Data))
    {
        string Str;
        Container[0].Get(Str);     // Obtener la cadena de informe del marco

        double Balance[];
        Container[1].Get(Balance); // Obtener la matriz doble correspondiente del marco

// .....
Report
Report
  • 2017.07.19
  • fxsaber
  • www.mql5.com
Библиотека для MetaTrader 4/5, которая позволяет формировать отчеты по истории торгов.
 
Otro ejemplo de aplicación Container

Foro sobre trading, sistemas automatizados de trading y prueba de estrategias de trading

Preguntas de los principiantes MQL5 MT5 MetaTrader 5

fxsaber, 2017.08.23 14:10

Necesitas usar Frame Mode para escribir los datos de los Agentes en un solo archivo.

// Ejemplo de grabación de datos de Agentes (incluyendo Agentes Cloud) en un fichero
input int Range = 0;

void OnTick()
{
// ....
}

// Abrir el archivo sólo en los modos Ejecución única o Fotograma.
const int handle = ((MQLInfoInteger(MQL_TESTER) && !MQLInfoInteger(MQL_OPTIMIZATION)) || MQLInfoInteger(MQL_FRAME_MODE)) ?
                   FileOpen(__FILE__, FILE_WRITE | FILE_TXT) : INVALID_HANDLE;

// Preparación de datos
void GetData( string &Str, MqlTick &Ticks[], double &Balance )
{
  Str = "Hello World!";
  
  CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, 0, 2); // Últimos dos ticks (ejemplo)
  
  Balance = AccountInfoDouble(ACCOUNT_BALANCE);
}

// Escritura de datos
void SaveData( const string &Str, const MqlTick &Ticks[], const double Balance )
{
  FileWrite(handle, Str);
  
  for (int i = 0; i < ArraySize(Ticks); i++)
    FileWrite(handle, Ticks[i].bid);
    
  FileWrite(handle, Balance);
}

void OnTesterDeinit()
{
  if (handle != INVALID_HANDLE)  
    FileClose(handle);
    
  ChartClose();
}

#include <TypeToBytes.mqh> // https://www.mql5.com/es/code/16280

double OnTester()
{
  string Str;
  MqlTick Ticks[];
  double Balance;
  
  GetData(Str, Ticks, Balance); // Preparación de los datos para el registro

  if (MQLInfoInteger(MQL_OPTIMIZATION)) // Optimización
  {
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
    
    Container[0] = Str;
    Container[1] = Ticks;
    Container[2] = Balance;
  
    FrameAdd(NULL, 0, 0, Container.Data); // Envío de datos del Agente al Terminal
  }
  else // Ejecución única
  {    
    if (handle != INVALID_HANDLE)
      SaveData(Str, Ticks, Balance); // Los datos se escribirán en la carpeta MQL5\Files del Agente (no en el Terminal)
    
    FileClose(handle);
  }
  
  return(0);
}

void OnTesterPass()
{    
  if (handle != INVALID_HANDLE)
  {
    ulong Pass;
    string Name;
    long ID;
    double Value;
  
    CONTAINER<uchar> Container; // https://www.mql5.com/ru/forum/95447/page4#comment_5464205
  
    while (FrameNext(Pass, Name, ID, Value, Container.Data))
    {
      string Str;
      MqlTick Ticks[];
      double Balance;
      
      // Datos recibidos del Agente
      Container[0].Get(Str);
      Container[1].Get(Ticks);
      Container[2].Get(Balance);
      
// FileWrite(handle, Pass); // Si desea escribir el número del pasaje
      SaveData(Str, Ticks, Balance); // Los datos se escribirán en la carpeta MQL5\Files del Terminal (no en el Agente)
    }
  }
}
 
Ejemplo de codificación de datos estándar (rojo - uso de biblioteca)

Foro sobre comercio, sistemas automatizados de comercio y prueba de estrategias comerciales

Nueva versión de MetaTrader 5 build 1640: crear y probar sus propios instrumentos financieros

fxsaber, 2017.10.10 07:51

// Cuánto se exprimen los datos de MqlRates y la velocidad de empaquetado/desempaquetado
#include <TypeToBytes.mqh> // https://www.mql5.com/es/code/16280

#define  TOSTRING(A) #A + " = " + (string)(A) + "\n"

void OnStart()
{
  MqlRates Rates[];
  uchar Tmp[];  
  
  const int Amount = CopyRates(_Symbol, PERIOD_CURRENT, 0, Bars(_Symbol, PERIOD_CURRENT), Rates) * sizeof(MqlRates);  
  
  // Archivo
  const ulong StartTime1 = GetMicrosecondCount();
  const int AmountZIP = CryptEncode(CRYPT_ARCH_ZIP, _R(Rates).Bytes, Tmp, Tmp);
  
  Print(TOSTRING(Amount) + TOSTRING(AmountZIP) + TOSTRING((double)Amount / AmountZIP) + TOSTRING(GetMicrosecondCount() - StartTime1));
  
  uchar Tmp2[];
  
  // Descomprimir
  const ulong StartTime2 = GetMicrosecondCount();
  CryptDecode(CRYPT_ARCH_ZIP, Tmp, Tmp2, Tmp2);
  Print(TOSTRING(GetMicrosecondCount() - StartTime2));
  
  Print(TOSTRING(_R(Rates) == Tmp2)); // ¿Coinciden los datos?
}
 
Uso de la biblioteca para poner/recuperar cualquier dato en/de una cadena
// Ejemplo multiplataforma de paso de datos arbitrarios a través de un evento personalizado

#include <fxsaber\HistoryTicks\Data_String.mqh> // https://www.mql5.com/es/code/20298

// Imprimir datos arbitrarios
template <typename T>
bool MyPrint( const T &Value )
{
  T Array[1];
  
  Array[0] = Value;
  
  ArrayPrint(Array, _Digits, NULL, 0, WHOLE_ARRAY, ARRAYPRINT_HEADER | ARRAYPRINT_ALIGN);
  
  return(true);
}

void OnChartEvent( const int id, const long &lparam, const double&, const string &sparam )
{
  // Imprimir los datos obtenidos
  if ((id == CHARTEVENT_CUSTOM) &&
      (lparam ?  MyPrint(DATA_STRING::FromString<MqlDateTime>(sparam)) // Obtenido MqlDateTime
              : !MyPrint(DATA_STRING::FromString<MqlTick>(sparam))))   // Got MqlTick
    ExpertRemove(); // Fuera del ejemplo
}

void OnInit()
{
  MqlTick Tick;  
  MqlDateTime DateTime;
  
  // Rellenar los valores
  SymbolInfoTick(_Symbol, Tick);  
  TimeCurrent(DateTime);

  // Transmitido
  EventChartCustom(0, 0, 0, 0, DATA_STRING::ToString(Tick));     // Pasado MqlTick
  EventChartCustom(0, 0, 1, 0, DATA_STRING::ToString(DateTime)); // Pasado MqlDateTime
}
 
Un ejemplo sencillo de uso

Foro sobre comercio, sistemas automatizados de comercio y prueba de estrategias comerciales

Versión beta de MetaTrader 5 build 1995: calendario económico, programas MQL5 como servicios y API para lenguaje R

fxsaber, 2019.02.18 16:36

#include <TypeToBytes.mqh> // https://www.mql5.com/es/code/16280

int StringToShortArray2( const string Str, ushort &Array[], const int = 0, const int = 0 )
{
  const int Size = ArrayResize(Array, StringLen(Str));
  
  for (int i = 0; i < Size; i++)
    _W(Array[i]) = Str[i];
  
  return(Size);
}
 

Hola. Está funcionando.

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
  };

#include <Exchange_Data.mqh>

#define  AMOUNT 100

EXCHANGE_DATA<Message>ExchangeTicks(AMOUNT,true);
//+------------------------------------------------------------------+
//| Función de inicialización del indicador personalizada |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- asignación de búferes indicadores
   static Message Ticks[1];
   Ticks[0].cnt=1;
   Ticks[0].res=true;
   Ticks[0].ter=1;
   ExchangeTicks.DataSave(Ticks);
//---
   return(INIT_SUCCEEDED);
  }

Así es como funciona.

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
   string            str;
  };

#include <Exchange_Data.mqh>

#define  AMOUNT 1000

EXCHANGE_DATA<Message>ExchangeTicks(AMOUNT,true);
//+------------------------------------------------------------------+
//| Función de inicialización del indicador personalizada |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- asignación de búferes indicadores
   static Message Ticks[1];
   Ticks[0].cnt=1;
   Ticks[0].res=true;
   Ticks[0].ter=1;
   Ticks[0].str = "SDf";
   ExchangeTicks.DataSave(Ticks);
//---
   return(INIT_SUCCEEDED);
  }

Lo conseguí de aquí para MT4

https://www.mql5.com/ru/forum/5905/page11#comment_6134460
 
Aleksei Beliakov:

Es así.

#define  DEFINE_STRING(A)                        \
  struct STRING##A                              \
  {                                             \
  private:                                      \
    short Array[A];                             \
                                                \
  public:                                       \
    void operator =( const string Str )         \
    {                                           \
      ::StringToShortArray(Str, this.Array);    \
                                                \
      return;                                   \
    }                                           \
                                                \
    string operator []( const int = 0 ) const   \
    {                                           \
      return(::ShortArrayToString(this.Array)); \
    }                                           \
  };                                            
  
DEFINE_STRING(128) // Un análogo de una cadena que tiene un máximo de 128 caracteres.

#undef  DEFINE_STRING

struct Message
  {
   int               cnt;
   bool              res;
   int               ter;
   STRING128         str;
  };
1234567
Nuevo comentario