Bibliotecas: Expert - página 2

[Алексей Тарабанов]

fxsaber:

Ah, esses hackers russos.... Bem, por que interromper todos os especialistas quando você está um pouco confuso?

A propósito, você também tem um bug. A estática não funciona.

[fxsaber]

Алексей Тарабанов:

A propósito, você também tem um bug. A estática não funciona.

Não vi nenhum erro aqui

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação.

Perguntas de iniciantes MQL5 MT5 MetaTrader 5

fxsaber, 2018.08.02 17:09

// Interrompe todos os Expert Advisors se o SL for acionado.

#include <MT4Orders.mqh>      // https://www.mql5.com/pt/code/16006
#include <fxsaber\Expert.mqh> // https://www.mql5.com/pt/code/19003

void OnTrade()
{
  static int PrevTotal = OrdersHistoryTotal();
  const int Total = OrdersHistoryTotal();
  
  for (int i = Total - 1; i >= PrevTotal; i--)
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY) && (OrderCloseReason() == DEAL_REASON_SL))
    {
      long Chart = ChartFirst();
  
      while (Chart != -1)
      {
        if ((Chart != ChartID()) && EXPERT::Is(Chart))
          EXPERT::Remove(Chart);
  
        Chart = ChartNext(Chart);
      }

      break;
    }        
    
  PrevTotal = Total;
}

[fxsaber]

// O indicador interrompe todas as tentativas de negociação por meio de Expert Advisors. Ele só permite a negociação com as mãos.
// Para evitar a tentação de desligá-lo enquanto o Terminal está em execução, o indicador está no modo invisível.

#property indicator_chart_window
#property indicator_buffers 0
#property indicator_plots   0

#include <Symbol.mqh>         // https://www.mql5.com/pt/code/18855
#include <fxsaber\Expert.mqh> // https://www.mql5.com/pt/code/19003

void MyAlert( const string Str )
{
  string StrArray[];
  
  for (int i = StringSplit(Str, '\n', StrArray) - 1; i >= 0; i--)
    Alert(StrArray[i]);
}

bool NextOnCalculate( const string SymbName = NULL )
{
  const SYMBOL Symb(SymbName);
  
  MqlRates Rates[1] = {0};
  Rates[0].time = TimeCurrent();
          
  return(Symb.IsCustom() ? Symb.CloneRates(Rates) : ChartSetSymbolPeriod(0, _Symbol, _Period));
}

const SYMBOL SymbTimer("Timer");

void OnInit()
{
  if (_Symbol == SymbTimer.Name)
    ChartIndicatorGet(0, 0, ChartIndicatorName(0, 0, 0));    
  else if (SymbTimer.IsExist() && SymbTimer.On() && NextOnCalculate(SymbTimer.Name))
  {
    iCustom(SymbTimer.Name, PERIOD_CURRENT,
            ".." + StringSubstr(MQLInfoString(MQL_PROGRAM_PATH), StringLen(TerminalInfoString(TERMINAL_PATH)) + 5));
    
    SymbTimer.Off(); 
  }
}

string GetExpertData( const ulong Chart = 0 )
{
  string Str = NULL;

  MqlParam Parameters[];
  string Names[];

  if (EXPERT::Parameters(Chart, Parameters, Names))
  {
    Str += "\n" + ::ChartSymbol(Chart) + " " + ::EnumToString(::ChartPeriod(Chart)) + " " + Parameters[0].string_value + "\n";

    const int Amount = ::ArraySize(Names);

    for (int i = 0; i < Amount; i++)
      Str += (string)i + ": "+ Names[i] + " = " + Parameters[i + 1].string_value + "\n";
  }

  return(Str);
}

void Active( const int AlertTime = 5 )
{
  static const uint StartTime = GetTickCount();
  static uint PrevInterval = 0;
  const uint Interval = (GetTickCount() - StartTime) / 1000;
  const string Str = MQLInfoString(MQL_PROGRAM_NAME) + ": I've been watching you for " + TimeToString(Interval, TIME_SECONDS);
    
  long Chart = ChartFirst();

  if (Chart != -1)  
    do
    {
      if (EXPERT::Is(Chart))
        MyAlert(GetExpertData(Chart) + "Removed - " + (string)EXPERT::Remove(Chart));
        
      ChartSetString(Chart, CHART_COMMENT,  Str);
      ChartRedraw(Chart);
    }
    while ((Chart = ChartNext(Chart)) != -1);    
  else if (!(Interval % AlertTime) && (Interval != PrevInterval))
  {
    MyAlert(Str);
    
    PrevInterval = Interval;
  }
}

int OnCalculate( const int, const int, const int, const double &[] )
{
  static int i = 0;
  
  if ((_Symbol == SymbTimer.Name) && NextOnCalculate())
    Active();
  else if (i++ > 0)
    ChartIndicatorDelete(0, 0, ChartIndicatorName(0, 0, ChartIndicatorsTotal(0, 0) - 1));           
    
  return(0);
}

ZY Se você reiniciar o terminal, às vezes poderá se deparar (MT5 build 1881) com o fato de ele travar nos processos. Isso pode ser superado removendo à força o processo correspondente terminal64.exe e excluindo o MetaTrader 5\Bases\Custom\history\Timer\*.hcc.

