Проблема считывания массива с файла, кто с таким сталкивался???

[Удален] 2010.07.19 20:15 #11

Vinin:

Надо код смотреть.Так бесполезно.

Простите все, что так долго не отписывал

Ну вот простой пример моей проблемы:

Предположим мы используем вот этот индикатор для генерирования файла - это стандартный МА, с функциею записывания в файл.

//+------------------------------------------------------------------+
//|                                        Custom Moving Average.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net/"

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1 Red
//---- indicator parameters
extern int MA_Period=13;
extern int MA_Shift=0;
extern int MA_Method=0;
//---- indicator buffers
double ExtMapBuffer[];
//----
int ExtCountedBars=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   int    draw_begin;
   string short_name;
//---- drawing settings
   SetIndexStyle(0,DRAW_LINE);
   SetIndexShift(0,MA_Shift);
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS));
   if(MA_Period<2) MA_Period=13;
   draw_begin=MA_Period-1;
//---- indicator short name
   switch(MA_Method)
     {
      case 1 : short_name="EMA(";  draw_begin=0; break;
      case 2 : short_name="SMMA("; break;
      case 3 : short_name="LWMA("; break;
      default :
         MA_Method=0;
         short_name="SMA(";
     }
   IndicatorShortName(short_name+MA_Period+")");
   SetIndexDrawBegin(0,draw_begin);
//---- indicator buffers mapping
   SetIndexBuffer(0,ExtMapBuffer);
//---- initialization done
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int start()
  {
   if(Bars<=MA_Period) return(0);
   ExtCountedBars=IndicatorCounted();
//---- check for possible errors
   if (ExtCountedBars<0) return(-1);
//---- last counted bar will be recounted
   if (ExtCountedBars>0) ExtCountedBars--;
//----
   switch(MA_Method)
     {
      case 0 : sma();  break;
      case 1 : ema();  break;
      case 2 : smma(); break;
      case 3 : lwma();
     }
//---- done
//write file
   int h=FileOpen("test.bin",FILE_BIN|FILE_WRITE);
   FileWriteInteger(h,ArraySize(ExtMapBuffer),LONG_VALUE);
   FileWriteArray(h,ExtMapBuffer,0,ArraySize(ExtMapBuffer));
   FileClose(h);

   return(0);
  }
//+------------------------------------------------------------------+
//| Simple Moving Average                                            |
//+------------------------------------------------------------------+
void sma()
  {
   double sum=0;
   int    i,pos=Bars-ExtCountedBars-1;
//---- initial accumulation
   if(pos<MA_Period) pos=MA_Period;
   for(i=1;i<MA_Period;i++,pos--)
      sum+=Close[pos];
//---- main calculation loop
   while(pos>=0)
     {
      sum+=Close[pos];
      ExtMapBuffer[pos]=sum/MA_Period;
           sum-=Close[pos+MA_Period-1];
           pos--;
     }
//---- zero initial bars
   if(ExtCountedBars<1)
      for(i=1;i<MA_Period;i++) ExtMapBuffer[Bars-i]=0;
  }
//+------------------------------------------------------------------+
//| Exponential Moving Average                                       |
//+------------------------------------------------------------------+
void ema()
  {
   double pr=2.0/(MA_Period+1);
   int    pos=Bars-2;
   if(ExtCountedBars>2) pos=Bars-ExtCountedBars-1;
//---- main calculation loop
   while(pos>=0)
     {
      if(pos==Bars-2) ExtMapBuffer[pos+1]=Close[pos+1];
      ExtMapBuffer[pos]=Close[pos]*pr+ExtMapBuffer[pos+1]*(1-pr);
           pos--;
     }
  }
//+------------------------------------------------------------------+
//| Smoothed Moving Average                                          |
//+------------------------------------------------------------------+
void smma()
  {
   double sum=0;
   int    i,k,pos=Bars-ExtCountedBars+1;
//---- main calculation loop
   pos=Bars-MA_Period;
   if(pos>Bars-ExtCountedBars) pos=Bars-ExtCountedBars;
   while(pos>=0)
     {
      if(pos==Bars-MA_Period)
        {
         //---- initial accumulation
         for(i=0,k=pos;i<MA_Period;i++,k++)
           {
            sum+=Close[k];
            //---- zero initial bars
            ExtMapBuffer[k]=0;
           }
        }
      else sum=ExtMapBuffer[pos+1]*(MA_Period-1)+Close[pos];
      ExtMapBuffer[pos]=sum/MA_Period;
           pos--;
     }
  }
