Почему мигает ZigZag + текстовые метки в МТ5 ?

Alexandr Gavrilin 2022.10.31 07:55

В МТ4 такой проблемы не обнаружено, но в МТ5, если индикатор рисует ZigZag с помощью DRAW_SECTION и на графике используются объекты (текстовые метки), то начинает ZigZag мигать!

В Тестере стратегий он не мигает, только когда на графике.

Когда будет решена данная проблема в МТ5? Или можно как-то эту проблему обойти? Еще раз повторю, что в мт4 такой проблемы нет. И эта проблема только с индикаторами , которые реализуются через DRAW_SECTION с линиями такой проблемы нет.

Дополню еще вот какой момент заметил: Если запустить в тестере стратегий данный индикатор, то на графиках он вообще перестает рисовать. Это че за чудеса???

За основу взят стандартный зигзаг и добавлены метки к его экстремумам. Проблема видна в любой день когда идет поток тиков.

//+------------------------------------------------------------------+
//|                                                       ZigZag.mq5 |
//|                   Copyright 2009-2020, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "2009-2020, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_plots   1
//--- plot ZigZag
#property indicator_label1  "ZigZag"
#property indicator_type1   DRAW_SECTION
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1

#include <ChartObjects\ChartObjectsTxtControls.mqh>

//--- input parameters
input int InpDepth    =12;  // Depth
input int InpDeviation=5;   // Deviation
input int InpBackstep =3;   // Back Step

input int   MaxLabels=100; //Max labels
input color TextColor=clrRed; //Text color
input int   TextSize=12; //Text size
//--- indicator buffers
double    ZigZagBuffer[];      // main buffer
double    HighMapBuffer[];     // ZigZag high extremes (peaks)
double    LowMapBuffer[];      // ZigZag low extremes (bottoms)

int       ExtRecalc=3;         // number of last extremes for recalculation

enum EnSearchMode
  {
   Extremum=0, // searching for the first extremum
   Peak=1,     // searching for the next ZigZag peak
   Bottom=-1   // searching for the next ZigZag bottom
  };

CChartObjectText g_label;
void OnDeinit(const int reason)
  {
   ObjectsDeleteAll(0,"zz_");
  }
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ZigZagBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,HighMapBuffer,INDICATOR_CALCULATIONS);
   SetIndexBuffer(2,LowMapBuffer,INDICATOR_CALCULATIONS);
//--- set short name and digits
   string short_name=StringFormat("ZigZagPro(%d,%d,%d)",InpDepth,InpDeviation,InpBackstep);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
   PlotIndexSetString(0,PLOT_LABEL,short_name);
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- set an empty value
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
  }
//+------------------------------------------------------------------+
//| ZigZag calculation                                               |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   if(rates_total<100)
      return(0);

   int    i=0;
   int    start=0,extreme_counter=0,extreme_search=Extremum;
   int    shift=0,back=0,last_high_pos=0,last_low_pos=0;
   double val=0,res=0;
   double curlow=0,curhigh=0,last_high=0,last_low=0;
//--- initializing
   if(prev_calculated==0)
     {
      ArrayInitialize(ZigZagBuffer,0.0);
      ArrayInitialize(HighMapBuffer,0.0);
      ArrayInitialize(LowMapBuffer,0.0);
      start=InpDepth;
     }

//--- ZigZag was already calculated before
   if(prev_calculated>0)
     {
      i=rates_total-1;
      //--- searching for the third extremum from the last uncompleted bar
      while(extreme_counter<ExtRecalc && i>rates_total-100)
        {
         res=ZigZagBuffer[i];
         if(res!=0.0)
            extreme_counter++;
         i--;
        }
      i++;
      start=i;

      //--- what type of exremum we search for
      if(LowMapBuffer[i]!=0.0)
        {
         curlow=LowMapBuffer[i];
         extreme_search=Peak;
        }
      else
        {
         curhigh=HighMapBuffer[i];
         extreme_search=Bottom;
        }
      //--- clear indicator values
      for(i=start+1; i<rates_total && !IsStopped(); i++)
        {
         ZigZagBuffer[i] =0.0;
         LowMapBuffer[i] =0.0;
         HighMapBuffer[i]=0.0;
        }
     }

//--- searching for high and low extremes
   for(shift=start; shift<rates_total && !IsStopped(); shift++)
     {
      //--- low
      val=low[Lowest(low,InpDepth,shift)];
      if(val==last_low)
         val=0.0;
      else
        {
         last_low=val;
         if((low[shift]-val)>InpDeviation*_Point)
            val=0.0;
         else
           {
            for(back=1; back<=InpBackstep; back++)
              {
               res=LowMapBuffer[shift-back];
               if((res!=0) && (res>val))
                  LowMapBuffer[shift-back]=0.0;
              }
           }
        }
      if(low[shift]==val)
         LowMapBuffer[shift]=val;
      else
         LowMapBuffer[shift]=0.0;
      //--- high
      val=high[Highest(high,InpDepth,shift)];
      if(val==last_high)
         val=0.0;
      else
        {
         last_high=val;
         if((val-high[shift])>InpDeviation*_Point)
            val=0.0;
         else
           {
            for(back=1; back<=InpBackstep; back++)
              {
               res=HighMapBuffer[shift-back];
               if((res!=0) && (res<val))
                  HighMapBuffer[shift-back]=0.0;
              }
           }
        }
      if(high[shift]==val)
         HighMapBuffer[shift]=val;
      else
         HighMapBuffer[shift]=0.0;
     }