[Алексей Тарабанов]

Obrigado a você. Muito bom!

[fxsaber]

No artigo, o autor destacou em grande detalhe as nuances dos resultados dessa biblioteca. Recomendo a leitura do artigo.

[Sergey Eremin]

Andrey Khatimlianskii:

Acontece que o MT4 está faltando muito mais do que FileSave e FileLoad (que são escritos em 3 linhas cada):

1. Não há CHART_EXPERT_NAME (e não há nada para substituí-lo, exceto depois de corrigir todas as outras nuances - a tag name).

Em meu projeto, resolvi o problema dessa forma (com a tag "name"):

      void Update()
      {                
         long chartId = ChartFirst();
         
         while(chartId > 0)
         {
            #ifdef __MQL4__
            string chartEAName = GetChartEAName(chartId);
            #endif 
            
            #ifdef __MQL5__     
            string chartEAName = ChartGetString(chartId, CHART_EXPERT_NAME);
            #endif
            
            if(chartEAName == m_eaName)
            {
               // ...
            }
            
            chartId = ChartNext(chartId);
         }
      }
      
      #ifdef __MQL4__
      string GetChartEAName(const long chartId)
      {
         if(!SaveTemplate(chartId))
         {
            return "";
         }
         
         string result = "";
         
         int handle = FileOpen("ea_name_checking.tpl",FILE_TXT|FILE_READ);
         if(handle == INVALID_HANDLE)
         {
            Print
            (
               "Error in ", __FILE__,", line ", __LINE__,
               ": can't open template file 'ea_name_checking.tpl', error code = ", GetLastError()
            );
         }
         else
         {
            string text = "";
            
            while(!FileIsEnding(handle)) 
            { 
               text = text + FileReadString(handle, (uint)FileSize(handle)) +"\r\n";
            }
            
            SubstringParser eaSectionTextParser(text, "<expert>", "</expert>");            
            string eaSectionText = eaSectionTextParser.Get();
            
            if(StringTrimLeft(StringTrimRight(eaSectionText)) != "")
            {
               SubstringParser eaNameParser(eaSectionText, "name=","\r\n");
               string eaName = StringTrimLeft(StringTrimRight(eaNameParser.Get()));
               
               if(eaName != "")               
               {
                  result = eaName;
               }
            }            
         }
         
         FileClose(handle);
         FileDelete("ea_name_checking.tpl");
         
         return result;
      }
      
      bool SaveTemplate(const long chartId)
      {
         ResetLastError();
         
         if(!ChartSaveTemplate(chartId, "\\Files\\ea_name_checking.tpl"))
         {            
            Print
            (
               "Error in ", __FILE__,", line ", __LINE__,
               ": can't save template to the file 'ea_name_checking.tpl', error code = ", GetLastError()
            );
            
            return false;
         }
         
         return true;
      }      
      #endif

Onde o SubstringParser tem esse código:

#property strict

class SubstringParser
{
   private:
      string m_text;
      string m_subStart;
      string m_subEnd;
   
   public:
      SubstringParser(const string text, const string subStart, const string subEnd)
      {
         m_text = text;
         m_subStart = subStart;
         m_subEnd = subEnd;
      }
      
      string Get()
      {
         int startPhraseLengt = StringLen(m_subStart);
         int startPos = StringFind(m_text, m_subStart) + startPhraseLengt;
         int endPos = StringFind(m_text, m_subEnd, startPos);
                 
         if(startPos >= startPhraseLengt && endPos > startPos)
         {
            return StringSubstr(m_text, startPos, endPos - startPos);      
         }
         else
         {
            return "";
         }
      }
};

Ou seja, salva o modelo de gráfico, lê-o, analisa-o e encontra o nome do Expert Advisor. Ainda é uma muleta, mas funciona bem até agora (por cerca de dois meses). Acho que, se você usar um HDD comum, não deve fazer isso com muita frequência (por exemplo, a cada tick). Espero que o CHART_EXPERT_NAME apareça na MQL4 algum dia .

[Stanislav Korotky]

Haverá uma nova versão com suporte para a execução de scripts?

[fxsaber]

Stanislav Korotky:
Haverá uma nova versão com suporte para a execução de scripts?

Esse exemplo não funciona?

[Stanislav Korotky]

fxsaber:

Esse exemplo não funciona?

Ele não é muito semelhante ao meu caso de uso. A principal pergunta sobre o exemplo é o que acontece se o nome do arquivo de música for especificado em um parâmetro de script, em vez de lançá-lo por meio de variáveis globais? Posso lhe enviar meu projeto em uma mensagem privada.

[fxsaber]

Stanislav Korotky:

Não é muito semelhante ao meu caso de uso. A principal pergunta sobre o exemplo é o que acontece se o nome do arquivo de música for especificado em um parâmetro de script em vez de ser lançado por meio de variáveis globais?

Não me lembro o motivo, mas a opção com um parâmetro de entrada é imediatamente sugerida. Como o exemplo é tão distorcido, deve ser uma limitação do MT5.