하나의 차트에 여러개의 지표 넣기(파트 06): MetaTrader 5를 RAD 시스템으로 전환하기(II)

소개

이전 기사에서 저는 MetaTrader 5 객체를 사용하여 차트 거래를 생성하고 플랫폼을 RAD 시스템으로 전환하는 방법을 보여주었습니다. 시스템은 매우 잘 작동하며 많은 독자분들은 제가 제안한 시스템에서 여러가지 확장된 기능들을 할 수 있는 라이브러리를 만드는 것에 대해 생각해 봤을 것입니다. 그렇게 하면 보다 멋지고 사용하기 쉬운 인터페이스로를 지닌 직관적인 Expert Advisor를 개발할 수 있을 것입니다.

저는 이런 아이디어가 너무 좋아서 기능을 추가하는 방법을 단계별로 보여 드려야겠다고 생각하게 되었습니다. 여기서는 저는 두 가지의 새로운 주요 기능을 구현할 것입니다(여기서 드리는 정보는 여러분이 필요로 하거나 원하는 방식으로 또 다른 기능을 구현하기 위한 기초의 역할을 하게 될 것입니다). 이들 기능을 가능하게 하는 요소들은 다양한 방식으로 사용될 수 있습니다. 우리의 창의성이 발휘된다면 가능성은 무한합니다.

계획

IDE에서 변경된 사항은 다음의 이미지에서 확인할 수 있습니다:

         

보시다시피 디자인에 약간의 변경이 있습니다. 두 개의 새로운 영역이 추가되었습니다: 하나는 자산의 이름을 수신하는 것이고 다른 하나는 당일의 누적 가치를 수신하는 것입니다. 이것들이 없어도 우리의 결정에 별다른 영향을 미치지 않을 것입니다. 그러나 그들은 어쨌든 흥미로운 것들입니다. IDE에 기능을 추가하는 가장 간단하고 올바른 방법을 보여 드리겠습니다. 새로운 인터페이스에서 객체 목록을 엽니다. 다음과 같이 나타날 것입니다:

두 개의 에워싸인 객체에는 연결된 이벤트가 없습니다. 즉, IDE에서 작동하지 않습니다. 다른 모든 객체는 이미 특정 이벤트와 올바르게 연결되어 있으며 MetaTrader 5는 EA에서 이러한 이벤트가 발생할 때 올바르게 실행되도록 할 수 있습니다. 즉, IDE 인터페이스를 원하는 대로 수정할 수 있지만 기능이 아직 구현되지 않은 경우에는 MetaTrader 5는 차트에 객체를 표시하는 것 외에는 아무런 작업도 수행하지 않습니다. 거래 중인 자산의 이름을 수신하려면 EDIT 00 객체가 필요하며 이 이름은 객체의 중앙에 나타나야 합니다. EDIT 01 객체는 일정 기간 동안의 누적된 값을 받습니다. 우리는 하루 동안 이익을 얻었는지 손실을 입었는지 알기 위해 기간을 일일로 하여 사용할 것입니다. 값이 음수이면 한 색상으로 표시되고 양수이면 다른 색상으로 표시됩니다.

두 값을 사용자가 변경할 수 없게 할 것이므로 아래 그림과 같이 해당 속성을 읽기 전용으로 합니다.

그러나 정보가 표시되는 방식을 지정하는 것은 불가능합니다. 즉 텍스트가 객체의 중앙에 위치하도록 텍스트를 정렬할 수 없습니다. 만약 이를 원할 경우 텍스트를 가운데로 설정하는 속성을 사용하여 수행할 수 있습니다. 자세한 내용은 "객체 속성"을 참조하십시오. 테이블의 ENUM_ALIGN_MODE에 유의하십시오. 테이블에는 양쪽 정렬된 텍스트를 사용할 수 있는 객체가 포함되어 있습니다.

따라서 어떠한 수정을 하려는 것이든 가장 먼저 해야 할 일은 계획을 세우는 것입니다: 새로운 기능과 기능들의 형식과 사용자가 이들과 상호 작용하는 방식을 정의해야 합니다. 이렇게 하면 MetaTrader 5 인터페이스 자체를 사용하여 올바른 객체를 선택하고 구성할 수 있습니다. 그 결과로 우리는 준비된 IDE를 갖게 되며 MQL5 코드를 통해서 약간의 조정을 하기만 하면 IDE가 100% 기능하게 됩니다. 그럼 수정을 진행해 보겠습니다.

