Quiero aprender el lenguaje de programación del terminal MT5. ¿Por dónde empiezo como principiante? - página 6

[Ihor Herasko]

Vasiliy Kolesov:

No es conveniente aprender del libro de texto de Kovalev desde cero, ya que está anticuado. Empiezas a hacer algunos ejercicios y no se compilan. Y el simple hecho de leer, sin practicar, hace que sea más difícil recordar las cosas.

No creo que estemos hablando de ningún ejemplo sencillo. Probablemente ya esté al final del libro de texto. Y probablemente sea una cuestión de sintaxis, que, si se entienden los fundamentos, se corrige fácilmente. En cualquier caso, el TC siempre puede preguntar por qué tal o cual ejemplo no compila.

¿Puedes dar un ejemplo del tutorial que no compile? A modo de ejemplo, vamos a desglosarlo.

[Ihor Herasko]

Ilya Malev:

Te han aconsejado, con razón, que aprendas C++, porque es MQL, y hay mucho más material sobre C++.

Si sabes C++, entonces estudia MQL desde la ayuda, analizando los EAs de otras personas.

Esto es así si uno planifica sus actividades fuera de la MT. Pero no se puede planificar algo así de antemano. Ahora mismo el objetivo es aprender a escribir para la MT. Y si una persona comienza en C o C++, estará atascado allí por esas cosas que están ausentes en MQL desde el principio. Después de todo, incluso una simple impresión de valores no puede hacerse con cout. En este sentido, MQL es mucho más fácil: imprimir o alertar.

Así que es mejor empezar a aprender lo que necesitas. Y más tarde, si te gusta y quieres continuar, puedes cambiar a C++.

[BillionerClub]

Aprende C++ si eres principiante. Aquí hay un buen recursohttps://foxford.ru/wiki/informatika/otlichiya-yazykov-programmirovaniya-si-i-s

Evita a los no profesionales, su lenguaje es demasiado seco para recordar algo. Utiliza técnicas mnemotécnicas, hay muchos libros sobre este tema en Internet.

Personalmente, para memorizar algo, hay que imaginar una función, por ejemplo, como un objeto del mundo real, añadiendo más brillo y humor, sexo y surrealismo.

[Dmitiry Ananiev]

multiplicator:

es mejor

Hay que introducir 6 parámetros más en PositionOpen.

Los demás parámetros no necesitan ser prescritos

[Vasiliy Kolesov]

Ihor Herasko:

No son ejemplos sencillos. Probablemente ya esté al final de un libro de texto. Y probablemente se trate de la sintaxis, que, si se entiende lo básico, se puede arreglar fácilmente. En cualquier caso, el TC siempre puede preguntar por qué tal o cual ejemplo no compila.

¿Puedes dar un ejemplo del tutorial que no compile? Pongamos un ejemplo.

Sí, desde el principio, por ejemplo no existe la función Start, ahora esOnInit().

He encontrado una buena descripción aquí, si empiezas desde cerohttps://sgr-tradeinvest.ru/mql4

[Ihor Herasko]

Vasiliy Kolesov :

sí, desde el principio, por ejemplo, no hay función de inicio, ahora es OnInit()

Compilado. No hay errores. Solo una advertencia, que se corrige fácilmente con una comprensión elemental del término "función".

Incluso tomé un ejemplo un poco más grande:

 //--------------------------------------------------------------------
// tradingexpert.mq4 
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
#property copyright "Copyright © Book, 2007"
#property link        "http://AutoGraf.dp.ua"
//--------------------------------------------------------------- 1 --
                                   // Численные значения для М15
extern double StopLoss   = 200 ;     // SL для открываемого ордера
extern double TakeProfit = 39 ;       // ТР для открываемого ордера
extern int     Period_MA_1= 11 ;       // Период МА 1
extern int     Period_MA_2= 31 ;       // Период МА 2
extern double Rastvor    = 28.0 ;     // Расстояние между МА 
extern double Lots       = 0.1 ;     // Жестко заданное колич. лотов
extern double Prots      = 0.07 ;     // Процент свободных средств
 
