baxromsaid 2020.03.11 11:55 #11941

Estou num andróide.

Vladimir Karputov 2020.03.11 12:09 #11942

baxromsaid:
Eu não sei como abrir uma conta de demonstração.

baxromsaid:
Estou em andróide.

MetaQuotes não é um corretor - portanto só pode abrir uma conta demo nos servidores MetaQuotes-Demo.

Uma conta comercial real deve ser aberta com um corretor.

odyn 2020.03.14 10:24 #11943

Olá conhecedores!

Pode dizer-me, por favor, porque é que o meu código não se define vol e perguntar? O valor zero é sempre exibido em Imprimir. A dispersão é "fixação" normalmente, mostra o valor correcto.

Anexo a EA ao gráfico LTCUSD.

O que é o erro?

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
int a=0,b=0,c=0,spread=0,i=0,j=0;
double x=0,y=0,z=0,m=0,ask=0;
input int vyb=7;
bool bool_1=true,bool_2=true,bool_3=true;
string str_1="",str_2="",str_3="",name="",Text[101];
ulong vol=0;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
  name=_Symbol;
  Print("текущий символ: ",name); 
  spread=m_symbol.Spread();
  Print("спред по символу: ",spread);
  vol=m_symbol.Volume();
  Print("обьєм по символу ",name," - ",vol);
  ask=m_symbol.Ask();
  Print("Цена Аск равно ",ask);

Qualquer pergunta de novato, [AVISO FECHADO!] Qualquer pergunta Perguntas de um "boneco"

Vladimir Karputov 2020.03.14 10:48 #11944

odyn:

Olá conhecedores!

Pode dizer-me, por favor, porque é que o meu código não se define vol e perguntar? O valor zero é sempre exibido em Imprimir. A dispersão é "fixação" normalmente, mostra o valor correcto.

Anexo a EA ao gráfico LTCUSD.

O que é o erro?

Deve aplicar ou CSymbolInfo::Refresh ou CSymbolInfo::RefreshRates método antes de o obter - dependendo do que necessita.

Aqui está o código destas funções:

//+------------------------------------------------------------------+
//| Refresh cached data                                              |
//+------------------------------------------------------------------+
bool CSymbolInfo::Refresh(void)
  {
   long tmp=0;
//---
   if(!SymbolInfoDouble(m_name,SYMBOL_POINT,m_point))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE,m_tick_value))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE_PROFIT,m_tick_value_profit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE_LOSS,m_tick_value_loss))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_SIZE,m_tick_size))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_CONTRACT_SIZE,m_contract_size))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_MIN,m_lots_min))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_MAX,m_lots_max))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_STEP,m_lots_step))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_LIMIT,m_lots_limit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_SWAP_LONG,m_swap_long))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_SWAP_SHORT,m_swap_short))
      return(false);
   if(!SymbolInfoInteger(m_name,SYMBOL_DIGITS,tmp))
      return(false);
   m_digits=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_ORDER_MODE,tmp))
      return(false);
   m_order_mode=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_EXEMODE,tmp))
      return(false);
   m_trade_execution=(ENUM_SYMBOL_TRADE_EXECUTION)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_CALC_MODE,tmp))
      return(false);
   m_trade_calcmode=(ENUM_SYMBOL_CALC_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_MODE,tmp))
      return(false);
   m_trade_mode=(ENUM_SYMBOL_TRADE_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_SWAP_MODE,tmp))
      return(false);
   m_swap_mode=(ENUM_SYMBOL_SWAP_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_SWAP_ROLLOVER3DAYS,tmp))
      return(false);
   m_swap3=(ENUM_DAY_OF_WEEK)tmp;
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_INITIAL,m_margin_initial))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_MAINTENANCE,m_margin_maintenance))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_LONG,m_margin_long))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_SHORT,m_margin_short))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_LIMIT,m_margin_limit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_STOP,m_margin_stop))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_STOPLIMIT,m_margin_stoplimit))
      return(false);
   if(!SymbolInfoInteger(m_name,SYMBOL_EXPIRATION_MODE,tmp))
      return(false);
   m_trade_time_flags=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_FILLING_MODE,tmp))
      return(false);
   m_trade_fill_flags=(int)tmp;
//--- succeed
   return(true);
  }
//+------------------------------------------------------------------+
//| Refresh cached data                                              |
//+------------------------------------------------------------------+
bool CSymbolInfo::RefreshRates(void)
  {
   return(SymbolInfoTick(m_name,m_tick));
  }

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Refresh

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Refresh - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