수정

코드가 엉망이 되는 것을 방지하려면 어떤 기능이 이미 존재하는지와 실제로 구현해야 하는 기능이 무엇인지를 최대한 정리해야 합니다. 대부분의 경우 기존의 코드를 약간 변경하고 새 코드를 가져와 테스트하는 것으로 충분할 수 있습니다. 이 새 코드는 우리가 구현하려고 하는 코드에서 재사용되며 우리가 테스트 해야 할 유일한 부분은 작은 함수들로 이들 함수들은 완전히 새로운 기능들이 작동하도록 하기 위해 추가될 것들입니다. 좋은 프로그래머는 항상 이렇게 합니다: 기존의 코드에 제어가 가능한 특정 부분을 추가하여 어떤 식으로든 기존의 코드를 재사용하려고 합니다.

수정 1. 자산명 추가

이 부분을 구현하기 위해 많은 변경이 필요하지는 않지만 이러한 변경은 올바른 위치에 구현되어야 합니다. 먼저 열거형에 새 값을 추가해 보겠습니다. 소스 코드는 아래와 같습니다:

enum eObjectsIDE {eRESULT, eBTN_BUY, eBTN_SELL, eCHECK_DAYTRADE, eBTN_CANCEL, eEDIT_LEVERAGE, eEDIT_TAKE, eEDIT_STOP};

아래는 새 코드입니다; 강조 표시된 부분이 추가된 것입니다. 열거형의 시작이나 끝에 새 값을 추가하지 않는다는 점을 주의하십시오. 왜냐하면 이미 존재하고 잘 작동하는 다른 코드 부분을 엉망으로 만드는 것을 피하기 위해서 입니다.

enum eObjectsIDE {eRESULT, eLABEL_SYMBOL, eBTN_BUY, eBTN_SELL, eCHECK_DAYTRADE, eBTN_CANCEL, eEDIT_LEVERAGE, eEDIT_TAKE, eEDIT_STOP};

열거의 시작이나 끝에 새 값을 추가하는 경우 이러한 제한이 사용된 모든 위치를 찾아서 변경해야 합니다. 많은 경우 건망증처럼 잊어버리고는 누락 되는 것이 발생할 수 있으며 이는 찾기 어려운 오류로 이어질 수 있습니다. 오류가 새로운 것을 추가해서 나타나는 것처럼 보이지만 실제로는 건망증 때문이라고 생각할 수 있습니다. 따라서 극단의 값 사이의 어딘가에 변경 사항을 추가합니다.

그 직후에 시스템에 메시지를 추가해야 합니다. 그렇지 않으면 런타임 오류가 발생할 수 있습니다. 따라서 소스 코드에 다음과 같은 줄을 추가합니다.

static const string C_Chart_IDE::szMsgIDE[] = {
                                                "MSG_RESULT",
                                                "MSG_NAME_SYMBOL",
                                                "MSG_BUY_MARKET",
                                                "MSG_SELL_MARKET",
                                                "MSG_DAY_TRADE",
                                                "MSG_CLOSE_POSITION",
                                                "MSG_LEVERAGE_VALUE",
                                                "MSG_TAKE_VALUE",
                                                "MSG_STOP_VALUE"
                                              };

보시다시피 순서를 유지하기 위해 같은 위치에 추가했습니다. 그러나 이 시점에서 상수는 언제든지 추가될 수 있습니다. 변경을 하더라도 어떤 객체가 메시지를 수신할지 확인하는 데만 사용되기 때문에 아무런 차이가 없습니다. 구조적 목적을 위해 두 번째 메시지로 추가했습니다.

이제 MetaTrader 5로 돌아가서 아래와 같이 변경해 보겠습니다:

         