//+------------------------------------------------------------------+
//| Linear Weighted Moving Average                                   |
//+------------------------------------------------------------------+
void lwma()
  {
   double sum=0.0,lsum=0.0;
   double price;
   int    i,weight=0,pos=Bars-ExtCountedBars-1;
//---- initial accumulation
   if(pos<MA_Period) pos=MA_Period;
   for(i=1;i<=MA_Period;i++,pos--)
     {
      price=Close[pos];
      sum+=price*i;
      lsum+=price;
      weight+=i;
     }
//---- main calculation loop
   pos++;
   i=pos+MA_Period;
   while(pos>=0)
     {
      ExtMapBuffer[pos]=sum/weight;
      if(pos==0) break;
      pos--;
      i--;
      price=Close[pos];
      sum=sum-lsum+price*MA_Period;
      lsum-=Close[i];
      lsum+=price;
     }
//---- zero initial bars
   if(ExtCountedBars<1)
      for(i=1;i<MA_Period;i++) ExtMapBuffer[Bars-i]=0;
  }
//+------------------------------------------------------------------+

Как только мы бросаем на график этот индюк, он сразу создаёт файл.

Этот файл я должен отобразить вот этим индюком: - это стандартный МА с функцией по выводу данных с файла в массив.

//+------------------------------------------------------------------+
//|                                        Custom Moving Average.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net/"

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1 Red
//---- indicator parameters
extern int MA_Period=13;
extern int MA_Shift=0;
extern int MA_Method=0;
//---- indicator buffers
double ExtMapBuffer[];
//----
int ExtCountedBars=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   int    draw_begin;
   string short_name;
//---- drawing settings
   SetIndexStyle(0,DRAW_LINE);
   SetIndexShift(0,MA_Shift);
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS));
   if(MA_Period<2) MA_Period=13;
   draw_begin=MA_Period-1;
//---- indicator short name
   switch(MA_Method)
     {
      case 1 : short_name="EMA(";  draw_begin=0; break;
      case 2 : short_name="SMMA("; break;
      case 3 : short_name="LWMA("; break;
      default :
         MA_Method=0;
         short_name="SMA(";
     }
   IndicatorShortName(short_name+MA_Period+")");
   SetIndexDrawBegin(0,draw_begin);
//---- indicator buffers mapping
   SetIndexBuffer(0,ExtMapBuffer);
//---- initialization done
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int start()
  {
   if(Bars<=MA_Period) return(0);
   ExtCountedBars=IndicatorCounted();
//---- check for possible errors
   if (ExtCountedBars<0) return(-1);
//---- last counted bar will be recounted
   if (ExtCountedBars>0) ExtCountedBars--;
//----
    int  h=FileOpen("test.bin",FILE_BIN|FILE_READ);
    if (h<0)Alert("no file");
   int s=FileReadInteger(h,LONG_VALUE);
   ArrayResize(ExtMapBuffer,s);
   FileReadArray(h,ExtMapBuffer,0,s); //Alert(ExtMapBuffer[2]);
   FileClose(h);    

//---- done
//write file
/*
   int h=FileOpen("test.bin",FILE_BIN|FILE_WRITE);
   FileWriteInteger(h,ArraySize(ExtMapBuffer),LONG_VALUE);
   FileWriteArray(h,ExtMapBuffer,0,ArraySize(ExtMapBuffer));
   FileClose(h);
*/
   return(0);
  }

И если это делать в том же самом терминале где был создан сам файл то всё как бы прекрасно работает, и все буфера занимают свои значения,

ну а если изменить на другой терминал (даже просто переустановленною копию предыдущего терминала в другую папку), то все значения просто пропадают и на их место и становится 2147483647 или "ничто".

Вот и вся проблема в более "информативно"

С Уважением, спасибо ещё раз за помощь!

P.S. я использовал UWCT терминал

Любые вопросы новичков по Помогите с организацией кода Мультитаймфреймовые индикаторы

Yurixx 2010.07.19 21:05 #12

Каждый терминал установлен в своей директории. МТ4 по умолчанию открывает и пишет клиентские файлы только в папке C:\Program Files\папка терминала\experts\files\