odyn 2020.03.14 11:03 #11945

Vladimir Karputov:

Deve aplicar ou CSymbolInfo::Refresh ou CSymbolInfo::RefreshRates método antes de obter - dependendo do que necessita

Muito obrigado, caro Vladimir!

Talvez também me possa dizer como obter o nome do símbolo com o métodoCSymbolInfo Name ? Quando o tento fazer

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
int a=0,b=0,c=0,spread=0,i=0,j=0;
double x=0,y=0,z=0,m=0,ask=0;
input int vyb=7;
bool bool_1=true,bool_2=true,bool_3=true;
string str_1="",str_2="",str_3="",name="",Text[101];
ulong vol=0;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
  name=m_symbol.Name(Symbol())
  Print("текущий символ: ",name);

Recebo um valor booleano verdadeiro na variável do nome.

Vladimir Karputov 2020.03.14 13:38 #11946

odyn:

Muito obrigado, caro Vladimir!

Talvez também possa sugerir: como obter um nome simbólico usando o métodoCSymbolInfo Name ? Quando tento fazê-lo desta forma

Recebo um valor booleano verdadeiro na variável do nome.

Faço-o - inicializo a variável da classe CSymbolInfo.

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
***
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
   RefreshRates();
***
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      if(InpPrintLog)
         Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      if(InpPrintLog)
         Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }

Se quiser obter um nome (por exemplo, ao comparar o símbolo de posição com o símbolo actual), precisa de utilizar o método CSymbolInfo::Name().

Exemplo de utilização:

//+------------------------------------------------------------------+
//| Is position exists                                               |
//+------------------------------------------------------------------+
bool IsPositionExists(void)
  {
   for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            return(true);
//---
   return(false);
  }

A ajuda mostra duas formas de chamar o método Nome

Nome

Obtém o nome do instrumento financeiro.

string  Name() const

Valor devolvido

Nome do instrumento financeiro.

Nome

Define o nome do instrumento financeiro para continuar a trabalhar com ele.

bool  Name(string name)

Valor devolvido

Não.

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Name

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Name - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

odyn 2020.03.14 14:16 #11947

Vladimir Karputov:

Se quiser obter um nome (por exemplo, ao comparar um símbolo de posição com o símbolo actual), precisa de utilizar o método CSymbolInfo::Name().

Exemplo de utilização:

A ajuda mostra duas formas de chamar o método Nome

Nome

Obtém o nome do instrumento financeiro.

Valor devolvido

Nome do instrumento financeiro.

Tenho uma pergunta sobre esta forma de método Nome.

COMO é que recebo o NOME do instrumento na variável? Porque fazendo-o desta forma:

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
string str_1="",str_2="",str_3="",name="";
name=m_symbol.Name();
Print("текущий символ: ",name);

Como obter uma corda com o nome do instrumento, usandoo método CSymbolInfo::Name() ?

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Name

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Name - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

Vladimir Karputov 2020.03.14 14:23 #11948

odyn:

Tenho uma pergunta sobre esta forma particular do método do Nome.

COMO é que eu obtenho o NOME da ferramenta numa variável? Porque fazer isto:

Como obtenho uma cadeia com nome de ferramenta, usando ométodo CSymbolInfo::Name() ?

Primeiro INICIALIZAMo-lo. Depois usamos o método Name().

Executamos o código no carácter '''.

//+------------------------------------------------------------------+
//|                                                            1.mq5 |
//|                              Copyright © 2020, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property version   "1.00"
#include <Trade\SymbolInfo.mqh>
//---
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return;
     }
   string name=m_symbol.Name();
   Print("текущий символ: ",name);
//---
  }
//+------------------------------------------------------------------+

Resultado:

1 (EURUSD,H1)   текущий символ: EURUSD

odyn 2020.03.14 14:45 #11949

Vladimir Karputov:

Primeiro INICIALIZAMOS. Depois utilizamos o método Name().

Executar o código no carácter '''.

Resultado:

Já está. Obrigado pela vossa paciência )).

PS: o meu compilador está a culpar o retorno no seu código. Quando o removi, não há problema.

Vladimir Karputov 2020.03.14 14:49 #11950

odyn:

Já está. Obrigado pela vossa paciência )).

PS: o meu compilador está a culpar o retorno no seu código. Quando o removi, não há problema.

Isto é um guião (dei um exemplo de um guião), não uma EA. Se copiou o meu código para a EA, haverá um erro.

Perguntas de Iniciantes MQL5 MT5 MetaTrader 5 - página 1195

Nome

Nome

Nome