bool Work= true ;                     // Эксперт будет работать.
string Symb;                       // Название финанс. инструмента
//--------------------------------------------------------------- 2 --
int start()
  {
   int
   Total,                           // Количество ордеров в окне 
   Tip=- 1 ,                           // Тип выбран. ордера (B=0,S=1)
   Ticket;                           // Номер ордера
   double
   MA_1_t,                           // Значен. МА_1 текущее
   MA_2_t,                           // Значен. МА_2 текущее 
   Lot,                             // Колич. лотов в выбран.ордере
   Lts,                             // Колич. лотов в открыв.ордере
   Min_Lot,                         // Минимальное количество лотов
   Step,                             // Шаг изменения размера лота
   Free,                             // Текущие свободные средства
   One_Lot,                         // Стоимость одного лота
   Price,                           // Цена выбранного ордера
   SL,                               // SL выбранного ордера 
   TP;                               // TP выбранного ордера
   bool
   Ans  = false ,                     // Ответ сервера после закрытия
   Cls_B= false ,                     // Критерий для закрытия  Buy
   Cls_S= false ,                     // Критерий для закрытия  Sell
   Opn_B= false ,                     // Критерий для открытия  Buy
   Opn_S= false ;                     // Критерий для открытия  Sell
//--------------------------------------------------------------- 3 --
   // Предварит.обработка
   if ( Bars < Period_MA_2)                       // Недостаточно баров
     {
       Alert ( "Недостаточно баров в окне. Эксперт не работает." );
       return ;                                   // Выход из start()
     }
   if (Work== false )                               // Критическая ошибка
     {
       Alert ( "Критическая ошибка. Эксперт не работает." );
       return ;                                   // Выход из start()
     }
//--------------------------------------------------------------- 4 --
   // Учёт ордеров
   Symb= Symbol ();                               // Название фин.инстр.
   Total= 0 ;                                     // Количество ордеров
   for ( int i= 1 ; i<= OrdersTotal (); i++)           // Цикл перебора ордер
     {
       if ( OrderSelect (i- 1 , SELECT_BY_POS )== true ) // Если есть следующий
        {                                       // Анализ ордеров:
         if ( OrderSymbol ()!=Symb) continue ;       // Не наш фин. инструм
         if ( OrderType ()> 1 )                     // Попался отложенный
           {
             Alert ( "Обнаружен отложенный ордер. Эксперт не работает." );
             return ;                             // Выход из start()
           }
         Total++;                               // Счётчик рыночн. орд
         if (Total> 1 )                           // Не более одного орд
           {
             Alert ( "Несколько рыночных ордеров. Эксперт не работает." );
             return ;                             // Выход из start()
           }
         Ticket= OrderTicket ();                   // Номер выбранн. орд.
         Tip   = OrderType ();                     // Тип выбранного орд.
         Price = OrderOpenPrice ();               // Цена выбранн. орд.
         SL    = OrderStopLoss ();                 // SL выбранного орд.
         TP    = OrderTakeProfit ();               // TP выбранного орд.
         Lot   = OrderLots ();                     // Количество лотов
        }
     }
//--------------------------------------------------------------- 5 --
   // Торговые критерии
   MA_1_t= iMA ( NULL , 0 ,Period_MA_1, 0 , MODE_LWMA , PRICE_TYPICAL , 0 ); // МА_1
   MA_2_t= iMA ( NULL , 0 ,Period_MA_2, 0 , MODE_LWMA , PRICE_TYPICAL , 0 ); // МА_2
 
   if (MA_1_t > MA_2_t + Rastvor* Point )         // Если разница между
     {                                           // ..МА 1 и 2 большая
      Opn_B= true ;                               // Критерий откр. Buy
      Cls_S= true ;                               // Критерий закр. Sell
     }
   if (MA_1_t < MA_2_t - Rastvor* Point )         // Если разница между
     {                                           // ..МА 1 и 2 большая
      Opn_S= true ;                               // Критерий откр. Sell
      Cls_B= true ;                               // Критерий закр. Buy
     }
//--------------------------------------------------------------- 6 --
   // Закрытие ордеров
   while ( true )                                   // Цикл закрытия орд.
     {
       if (Tip== 0 && Cls_B== true )                 // Открыт ордер Buy..
        {                                       //и есть критерий закр
         Alert ( "Попытка закрыть Buy " ,Ticket, ". Ожидание ответа.." );
         RefreshRates ();                         // Обновление данных
         Ans= OrderClose (Ticket,Lot, Bid , 2 );       // Закрытие Buy
         if (Ans== true )                         // Получилось :)
           {
             Alert ( "Закрыт ордер Buy " ,Ticket);
             break ;                               // Выход из цикла закр
           }
         if (Fun_Error( GetLastError ())== 1 )       // Обработка ошибок
             continue ;                           // Повторная попытка
         return ;                                 // Выход из start()
        }
 
       if (Tip== 1 && Cls_S== true )                 // Открыт ордер Sell..
        {                                       // и есть критерий закр
         Alert ( "Попытка закрыть Sell " ,Ticket, ". Ожидание ответа.." );
         RefreshRates ();                         // Обновление данных
         Ans= OrderClose (Ticket,Lot, Ask , 2 );       // Закрытие Sell
         if (Ans== true )                         // Получилось :)
           {
             Alert ( "Закрыт ордер Sell " ,Ticket);
             break ;                               // Выход из цикла закр
           }
         if (Fun_Error( GetLastError ())== 1 )       // Обработка ошибок
             continue ;                           // Повторная попытка
         return ;                                 // Выход из start()
        }
       break ;                                     // Выход из while
     }
//--------------------------------------------------------------- 7 --
   // Стоимость ордеров
   RefreshRates ();                               // Обновление данных
   Min_Lot= MarketInfo (Symb, MODE_MINLOT );         // Миним. колич. лотов 
   Free   = AccountFreeMargin ();                 // Свободн средства
   MarketInfo (Symb, MODE_MARGINREQUIRED ); // Стоимость 1 лота
   Step   = MarketInfo (Symb, MODE_LOTSTEP );       // Шаг изменен размера
 
   if (Lots > 0 )                                 // Если заданы лоты,то 
      Lts =Lots;                                 // с ними и работаем 
   else                                          // % свободных средств
      Lts= MathFloor (Free*Prots/One_Lot/Step)*Step; // Для открытия
 
   if (Lts < Min_Lot) Lts=Min_Lot;               // Не меньше минимальн
   if (Lts*One_Lot > Free)                       // Лот дороже свободн.
     {
       Alert ( " Не хватает денег на " , Lts, " лотов" );
       return ;                                   // Выход из start()
     }
//--------------------------------------------------------------- 8 --
   // Открытие ордеров
   while ( true )                                   // Цикл закрытия орд.
     {
       if (Total== 0 && Opn_B== true )               // Открытых орд. нет +
        {                                       // критерий откр. Buy
         RefreshRates ();                         // Обновление данных
         SL= Bid - New_Stop(StopLoss)* Point ;     // Вычисление SL откр.
         TP= Bid + New_Stop(TakeProfit)* Point ;   // Вычисление TP откр.
         Alert ( "Попытка открыть Buy. Ожидание ответа.." );
         Ticket= OrderSend (Symb, OP_BUY ,Lts, Ask , 2 ,SL,TP); //Открытие Buy
         if (Ticket > 0 )                         // Получилось :)
           {
             Alert ( "Открыт ордер Buy " ,Ticket);
             return ;                             // Выход из start()
           }
         if (Fun_Error( GetLastError ())== 1 )       // Обработка ошибок
             continue ;                           // Повторная попытка
         return ;                                 // Выход из start()
        }
       if (Total== 0 && Opn_S== true )               // Открытых орд. нет +
        {                                       // критерий откр. Sell
         RefreshRates ();                         // Обновление данных
         SL= Ask + New_Stop(StopLoss)* Point ;     // Вычисление SL откр.
         TP= Ask - New_Stop(TakeProfit)* Point ;   // Вычисление TP откр.
         Alert ( "Попытка открыть Sell. Ожидание ответа.." );
         Ticket= OrderSend (Symb, OP_SELL ,Lts, Bid , 2 ,SL,TP); //Открытие Sel
         if (Ticket > 0 )                         // Получилось :)
           {
             Alert ( "Открыт ордер Sell " ,Ticket);
             return ;                             // Выход из start()
           }
         if (Fun_Error( GetLastError ())== 1 )       // Обработка ошибок
             continue ;                           // Повторная попытка
         return ;                                 // Выход из start()
        }
       break ;                                     // Выход из while
     }
//--------------------------------------------------------------- 9 --
   return ;                                       // Выход из start()
  }