Так что если вы этим способом передаете информацию из одного терминала в другой, то адрес файла нужно указывать со всем путем.

Любые вопросы новичков по Одновременная работа на нескольких Вопросы от "чайника"

[Удален] 2010.07.19 21:49 #13

Yurixx:

Каждый терминал установлен в своей директории. МТ4 по умолчанию открывает и пишет клиентские файлы только в папке C:\Program Files\папка терминала\experts\files\

Так что если вы этим способом передаете информацию из одного терминала в другой, то адрес файла нужно указывать со всем путем.

Нет я файл передаю в другой терминал просто, копирую из терминала где был создан файл C:\Program Files\папка терминала\experts\files\

в всавляю в папку /файлы другова терминала (тово где записанная инйормацыя должна быть отображена)

- тоесьть я копирую буфера чтобы работать с ними на растоянии от главного индикатора.

Можно ли поместить индикатор Имеет ли МТ4 архив После оптимизации тест на

[Удален] 2010.07.19 21:53 #14

JohnOne:

Простите все, что так долго не отписывал...

Ну вот сразу бы с кодом… :)

Ошибка закралась в индикатор считывающий данные из файла "test.bin". Ниже «проблемный кусок»

ArrayResize(ExtMapBuffer,s);
FileReadArray(h,ExtMapBuffer,0,s); //Alert(ExtMapBuffer[2]);

Нельзя индикаторный массив принудительно заставлять менять свои размеры с помощью функции ArrayResize(). На это способна лишь MQL-машина, соответственно при поступлении новых баров, она автоматически изменяет размер индикаторного массива, а когда вы самостоятельно хотите это сделать, то в журнале появляется вот это (к слову, не забываем в первую очередь смотреть именно туда, следить за ошибками среды исполнения, так как компилятор данный нюанс прошляпил):

Это результат ошибки 4053 - ERR_SOME_ARRAY_ERROR - Ошибка массива.

Так что дело вовсе не в различных терминалах, если вы посмотрите в журналы терминалов в которых «вроде все в порядке», то увидите туже печальную ошибку. А первичное построение мувинга из файла в «родном» терминале происходит от того что количество истории (ровно как и баров, а также естественно размеров индикаторных массивов) совпадают, поэтому первая стадия конфликта первоначально проходит не замеченной, но как я уже сказал – журнал без пристрастен, и баг в нем лезет во всех терминалах.

Ну а теперь немного о решении это проблемы. Мне ничего лучше в голову не пришло, как создать обыкновенный массив который соответственно можно растягивать как захочется, и использовать его как буфер, между файлом и индикаторным массивом. Итак создаем простой массив буфер:

double tmp[];

Первоначально записываем данные в него, естественно меняем его размеры как хотим, так как уже можно (массив то обыкновенный, а не индикаторный):

int s=FileReadInteger(h,LONG_VALUE);

ArrayResize(tmp,s);   
FileReadArray(h,tmp,0,s); //Alert(ExtMapBuffer[2]);   
FileClose(h);

Далее нюанс, простые массивы организованны не так как индикаторные (где нулевой индекс последний, а не первый как у обычных).

Поэтому перед тем как "слить" оба массива приводим обычный массив (tmp) в соответствие с индикаторным, для того чтобы не перепутать элементы и правильно построить МА:

ArraySetAsSeries(tmp, true);

Ну а далее просто копируем данные из массива-буфера в индикаторный массив:

ArrayCopy(ExtMapBuffer, tmp, 0, 0, Bars);

Так как МА будет строить естественно индикаторный массив, то его размер для нас важнее, и мы будем равняется на него (размер индикаторного массива равен количеству баров = Bars)

Исправленный вариант прилагаю.

Файлы:

ma_from_file.mq4 3 kb

Вопросы от начинающих MQL5 Как увеличить размер массива[] MT5. ТЕСТЕР СТРАТЕГИЙ. Расхождение

[Удален] 2010.07.20 06:58 #15

ToLik_SRGV:

Ну вот сразу бы с кодом… :)

.........................................................

Ошибка закралась в индикатор считывающий данные из файла "test.bin". Ниже «проблемный кусок»

Исправленный вариант прилагаю.

Огромнейшие СПАСИБО! ;) Всё работает!

Проблема считывания массива с файла, кто с таким сталкивался??? - страница 2