Bibliotecas: HistoryLoader

Novo comentário
 

HistoryLoader:

Expert Advisor Multi-moedas com módulo funcional para a organização de um acesso a todos os dados históricos com um resultado de processamento de pedido.

Autor: Nikolay Kositsin

 
Automated-Trading:

HistoryLoader:

Autor: Nikolay Kositsin

Erro de sintaxe na linha 91 (H ausente)."SERIES_SYNCRONIZED" deveria ser "SERIES_SYNCHRONIZED".
 
elib:
Erro de sintaxe na linha 91 (H ausente)."SERIES_SYNCRONIZED" deveria ser "SERIES_SYNCHRONIZED".

Nada dura para sempre sob a lua!

//+------------------------------------------------------------------+
//| verificação do histórico para upload|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- verificar símbolo e ponto final
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- verificar se o símbolo está selecionado no MarketWatch
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Falha ao adicionar o caractere ",symbol," na janela do MarketWatch!!!");
     }
//--- verificar se os dados estão presentes
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- não solicite o carregamento de seus próprios dados se for um indicador
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- segunda tentativa
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- há dados carregados para criar séries temporais
      if(first_date>0)
        {
         //--- forçar a construção de séries temporais
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- data de verificação
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- máximo de barras no gráfico a partir das opções do terminal
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- carregar informações do histórico de símbolos
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- fixar data de início para carregamento
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- carregar dados passo a passo
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- esperar pela construção da série temporal
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- pedir barras construídas
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- pedir o primeiro encontro
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- a cópia da próxima parte força o carregamento de dados
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- verificar se há dados
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- não mais do que 100 tentativas fracassadas
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+
 

Não funciona, ele morre no primeiro caractere....

Aqui está o código

//+------------------------------------------------------------------+ 
//|TestLoadHistory.mq5 
//| Copyright 2009, MetaQuotes Software Corp. 
//| https://www.mql5.com 
//+------------------------------------------------------------------+ 
#property copyright "2009, MetaQuotes Software Corp." 
#property link      "https://www.mql5.com" 
#property version   "1.02" 
#property script_show_inputs 

//--- parâmetros de entrada 

//+------------------------------------------------------------------+ 
//| Função de início do programa de script| 
//+------------------------------------------------------------------+ 
void OnStart()
  {


   int      all_symbols=SymbolsTotal(false);   string  sym_name="";
   Print("Load symbols ",all_symbols);

   for(int k=0;k<all_symbols;k++)
      if((sym_name=SymbolName(k,false))!="")
        {
         SymbolSelect(sym_name,true);

         Print(k," Symbol name ",sym_name);

datetime time= (TimeCurrent()-60*60*24*5);


         int res=CheckLoadHistory(sym_name,PERIOD_M1,time);

         switch(res)
           {
            case -1 : Print("Unknown symbol ",sym_name);             break;
            case -2 : Print("Requested bars more than max bars in chart ",sym_name); break;
            case -3 : Print("Program was stopped ",sym_name);                        break;
            case -4 : Print("Indicator shouldn't load its own data ",sym_name);      break;
            case -5 : Print("Load failed ",sym_name);                                break;
            case  0 : Print("Loaded OK ",sym_name);                                  break;
            case  1 : Print("Loaded previously ",sym_name);                          break;
            case  2 : Print("Loaded previously and built ",sym_name);                break;
            default : Print("Unknown result ",sym_name);
           }

         datetime first_date;
         SeriesInfoInteger(sym_name,PERIOD_M1,SERIES_FIRSTDATE,first_date);
         int bars=Bars(sym_name,PERIOD_M1);
         Print("First date ",first_date," - ",bars," bars");
       }
//--- 

//--- 
  }
//+------------------------------------------------------------------+
//| verificação do histórico para upload|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- verificar símbolo e ponto final
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- verificar se o símbolo está selecionado no MarketWatch
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Falha ao adicionar o caractere ",symbol," na janela do MarketWatch!!!");
     }
//--- verificar se os dados estão presentes
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- não solicite o carregamento de seus próprios dados se for um indicador
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- segunda tentativa
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- há dados carregados para criar séries temporais
      if(first_date>0)
        {
         //--- forçar a construção de séries temporais
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- data de verificação
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- máximo de barras no gráfico a partir das opções do terminal
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- carregar informações do histórico de símbolos
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- fixar data de início para carregamento
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- carregar dados passo a passo
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- esperar pela construção da série temporal
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- pedir barras construídas
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- pedir o primeiro encontro
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- a cópia da próxima parte força o carregamento de dados
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- verificar se há dados
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- não mais do que 100 tentativas fracassadas
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+

e ele morre aqui

while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
 

Oi Nikolay

O Historyloader.mqh tem apenas uma função de

int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)

ele não tem a função Loadhistory(), conforme mencionado.
 
Nikolay Kositsin:

Nada dura para sempre sob a lua!

Muito obrigado, está funcionando para mim!

Novo comentário