//-------------------------------------------------------------- 10 --
int Fun_Error( int Error)                         // Ф-ия обработ ошибок
  {
   switch (Error)
     {                                           // Преодолимые ошибки            
       case    4 : Alert ( "Торговый сервер занят. Пробуем ещё раз.." );
         Sleep ( 3000 );                           // Простое решение
         return ( 1 );                             // Выход из функции
       case 135 : Alert ( "Цена изменилась. Пробуем ещё раз.." );
         RefreshRates ();                         // Обновим данные
         return ( 1 );                             // Выход из функции
       case 136 : Alert ( "Нет цен. Ждём новый тик.." );
         while ( RefreshRates ()== false )           // До нового тика
             Sleep ( 1 );                           // Задержка в цикле
         return ( 1 );                             // Выход из функции
       case 137 : Alert ( "Брокер занят. Пробуем ещё раз.." );
         Sleep ( 3000 );                           // Простое решение
         return ( 1 );                             // Выход из функции
       case 146 : Alert ( "Подсистема торговли занята. Пробуем ещё.." );
         Sleep ( 500 );                             // Простое решение
         return ( 1 );                             // Выход из функции
         // Критические ошибки
       case    2 : Alert ( "Общая ошибка." );
         return ( 0 );                             // Выход из функции
       case    5 : Alert ( "Старая версия терминала." );
         Work= false ;                             // Больше не работать
         return ( 0 );                             // Выход из функции
       case 64 : Alert ( "Счет заблокирован." );
         Work= false ;                             // Больше не работать
         return ( 0 );                             // Выход из функции
       case 133 : Alert ( "Торговля запрещена." );
         return ( 0 );                             // Выход из функции
       case 134 : Alert ( "Недостаточно денег для совершения операции." );
         return ( 0 );                             // Выход из функции
       default : Alert ( "Возникла ошибка " ,Error); // Другие варианты   
         return ( 0 );                             // Выход из функции
     }
  }
