Nützliche Funktionen von KimIV - Seite 54

[Igor Kim]

Die Funktion TakeProfitLastPos().

Diese Funktion gibt das TakeProfit-Kursniveau der letzten offenen Position oder -1 zurück. Die Funktion TakeProfitLastPos() akzeptiert die folgenden optionalen Parameter:

• sy - Name des Instruments. "" - beliebiges Symbol, NULL - aktuelles Symbol. Der Standardwert ist "".
• op - Handelsoperation. Gültige Werte: -1, OP_BUY, OP_SELL. Der Standardwert ist -1 - beliebiger Handel.
• mn - Handelskennzeichen, MagicNumber. Standardwert -1 - beliebige Magie.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 06.08.2008                                                     |
//|  Описание : Возвращает цену TakeProfit последней открытой позиций или -1.  |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double TakeProfitLastPos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=-1;
  int      i, k=OrdersTotal();

  if ( sy=="0") sy=Symbol();
  for ( i=0; i< k; i++) {
    if (OrderSelect( i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()== sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if ( op<0 || OrderType()== op) {
            if ( mn<0 || OrderMagicNumber()== mn) {
              if ( t<OrderOpenTime()) {
                t=OrderOpenTime();
                r=OrderTakeProfit();
              }
            }
          }
        }
      }
    }
  }
  return( r);
}

Diese Funktion kann z.B. verwendet werden, um das Preisniveau des TakeProfit der letzten offenen Position zu ermitteln, um anschließend eine Pending Order auf diesem Niveau zu platzieren.

[Юрий Жданов]

Wie wäre es, das "richtige" Los zur richtigen Zeit zu öffnen?

[[Gelöscht]]

Können Sie mir sagen, ob es eine Möglichkeit gibt, die Losgröße eines schwebenden Auftrags in MQL4 zu ändern?

[Rashid Umarov]

sdgg >> :
Wissen Sie, ob es eine Möglichkeit gibt, die Losgröße eines schwebenden Auftrags in MQL4 zu ändern?

Nein. Sie löschen den alten Auftrag und legen einen neuen mit dem gewünschten Volumen an.

[Yuriy Zaytsev]

sdgg писал (а) >>
Können Sie mir sagen, ob es eine Möglichkeit gibt, das Los eines schwebenden Auftrags in MQL4 zu ändern?

Die Entwickler haben das nicht absichtlich getan - um Probleme zu vermeiden!

[RGTmy]

Ich möchte wissen, wie ich in einem EA, der mit zwei Währungspaaren handelt, grafische Objekte erstellen kann, die auf jedem Chart die Eröffnungs- und Schlusspositionen für jedes Währungspaar markieren. Ein EA, der auf einen einzelnen Chart geladen wird, erstellt diese Markierungen automatisch nur auf diesem Chart. Vielleicht gibt es eine solche Funktion, die für die Verwendung in EAs mit mehreren Währungen gedacht ist?

[Rashid Umarov]

RGT >> :

Ich möchte wissen, wie ich in einem EA, der mit zwei Währungspaaren handelt, grafische Objekte erstellen kann, die auf jedem Chart die Eröffnungs- und Schlusspositionen für jedes Währungspaar markieren. Ein EA, der auf einen einzelnen Chart geladen wird, erstellt diese Markierungen automatisch nur auf diesem Chart. Vielleicht gibt es eine solche Funktion, die für die Verwendung in EAs mit mehreren Währungen gedacht ist?

Eine solche Funktion gibt es nicht. Objekte können nur auf dem Diagramm erstellt und verwaltet werden, dem der EA zugeordnet ist.

[Igor Kim]

TakeProfitLastClosePos() Funktion.

Gibt das TakeProfit-Kursniveau der letzten geschlossenen Position oder -1 zurück. Die Funktion TakeProfitLastClosePos() akzeptiert die folgenden optionalen Parameter:

• sy - Name des Instruments. "" - beliebiges Symbol, NULL - aktuelles Symbol. Der Standardwert ist "".
• op - Handelsoperation. Gültige Werte: -1, OP_BUY, OP_SELL. Der Standardwert ist -1 - beliebiger Handel.
• mn - Handelskennzeichen, MagicNumber. Standardwert -1 - beliebige Magie.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 20.10.2008                                                     |
//|  Описание : Возвращает цену TakeProfit последней закрытой позиций или -1.  |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double TakeProfitLastClosePos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=-1;
  int      i, k=OrdersHistoryTotal();

  if ( sy=="0") sy=Symbol();
  for ( i=0; i< k; i++) {
    if (OrderSelect( i, SELECT_BY_POS, MODE_HISTORY)) {
      if (OrderSymbol()== sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if ( op<0 || OrderType()== op) {
            if ( mn<0 || OrderMagicNumber()== mn) {
              if ( t<OrderCloseTime()) {
                t=OrderCloseTime();
                r=OrderTakeProfit();
              }
            }
          }
        }
      }
    }
  }
  return( r);
}

[drm]

KimIV >> :

TakeProfitLastClosePos() Funktion.

Gibt das TakeProfit-Kursniveau der letzten geschlossenen Position oder -1 zurück. Die Funktion TakeProfitLastClosePos() akzeptiert die folgenden optionalen Parameter:

• sy - Name des Instruments. "" - beliebiges Symbol, NULL - aktuelles Symbol. Der Standardwert ist "".
• op - Handelsoperation. Gültige Werte: -1, OP_BUY, OP_SELL. Der Standardwert ist -1 - beliebiger Handel.
• mn - Handelskennzeichen, MagicNumber. Standardwert -1 - eine beliebige magische Zahl.

Gibt es eine Funktion, die den Take Profit ändert, nachdem eine gewisse Zeit seit der Eröffnung der Position vergangen ist?

[Igor Kim]

drm1 писал(а) >>

Gibt es eine Funktion, die den Take-Profit nach einiger Zeit nach Eröffnung der Position ändert?

ÄndernAuftrag()

Nachfolgend finden Sie einige Beispiele für die Verwendung dieser Funktion...