//--- set last values
   if(extreme_search==0) // undefined values
     {
      last_low=0.0;
      last_high=0.0;
     }
   else
     {
      last_low=curlow;
      last_high=curhigh;
     }

//--- final selection of extreme points for ZigZag
   for(shift=start; shift<rates_total && !IsStopped(); shift++)
     {
      res=0.0;
      switch(extreme_search)
        {
         case Extremum:
            if(last_low==0.0 && last_high==0.0)
              {
               if(HighMapBuffer[shift]!=0)
                 {
                  last_high=high[shift];
                  last_high_pos=shift;
                  extreme_search=Bottom;
                  ZigZagBuffer[shift]=last_high;
                  res=1;
                 }
               if(LowMapBuffer[shift]!=0.0)
                 {
                  last_low=low[shift];
                  last_low_pos=shift;
                  extreme_search=Peak;
                  ZigZagBuffer[shift]=last_low;
                  res=1;
                 }
              }
            break;
         case Peak:
            if(LowMapBuffer[shift]!=0.0 && LowMapBuffer[shift]<last_low && HighMapBuffer[shift]==0.0)
              {
               ZigZagBuffer[last_low_pos]=0.0;
               last_low_pos=shift;
               last_low=LowMapBuffer[shift];
               ZigZagBuffer[shift]=last_low;
               res=1;
              }
            if(HighMapBuffer[shift]!=0.0 && LowMapBuffer[shift]==0.0)
              {
               last_high=HighMapBuffer[shift];
               last_high_pos=shift;
               ZigZagBuffer[shift]=last_high;
               extreme_search=Bottom;
               res=1;
              }
            break;
         case Bottom:
            if(HighMapBuffer[shift]!=0.0 && HighMapBuffer[shift]>last_high && LowMapBuffer[shift]==0.0)
              {
               ZigZagBuffer[last_high_pos]=0.0;
               last_high_pos=shift;
               last_high=HighMapBuffer[shift];
               ZigZagBuffer[shift]=last_high;
              }
            if(LowMapBuffer[shift]!=0.0 && HighMapBuffer[shift]==0.0)
              {
               last_low=LowMapBuffer[shift];
               last_low_pos=shift;
               ZigZagBuffer[shift]=last_low;
               extreme_search=Peak;
              }
            break;
         default:
           {
            Print("end");
            return(rates_total);
           }
        }
     }

   double dzz[2]= {0,0};
   int j=0;

   bool bfirst=true;
   for(i=0; i<rates_total && !IsStopped(); i++)
     {
      if(ZigZagBuffer[i]==0.0)
        {
         string sLabel=StringFormat("zz_%ld",time[i]);
         if(ObjectFind(0,sLabel)>=0)
            ObjectDelete(0,sLabel);

         continue;
        }

      if(bfirst)
        {
         bfirst=false;

         dzz[j]=ZigZagBuffer[i]; //сохраняем первый0

         j++;
        }
      else
        {
         dzz[j]=ZigZagBuffer[i]; //1
         double ddelta=NormalizeDouble(MathAbs(dzz[0]-dzz[1])/_Point,0);
         string sLabel=StringFormat("zz_%ld",time[i]);
         if(!g_label.Attach(0,sLabel,0,1))
           {
            //объект создаем 1 раз.
            g_label.Create(0,sLabel,0,time[i],dzz[j]);
            g_label.Anchor(ANCHOR_CENTER);
            g_label.Color(TextColor);
            g_label.Description(StringFormat("%d",(int)ddelta));
            g_label.FontSize(TextSize);
           }

         if(i==0) //если перерисовка на 0 баре, сместим метку и обновим текст
           {
            g_label.Price(1,dzz[j]);
            g_label.Description(StringFormat("%d",(int)ddelta));
           }

         j=0;
         dzz[j]=dzz[j+1];
         j++;
        }
     }


//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//|  Search for the index of the highest bar                         |
//+------------------------------------------------------------------+
int Highest(const double &array[],const int depth,const int start)
  {
   if(start<0)
      return(0);

   double max=array[start];
   int    index=start;
//--- start searching
   for(int i=start-1; i>start-depth && i>=0; i--)
     {
      if(array[i]>max)
        {
         index=i;
         max=array[i];
        }
     }
//--- return index of the highest bar
   return(index);
  }
