MQL5 向导 - 基于Bullish Engulfing（牛市吞烛）/Bearish Engulfing（熊市吞烛）和 Stochastic 的交易信号。 - MetaTrader 5EA

MQL5向导允许基于与客户终端一起提供的 标准库 类快速创建EA交易。 (详细信息参考 使用MQL5 向导快速创建EA交易)。它允许快速检测你的交易想法，你所要做的只是创建你自己的交易信号类。这个类的结构和例子可以在MQL5向导：如何创建交易信号的一个模块一文中找到。

总的思想如下：交易信号的类继承CExpertSignal，下一步，需要使用你自己的方法覆盖 LongCondition()和 ShortCondition() 这两个虚拟方法。

有一本书叫"最佳交易者的策略", 其中讨论了许多交易策略，我们将集中在由 Stochastic, CCI, MFI和RSI这些震荡指标确认的反转K线图模式。

最好的方式是创建继承自CExpertSignal的单独类来检查K线图模式的形成。为确认由K线图模式产生的交易信号，编写继承于CCandlePattern的类并在其中增加必要的特性（比如：由oscillators确认）就可以了。

这里我们将讨论基于 "Bullish Engulfing（牛市吞烛）/Bearish Engulfing（熊市吞烛） " K线图反转模式并由Stochastic指标确认的信号。. 交易信号模块基于 CCandlePattern 类，它是使用K线图模式创建交易信号的简单实例。

1. K线图反转模式“牛市吞烛”和“熊市吞烛”

1.1. 牛市吞烛

在下降趋势中当一个小的阴线被紧接其后的大的阳线完全包裹("吞噬")的时候则形成“牛市吞烛”反转模式。小阴线的阴影（尾巴）很短，使得大阳线的实体可以覆盖前一天的整个K线。

Fig. 1. "牛市吞烛" K线图模式

“牛市吞烛”模式的识别实现在CCandlePattern类的CheckPatternBullishEngulfing()方法:

//+------------------------------------------------------------------+
//| 检测 "牛市 吞烛" K线图模式的形成                                     |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishEngulfing()
  {
//--- 牛市吞烛
   if((Open(2)>Close(2))             &&  // 前一根K线为阴线
      (Close(1)-Open(1)>AvgBody(1))  &&  // 阳线的实体比通常实体都长 
      (Close(1)>Open(2))             &&  // 阳线的收盘价比前一根阴线的开盘价高
      (MidOpenClose(2)<CloseAvg(2))  &&  // 下降趋势
      (Open(1)<Close(2)))                // 阳线的开盘价比前一根阴线的收盘价低
      return(true);
//---
   return(false);
  }

1.2. 熊市吞烛

在上升趋势中当一个小的阳线被紧接其后的大的阴线完全包裹("吞噬")的时候则形成“熊市吞烛”反转模式。小阴线的阴影（尾巴）很短，使得大阳线的实体可以覆盖前一天的整个K线。

Fig. 2. "熊市吞烛" K线图模式

“熊市吞烛”模式的识别实现在CCandlePattern类的CheckPatternBearishEngulfing()方法:

//+------------------------------------------------------------------+
//| 检测"熊市吞烛" K线图模式的形成                                       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishEngulfing()
  {
//--- 熊市 吞烛
   if((Open(2)<Close(2))            &&  // 前一根K线是阳线
      (Open(1)-Close(1)>AvgBody(1)) &&  // K线的实体比通常实体都长
      (Close(1)<Open(2))            &&  // 阴线的收盘价比前一根阳线的开盘价低
      (MidOpenClose(2)>CloseAvg(2)) &&  // 上升趋势
      (Open(1)>Close(2)))               // 阴线的开盘价比前一根阳线的收盘价高
      return(true);
//---
   return(false);
  }

2. 由Stochastic指标确认交易信号

建立多头或空头头寸的交易信号必须由Stochastic振荡器确认。信号％D线必须大于/低于相应的临界水平（30或70）。

平掉持仓头寸取决于％D指标的值。它有两种情况:

1. 如果%D达到相反的临界水平（多头头寸为80而空头头寸为20）
2. 如果反转信号没有被确认（％D线达到以下水平：多头头寸为20而空头头寸为80）

Fig. 3. 由Stochastic指标确认的"牛市吞烛" 模式

进入和退出的交易条件的检测实现在两个方法中:

• int CBE_BE_Stoch::LongCondition() - 检查建立多头头寸 (返回80) 和平掉空头头寸（返回40）的条件;
  
• int CBE_BE_Stoch::ShortCondition() - 检查建立空头头寸 (返回80) 和平掉多头头寸（返回40）的条件。

2.1. 建立多头头寸/平掉空头头寸

1. “牛市吞烛“模式的形成必须由 Stochastic 指标确认: StochSignal(1)<30 (最后结束K线的Stochastic指标信号线的值必须小于30)。

2. 如果Stochastic 指标的信号线向上穿越20或80水平，空头头寸必须被平仓.