이제 MetaTrader 5는 이미 IDE의 객체가 메시지를 수신하는 객체인 것으로 인식합니다. 남은 것은 메시지를 보내는 절차를 만드는 일만 남습니다. 메시지를 작성하는 것은 한 번만 추가되어야 하며 MetaTrader 5가 차트에 IDE를 배치하는 즉시 보낼 수 있어야 합니다. 이는 필요한 코드를 객체 클래스의 Create 함수 끝에 추가하기만 하면 됩니다. 그러나 코드가 수정 사항으로 가득 찬 엉망이 되지 않도록 DispatchMessage 함수 안에 새 코드를 추가합니다. 원래의 함수는 다음과 같습니다:

void DispatchMessage(int iMsg, string szArg, double dValue = 0.0)
{
        if (m_CountObject < eEDIT_STOP) return;
        switch (iMsg)
        {
                case CHARTEVENT_CHART_CHANGE:
                        if (szArg == szMsgIDE[eRESULT])
                        {
                                ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_BGCOLOR, (dValue < 0 ? clrLightCoral : clrLightGreen));
                                ObjectSetString(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_TEXT, DoubleToString(dValue, 2));
                        }
                        break;
                case CHARTEVENT_OBJECT_CLICK:

// ... The rest of the code...

        }
}

아래는 관련된 수정 후의 코드입니다.

void DispatchMessage(int iMsg, string szArg, double dValue = 0.0)
{
        if (m_CountObject < eEDIT_STOP) return;
        switch (iMsg)
        {
                case CHARTEVENT_CHART_CHANGE:
                        if (szArg == szMsgIDE[eRESULT])
                        {
                                ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_BGCOLOR, (dValue < 0 ? clrLightCoral : clrLightGreen));
                                ObjectSetString(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_TEXT, DoubleToString(dValue, 2));
                        }else if (szArg == szMsgIDE[eLABEL_SYMBOL])
                        {
                                ObjectSetString(Terminal.Get_ID(), m_ArrObject[eLABEL_SYMBOL].szName, OBJPROP_TEXT, Terminal.GetSymbol());
                                ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eLABEL_SYMBOL].szName, OBJPROP_ALIGN, ALIGN_CENTER);
                        }
                        break;
                case CHARTEVENT_OBJECT_CLICK:

// ... The rest of the code

        }
}

보내기 기능을 만든 후 이 메시지를 보낼 지점을 선택할 수 있습니다. 가장 좋은 위치는 객체 클래스의 Create 함수 끝에 있으므로 최종 코드는 다음과 같습니다.

bool Create(int nSub)
{
        m_CountObject = 0;
        if ((m_fp = FileOpen("Chart Trade\\IDE.tpl", FILE_BIN | FILE_READ)) == INVALID_HANDLE) return false;
        FileReadInteger(m_fp, SHORT_VALUE);
                                
        for (m_CountObject = eRESULT; m_CountObject <= eEDIT_STOP; m_CountObject++) m_ArrObject[m_CountObject].szName = "";
        m_SubWindow = nSub;
        m_szLine = "";
        while (m_szLine != "</chart>")
        {
                if (!FileReadLine()) return false;
                if (m_szLine == "<object>")
                {
                        if (!FileReadLine()) return false;
                        if (m_szLine == "type")
                        {
                                if (m_szValue == "102") if (!LoopCreating(OBJ_LABEL)) return false;
                                if (m_szValue == "103") if (!LoopCreating(OBJ_BUTTON)) return false;
                                if (m_szValue == "106") if (!LoopCreating(OBJ_BITMAP_LABEL)) return false;
                                if (m_szValue == "107") if (!LoopCreating(OBJ_EDIT)) return false;
                                if (m_szValue == "110") if (!LoopCreating(OBJ_RECTANGLE_LABEL)) return false;
                        }
                }
        }
        FileClose(m_fp);
        DispatchMessage(CHARTEVENT_CHART_CHANGE, szMsgIDE[eLABEL_SYMBOL]);
        return true;
}

추가된 것은 녹색으로 강조 표시됩니다. 우리는 거의 변경한 것이 없었지만 메시지의 흐름이 이미 100% 구현되어 있는 상태이며 이제 구현해야 하는 다음 메시지로 이동할 수 있습니다.

수정 2. 당일의 누적값 합산(Coverage point)

다시 말하지만 자산 이름을 추가할 때와 동일한 논리를 따르므로 새 코드는 다음과 같습니다.