//+------------------------------------------------------------------+
//|  Search for the index of the lowest bar                          |
//+------------------------------------------------------------------+
int Lowest(const double &array[],const int depth,const int start)
  {
   if(start<0)
      return(0);

   double min=array[start];
   int    index=start;
//--- start searching
   for(int i=start-1; i>start-depth && i>=0; i--)
     {
      if(array[i]<min)
        {
         index=i;
         min=array[i];
        }
     }
//--- return index of the lowest bar
   return(index);
  }
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+

Файлы:

ZigZagPro.mq5 22 kb

lynxntech 2022.10.31 10:01 #1

самое простое избавиться от пересчета на каждом тике

//--- проверка на новый бар
   if(prev_calculated==rates_total)
      return(rates_total);

Alexandr Gavrilin 2022.11.01 07:04 #2

lynxntech #:

самое простое избавиться от пересчета на каждом тике

К сожалению в некоторых индикаторах мне нужно чтобы он каждый тик считал. В данном же варианте на 0м баре у нас может зигзаг перерисовывать свой экстремум и нужно обновлять данные в моменте.

Ваш костыль, это временное решение, но оно подходит не для всех случаев. И мигание все равно будет при формировании новых баров.

Индиктор TMA+CG mladen - Как кодировать? Ошибки, баги, вопросы

Nikolay Ivanov 2022.11.01 15:10 #3

у вас вся история пересчитывается каждый тик? (неохота изучать код)

Alexandr Gavrilin 2022.11.02 06:19 #4

Nikolay Ivanov #:
у вас вся история пересчитывается каждый тик? (неохота изучать код)

это стандартный зигзаг из терминала + метки.

но для правильного отображения метки на 0м баре при обновлении надо пересчитывать последние экстремумы.

Ivan Finogenov 2022.11.02 13:36 #5

Александр, как-то будет исправлена данная проблема в МТ5?

Stanislav Korotky 2022.11.02 16:07 #6

Справедливости ради стоит пофиксить для начала кое-какие баги представленного исходника (без этого у меня ваш зигзаг вообще не рисовался, только метки).

Цикл от start:

...
bool bfirst=true;
for(i=/*0*/start; i<rates_total && !IsStopped(); i++)
...

Последний бар не 0, т.к. направление индексации в МТ5 обратное (если явно не установить ArraySetAsSeries(...true)).

if(i==/*0*/rates_total - 1) //если перерисовка на 0 баре, сместим метку и обновим текст
{
  g_label.Price(1,dzz[j]);
  g_label.Description(StringFormat("%d",(int)ddelta));
}

В принципе, идея источника мигания (предположительно) в том, что работа с объектами занимает слишком много времени. Пока MQ не исправит, можно попробовать работу с объектами выполнять отложенным образом по таймеру, например раз в секунду.

Для чего нужна функция Вопросы по ООП в Как запретить удаление некоторых

Nikolai Semko 2022.11.03 01:35 #7

Alexandr Gavrilin #:

это стандартный зигзаг из терминала + метки.

но для правильного отображения метки на 0м баре при обновлении надо пересчитывать последние экстремумы.

зачем создавать метки там где их не видно. Полмиллиона меток - это жесть!
Еще раз - обратите внимание на канвас. Кода будет меньше, работать будет быстрее. Вместо десятков или сотен тысяч объектов будет только один.

Проблема с подключением библиотеки Что-то не так с Что надо делать переменной

Nikolai Semko 2022.11.03 05:15 #8

Nikolai Semko #:

зачем создавать метки там где их не видно. Полмиллиона меток - это жесть!
Еще раз - обратите внимание на канвас. Кода будет меньше, работать будет быстрее. Вместо десятков или сотен тысяч объектов будет только один.

например так

Файлы:

ZigZagPro.mq5 23 kb

iCanvas_CB.mqh 57 kb

Nikolai Semko 2022.11.03 14:00 #9

Alexandr Gavrilin #:

это стандартный зигзаг из терминала + метки.

но для правильного отображения метки на 0м баре при обновлении надо пересчитывать последние экстремумы.

Ваши главные тормоза:

чем больше объектов, тем больше тормозов. Причем вы не можете оптимизировать поиск и он происходит простым перебором таблицы объектов с начала таблицы объектов, а надо с конца.
У меня этот поиск реализован максимально оптимально:

while (size_labels>0 && labels[size_labels-1].time>=time[i]) size_labels--;

Именно поэтому мой вариант индикатора на canvas расчитывается достаточно быстро даже на unlimited bars на M1, а ваш на объектах в такой же ситуации безнадежно виснет.

Как правильно удалять объекты Почему не удаляется горизонталь? Ошибки, баги, вопросы

Alexandr Gavrilin 2022.11.04 08:14 #10

Nikolai Semko #:

Ваши главные тормоза:

спасибо за советы, но это код был взят тот что в примерах терминала.

Решение через канвас изучу, спасибо.

1 2

Новый комментарий