//+------------------------------------------------------------------+
//| 检测进入和退出市场的条件                                             |
//| 1) 市场进入 (建立多头头寸, result=80)                               |
//| 2) 市场退出 (平掉空头头寸, result=40)                               |
//+------------------------------------------------------------------+
int CBE_BE_Stoch::LongCondition()
  {
   int result=0;
//--- idx可被用来决定EA交易工作模式
//--- idx=0 - 此种情况EA在每个即时价位检查交易条件
//--- idx=1 - 此种情况EA 只在新建柱线时检查交易条件
   int idx   =StartIndex();
//--- 检查建立多头头寸的条件
//--- 牛市吞烛模式形成并且信号线小于30
  if (CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) && (StochSignal(1)<30))
     result=80;
//--- 检查平掉空头头寸的条件
//--- 信号线跨越超买超卖水平( 向下跌破20, 向上超过80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- 返回结果
   return(result);
  }

2.2. 建立空头尺寸/平掉多头尺寸

1. “熊市吞烛“模式的形成必须由 Stochastic 指标确认: StochSignal(1)>70 (最后结束K线的Stochastic指标信号线的值必须大于70)。

2. 如果Stochastic 指标的信号线向下穿越80或20水平，多头头寸必须被平仓。

//+------------------------------------------------------------------+
//| 检测进入和退出市场的条件                                             |
//| 1) 市场进入 (建立空头头寸, result=80)                               |
//| 2) 市场退出 (平掉多头头寸, result=40)                               |
//+------------------------------------------------------------------+
int CBE_BE_Stoch::ShortCondition()
  {
   int result=0;
//--- idx可被用来决定EA交易工作模式
//--- idx=0 -此种情况EA在每个即时价位检查交易条件
//--- idx=1 - 此种情况EA 只在新建柱线时检查交易条件
   int idx   =StartIndex();
//--- 检查建立空头头寸的条件
//---熊市吞烛模式形成并且信号线大于70
  if (CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) && (StochSignal(1)>70))
     result=80;
//--- 检查平掉多头头寸的条件
//---信号线跨越超买超卖水平( 向下跌破80, 向上超过20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//---返回结果
   return(result);
  }

2.3. 使用MQL5向导创造EA 交易

为创建EA交易请启动 MQL5向导:

Fig. 4. 使用MQL5向导创造EA 交易

让我们指定EA交易的名称:

Fig. 5. EA交易的通用属性

在这之后我们需要选择将被使用的交易信号模块。

Fig. 6. EA交易的信号属性

在我们的例子中，我们只使用一个交易信号模块。

增加交易信号模块 "Signals based on Bullish Engulfing/Bearish Engulfing confirmed by Stochastic" :

Fig. 7. EA交易的信号属性

添加的交易信号模块:

Fig. 8. EA交易的信号属性

你可以选择任意的追踪属性, 但我们将使用 "Trailing Stop not used（不使用移动止损）":

Fig. 9. EA交易的追踪属性

关于资金管理属性，我们将使用“Trading with fixed trade volume（以固定交易手数交易）”：

Fig. 10. EA交易的资金管理属性

通过按”Finish(完成)“按钮，我们将得到生成的EA交易的代码，代码放置在Expert_ABE_BE_Stoch.mq5, 它将被保存到 terminal_data_folder\MQL5\Experts\.

所生成EA交易的默认输入参数:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // 建仓的信号阈值 [0...100]
input int            Signal_ThresholdClose  =10;     //  平仓的信号阈 [0...100]
input double         Signal_PriceLevel      =0.0;    // 执行交易的价格水平
input double         Signal_StopLevel       =50.0;   // 止损水平 (点数)
input double         Signal_TakeLevel       =50.0;   // 止盈水平 (点数)

必须被替换为:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // 建仓的信号阈值 [0...100]
input int            Signal_ThresholdClose  =20;     // 平仓的信号阈值 [0...100]
input double         Signal_PriceLevel      =0.0;    //  执行交易的价格水平
input double         Signal_StopLevel       =0.0;    // 止损水平 (点数)
input double         Signal_TakeLevel       =0.0;    // 止盈水平 (点数)

Signal_ThresholdOpen/Signal_ThresholdClose输入参数允许指定建仓和平仓的阈值水平。

在交易信号类的LongCondition() 和ShortCondition()方法的代码中我们指定了阈值的固定值:

• 建立头寸: 80;
• 平掉头寸: 40.
  

Signal_StopLevel和Signal_TakeLevel输入参数的值被设置为0, 它意味着只有关闭条件为true时才平仓。

2.4. 历史回测结果

让我们来考察EA交易在历史数据(EURUSD H1, 自定义时段: 2010.01.01-2011.03.04, PeriodK=47,PeriodD=9, PeriodSlow=13, MA_period=5)上的回溯测试。

在创建EA 交易时，我们使用了固定交易量 (固定交易手数, 0.1),未使用移动止损算法 (不使用移动)。

Fig. 11. 基于牛市吞烛/熊市吞烛和Stochastic的EA交易的测试结果

最优输入参数集合可使用MetaTrader 5客户端的 Strategy Tester找到。

由MQL5向导创建的EA交易代码附加在expert_abe_be_stoch.mq5.