enum eObjectsIDE {eRESULT, eLABEL_SYMBOL, eROOF_DIARY, eBTN_BUY, eBTN_SELL, eCHECK_DAYTRADE, eBTN_CANCEL, eEDIT_LEVERAGE, eEDIT_TAKE, eEDIT_STOP};

// ... Rest of the code

static const string C_Chart_IDE::szMsgIDE[] = {
                                                "MSG_RESULT",
                                                "MSG_NAME_SYMBOL",
                                                "MSG_ROOF_DIARY",
                                                "MSG_BUY_MARKET",
                                                "MSG_SELL_MARKET",
                                                "MSG_DAY_TRADE",
                                                "MSG_CLOSE_POSITION",
                                                "MSG_LEVERAGE_VALUE",
                                                "MSG_TAKE_VALUE",
                                                "MSG_STOP_VALUE"
                                              };

그런 다음 새 메시지로 IDE를 변경해 보겠습니다:

         

새로운 IDE가 준비되었습니다. 이제 당일의 누적 값을 포함하는 메시지를 생성하는 코드를 구현할 것입니다. 이 기능이 구현될 클래스를 먼저 결정해야 합니다. 많은 사람들이 C_Chart_IDE 클래스에서 이 함수를 만들 것입니다. 그러나 정돈된 코드를 위해 주문과 함께 작동하는 함수와 함께 넣는 것이 좋습니다. 따라서 코드는 C_OrderView 클래스에서 구현됩니다. 코드는 아래와 같습니다:

double UpdateRoof(void)
{
        ulong   ticket;
        int     max;
        string  szSymbol = Terminal.GetSymbol();
        double  Accumulated = 0;
                                
        HistorySelect(macroGetDate(TimeLocal()), TimeLocal());
        max = HistoryDealsTotal();
        for (int c0 = 0; c0 < max; c0++) if ((ticket = HistoryDealGetTicket(c0)) > 0)
                if (HistoryDealGetString(ticket, DEAL_SYMBOL) == szSymbol)
                        Accumulated += HistoryDealGetDouble(ticket, DEAL_PROFIT);
                                                
        return Accumulated;
}

이제 코드가 구현되었으므로 시스템에 메시지를 추가해야 합니다. 운영자의 편의를 위해 완료된 결과를 보고하는 코드를 이미 추가했습니다. 코드는 다음과 같습니다:

void DispatchMessage(int iMsg, string szArg, double dValue = 0.0)
{
        static double AccumulatedRoof = 0.0;
        bool    b0;
        double  d0;

        if (m_CountObject < eEDIT_STOP) return;
        switch (iMsg)
        {
                case CHARTEVENT_CHART_CHANGE:
                        if ((b0 = (szArg == szMsgIDE[eRESULT])) || (szArg == szMsgIDE[eROOF_DIARY]))
                        {
                                if (b0)
                                {
                                        ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_BGCOLOR, (dValue < 0 ? clrLightCoral : clrLightGreen));
                                        ObjectSetString(Terminal.Get_ID(), m_ArrObject[eRESULT].szName, OBJPROP_TEXT, DoubleToString(dValue, 2));
                                }else
                                {
                                        AccumulatedRoof = dValue;
                                        dValue = 0;
                                }
                                d0 = AccumulatedRoof + dValue;
                                ObjectSetString(Terminal.Get_ID(), m_ArrObject[eROOF_DIARY].szName, OBJPROP_TEXT, DoubleToString(MathAbs(d0), 2));
                                ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eROOF_DIARY].szName, OBJPROP_BGCOLOR, (d0 >= 0 ? clrForestGreen : clrFireBrick));
                        }else   if (szArg == szMsgIDE[eLABEL_SYMBOL])
                        {
                                ObjectSetString(Terminal.Get_ID(), m_ArrObject[eLABEL_SYMBOL].szName, OBJPROP_TEXT, Terminal.GetSymbol());
                                ObjectSetInteger(Terminal.Get_ID(), m_ArrObject[eLABEL_SYMBOL].szName, OBJPROP_ALIGN, ALIGN_CENTER);
                        }
                        break;
                case CHARTEVENT_OBJECT_CLICK:

// .... The rest of the code....

        }
}