//-------------------------------------------------------------- 11 --
int New_Stop( int Parametr)                       // Проверка стоп-прик.
  {
   int Min_Dist= MarketInfo (Symb, MODE_STOPLEVEL ); // Миним. дистанция
   if (Parametr < Min_Dist)                     // Если меньше допуст.
     {
      Parametr=Min_Dist;                         // Установим допуст.
       Alert ( "Увеличена дистанция стоп-приказа." );
     }
   return (Parametr);                             // Возврат значения
  }
//-------------------------------------------------------------- 12 --

También compila. 12 advertencias, pero ninguna de ellas afecta el rendimiento del programa. También se corrigen. Por lo tanto, para comenzar el Tutorial, eso es todo.

[Ihor Herasko]

BillionerClub:

Aprende C++ si eres principiante. Aquí hay un buen recursohttps://foxford.ru/wiki/informatika/otlichiya-yazykov-programmirovaniya-si-i-s

El hombre necesita que lo lleven y tú le estás dando largas. En la fase de dominio de MQL la cuestión de si el programador necesita programar en principio, si puede llevarlo a cabo. MQL es más fácil que C++. ¿Por qué molestarse con las cosas complicadas?

Sobre todo, que el enlace anterior incluye todo lo que MQL no tiene: biblioteca estándar (MLQ tiene, pero propia, no C++), espacio de nombres, entrada y salida mediante cout y cin.

[Vasiliy Kolesov]

Ihor Herasko:

Compilado. No hay errores. Sólo una advertencia, que se corrige fácilmente con una comprensión básica del término "función".

Incluso tomé un ejemplo un poco más grande:

También compila. Hay 12 advertencias, pero ninguna de ellas afecta a la operatividad del programa. También se pueden arreglar fácilmente. Por eso el tutorial es un buen punto de partida.

Por alguna razón lo probé y no funcionó. Pensé que era por el cambio de nombre. Gracias por probarlo. Tal vez deberíamos volver a ello.

[Dmitry Fedoseev]

Vitaly Muzichenko:

Yuri, bueno, todo el mundo empieza en algún sitio.

Empecé con .php, luego estudié .js porque sin él, escribir algo normal simplemente no es realista. Cuando .js se complementaba con la librería jquery, era una gozada, pero había que aprenderla. Mucha gente escribió entonces que era una tontería y que sólo había que usar .js puro, después todo el mundo se pasó a usar jquery, porque las librerías molan.

Cuando toqué forex, estudié .mql porque lo necesitaba, aunque era difícil, no es lo mismo que php y js.

Así que lo único que importa es el deseo.

Ahora, para ser un chico cool, no basta con jquery, hay que estudiar ***teen más frameworks... Así es como el programador medio vive toda su vida de programador inacabado: aprende un framework y aparecen tres más a la vez.

[Dmitry Fedoseev]

Anastasia Vasilenko:
¿Qué has estudiado?

Si supieras lo que ya sabes y lo que puedes hacer. En general - sólo tome el Asesor Experto del kit de terminal, ábralo en el editor y vea si algo en el código está resaltado en un color diferente - ponga el cursor allí, presione f1 y lea la ayuda.

Si no está en absoluto familiarizado con la programación, no sabe para qué, si, etc. - Puedes empezar con cualquier libro de idiomas para dummies o libros infantiles.