Especialistas: Programação no MQL5 para traders: códigos-fonte retirados do livro. Parte 6 - página 3

[Alain Verleyen]

hini #property tester_set "FrameTransfer.set" (extensão de arquivo de conjunto de teste inválida, '*.set' esperado FrameTransfer.mq5)

Ele deve ser alterado desta forma para que a compilação seja bem-sucedida: #property tester_set "\\Presets\\FrameTransfer.set"

Até mesmo `#property tester_set "/Presets/FrameTransfer.set"` falhará.

Talvez você possa modificar a descrição no livro de algoritmos:

Correção disponível no build 5506.

[hini]

Alain Verleyen #:
Correção disponível no build 5506.

Obrigado.

[Stanislav Korotky]

Stanislav Korotky otimização personalizado baseado em R2 - RSquared.mqh, no qual o cálculo para o caso de lotes variáveis foi corrigido.

A qualidade da estimativa foi significativamente aprimorada - a julgar pela tabela de resultados de otimização, foi obtida uma combinação de fator de recuperação e parâmetros Sharpe.

Exemplo de uso.

Atenção! Se forem negociados símbolos diferentes, para obter uma estimativa adequada dos volumes, eles deverão ser convertidos de lotes para o valor na moeda de depósito, por exemplo (uma das variantes simplificadas):

#include <MQL5Book/DealFilter.mqh>
#include <MQL5Book/RSquared.mqh>

template<typename T>
union Type2Bytes
{
   T d;
   uchar bytes[sizeof(T)];
};

double OnTester()
{
   HistorySelect(0, LONG_MAX);
   
   #define   STAT_PROPS 5
   
   const ENUM_DEAL_PROPERTY_DOUBLE props[STAT_PROPS] =
   {
      DEAL_PROFIT, DEAL_SWAP, DEAL_COMMISSION, DEAL_FEE, DEAL_VOLUME
   };
   double expenses[][STAT_PROPS];
   ulong tickets[]; // usado aqui apenas para corresponder ao protótipo 'select', mas útil para depuração
   
   DealFilter filter;
   filter.let(DEAL_TYPE, (1 << DEAL_TYPE_BUY) | (1 << DEAL_TYPE_SELL), IS::OR_BITWISE)
      .let(DEAL_ENTRY, (1 << DEAL_ENTRY_OUT) | (1 << DEAL_ENTRY_INOUT) | (1 << DEAL_ENTRY_OUT_BY), IS::OR_BITWISE)
      .select(props, tickets, expenses);

   const int n = ArraySize(tickets);
   
   double balance[];
   double volumes[]; // levar em conta os volumes de comércio para usar o critério R2
   
   ArrayResize(balance, n + 1);
   balance[0] = 0;
   ArrayResize(volumes, n + 1);
   volumes[0] = 0;

   MapArray<ulong,double> sym2value; // hash de símbolo para valor de 1 lote
   
   for(int i = 0; i < n; ++i)
   {
      const string s = HistoryDealGetString(tickets[i], DEAL_SYMBOL);

      double value = 1;
      Type2Bytes<ulong> sym;
      ArrayInitialize(sym.bytes, 0);
      StringToCharArray(s, sym.bytes);
      int idx = sym2value.find(sym.d);
      if(idx == -1) // ainda não há registro do valor do símbolo por lote
      {
         const double price = SymbolInfoDouble(s, SYMBOL_ASK);
         const double pt = SymbolInfoDouble(s, SYMBOL_POINT);
         double profit = 1;
         ResetLastError();
         if(!OrderCalcProfit(ORDER_TYPE_BUY, s, 1, price, price + pt, profit)) // NB: estimado aproximadamente, pois usa a taxa atual para a moeda da conta
         {
            // WARN(StringFormat("OrderCalcProfit Error: %s %d ", s, _LastError));
         }
         value = profit * (price / pt); // NB: a alavancagem não é aplicada aqui
         idx = sym2value.put(sym.d, value);
      }
      else
      {
         value = sym2value.getValue(idx);
      }
   
      double result = 0;
      for(int j = 0; j < STAT_PROPS - 1; ++j) // loop por todas as props solicitadas, exceto pelo volume do negócio
      {
         result += expenses[i][j];
      }
      // usar volumes como modelo - mais investimentos - mais retornos esperados
      volumes[i + 1] = expenses[i][STAT_PROPS - 1] * value + volumes[i];
      balance[i + 1] = result + balance[i];
   }
   
   const double r2 = RSquaredTest(balance, volumes);
   
   #undef   STAT_PROPS
   
   return r2 * 100;
}

Em amarelo está marcado o que teve de ser adicionado em comparação com o cálculo da negociação de um símbolo (do exemplo anterior).

[Stanislav Korotky]

Stanislav Korotky #:

Correção de bug MQL5/Include/MQL5Book/TradeUtils.mqh.

Outra correção de erro relacionada (no método NormalizeLot ):

const double newLotsRounded = MathFloor(nlot * (1 + DBL_EPSILON) / stepLot) * stepLot;