Особенности языка mql5, тонкости и приёмы работы - страница 207

[fxsaber]

mktr8591:

Пример использования из жизни - в библиотеке Virtual класс VIRTUAL содержит static const VIRTUAL_DELETE VirtualDelete;

Его можно заменить на  static const VIRTUAL static_Virtual;

(и конечно  перенести деструктор в VIRTUAL) .

Нельзя. new-объекты при завершении программы не вызывают свой деструктор.

[mktr8591]

fxsaber:

Нельзя. new-объекты при завершении программы не вызывают свой деструктор.

Простите, не понял, где в VIRTUAL_DELETE new?

[fxsaber]

mktr8591:
Простите, не понял, где в VIRTUAL_DELETE new?

В VIRTUAL::Create.

ЗЫ Ветка не про Virtual...

[fxsaber]

Добыча своего Alert-окна.

#ifdef __MQL5__
  #include <WinAPI\WinAPI.mqh>
#else // #ifdef __MQL5__
  #define long int
    #define pack(A)  
      #include <WinAPI\WinAPI.mqh>
    #undef pack
  #undef long
  
  #undef HANDLE
  #define HANDLE int
#endif // #ifdef __MQL5__ #else

uint GetProcessID( const HANDLE Handle )
{
  uint ID = 0;
  
  user32::GetWindowThreadProcessId(Handle, ID);
  
  return(ID);
}

// Возвращает хендл Alert-окна.
HANDLE GetAlertHandle( void )
{  
  static HANDLE Handle = 0;
  
  if (!Handle)
  {
    static const string AlertCaptions[] = {"Alert", "Алерт"};
    static const uint ProcessID = GetProcessID((HANDLE)::ChartGetInteger(0, CHART_WINDOW_HANDLE));  
    
    for (int i = 0; i < sizeof(AlertCaptions) / 12; i++)  
    {
      Handle = user32::FindWindowW("#32770", AlertCaptions[i]);
      
      if (Handle && (GetProcessID(Handle) == ProcessID))
        break;
      else
        Handle = 0;
    }
  }
    
  return(Handle);
}

[fxsaber]

Нагрузка CPU при кастомных событиях.

void OnInit()
{
  EventChartCustom(0, 0, 0, 0, NULL);
}

void OnChartEvent( const int id, const long&, const double&, const string& )
{
  if (id == CHARTEVENT_CUSTOM)
  {
    Sleep(0); // Без этой строки будет 100%-я нагрузка ядра CPU.
    
    EventChartCustom(0, 0, 0, 0, NULL);
  }
}

[Artyom Trishkin]

Комментарии, не относящиеся к этой теме, были перенесены в "Любые вопросы новичков по MQL4 и MQL5, помощь и обсуждение по алгоритмам и кодам".

[fxsaber]

Иногда DEAL_TIME меньше DEAL_ORDER_TIME_SETUP. Наверное, это баг софта брокеров.

// Показывает ордера, которые имеют время выставления ПОЗЖЕ сделок, которые породил.
#property script_show_inputs

input datetime inFrom = D'2021.06.01';

void OnStart()
{
  if (HistorySelect(inFrom, INT_MAX))
    for (int i = HistoryDealsTotal() - 1; i >= 0; i--)
    {
      const ulong Deal = HistoryDealGetTicket(i);
      const ulong Order = HistoryDealGetInteger(Deal, DEAL_ORDER);
      
      if ((HistoryOrderGetInteger(Order, ORDER_TICKET) == Order) &&
          (HistoryOrderGetInteger(Order, ORDER_TIME_SETUP_MSC) > HistoryDealGetInteger(Deal, DEAL_TIME_MSC)))
        Print((string)Order + " - " + (string)Deal);
    }
}

Так это выглядит в GUI.

[mktr8591]

fxsaber:

Иногда DEAL_TIME меньше DEAL_ORDER_TIME_SETUP. Наверное, это баг софта брокеров.

Так это выглядит в GUI.

Вероятно,  баг.

Но ведь такое возможно и штатно? Если после  частичного исполнения изменить лимитный ордер пользователем/программой, то ORDER_TIME_SETUP обновится.

[fxsaber]

mktr8591:

Но ведь такое возможно и штатно? Если после  частичного исполнения изменить лимитный ордер пользователем/программой, то ORDER_TIME_SETUP обновится.

Это поле - константа. Прописывается вместе с тикетом.

[mktr8591]

fxsaber:

Это поле - константа. Прописывается вместе с тикетом.

Видимо, я неправильно понял торговую ситуацию.

Как я представлял: отложенный лимитник исполнялся несколькими сделками. Все это время он висел в живых ордерах, и поле ORDER_TIME_SETUP   не было константой. После крайней сделки он попал в историю. В этот момент ORDER_TIME_SETUP стало константой.

Или было не так?