강조 표시된 부분은 위에서 설명한대로 시스템을 지원합니다. 만약 시스템이 이러한 방식으로 구현되지 않은 경우 정보를 올바르게 업데이트하기 위해 시스템에 두 개의 메시지를 보내야 합니다. 그러나 위와 같이 코드가 구현된 방식을 따르면 단일 메시지를 통해 오픈 포지션의 결과와 당일의 결과를 모두 추적할 수 있습니다.

EA의 또 다른 수정 사항은OnTrade 함수와 관련한 것입니다. 이 함수는 다음과 같이 보입니다:

void OnTrade()
{
        SubWin.DispatchMessage(CHARTEVENT_CHART_CHANGE, C_Chart_IDE::szMsgIDE[C_Chart_IDE::eROOF_DIARY], NanoEA.UpdateRoof());
        NanoEA.UpdatePosition();
}

이 시스템은 작동하기는 하나 OnTick과 함께 EA의 성능을 저하시킬수 있는OnTrade 함수의 실행 시간에 주의해야 합니다. OnTick에 포함된 코드의 경우는 그다지 좋아 보이지 않으며 최적화가 중요합니다. 그러나OnTrade를 사용하면 더 쉬우며 실제로 포지션이 변경될 때 함수가 호출됩니다. 이를 알면 두 가지의 대안이 있다는 것을 짐작하실 것입니다. 첫 번째는UpdateRoof위치를 수정하여 실행 시간을 제한하는 것입니다. 또 다른 대안은OnTrade 함수 자체를 수정하는 것입니다. 실제 사용을 위해 Update Roof함수를 수정하고 이를 통해 오픈 포지션이 있을 경우 실행 시간이 조금이라도 개선되도록 할 것입니다. 새로운 기능은 다음과 같습니다:

double UpdateRoof(void)
{
        ulong           ticket;
        string  szSymbol = Terminal.GetSymbol();
        int             max;
        static int      memMax = 0;
        static double   Accumulated = 0;
                
        HistorySelect(macroGetDate(TimeLocal()), TimeLocal());
        max = HistoryDealsTotal();
        if (memMax == max) return Accumulated; else memMax = max;
        for (int c0 = 0; c0 < max; c0++) if ((ticket = HistoryDealGetTicket(c0)) > 0)
                if (HistoryDealGetString(ticket, DEAL_SYMBOL) == szSymbol)
                        Accumulated += HistoryDealGetDouble(ticket, DEAL_PROFIT);
                                                
        return Accumulated;
}

강조 표시된 줄은 원래 함수에 추가된 코드를 보여줍니다. 별거 아닌 것 같아도 많은 차이를 보입니다. 왜 그런지 살펴 봅시다. 코드가 처음으로 참조될 때 지정된 기간 동안 주문 내역에 값이 없으면memMax 정적 변수와 Accumulated가 모두 0으로 설정됩니다. 테스트에서 이들이 반영되고 루틴은 반환되지만 데이터가 있는 경우 테스트되고memMax와Accumulated모두 새 조건을 반영합니다. 이러한 변수가 정적이라는 사실은 해당 값이 호출 간에 유지된다는 것을 의미합니다. 따라서 자산의 움직임에 따라 포지션의 값이 변경되면 MetaTrader 5는OnTrade기능을 호출하는 이벤트를 생성합니다. 이 시점에서UpdateRoof함수의 새로운 호출이 있게 되며 포지션이 청산되지 않은 경우 함수는 제어점으로 돌아가고 반환 프로세스의 속도를 높입니다.

결론

이 기사에서는 RAD 시스템에 새로운 기능을 추가하여 상호 작용 및 제어 인터페이스를 구축할 때 훨씬 단순하고 오류가 적은 IDE 인터페이스를 생성하도록 하고 시스템을 이상적으로 만드는 라이브러리의 생성을 가능하게 하는 방법을 살펴보았습니다. 여기서는 MQL5로만 작업하는 것을 고려했습니다. 여러분의 창의성에 따라 여러가지로 사용될 수 있을 것입니다. 또한 동일한 아이디어를 외부 라이브러리에 통합하여 IDE의 생성을 크게 확장할 수도 있습니다.