CGraphicのテスト - 質問と提案

Vladimir Karputov 2016.12.10 14:21

新しい関数のアプリケーションを探す - 特にGrahic ライブラリ（科学的グラフ）のために。

例として、グラフ上の領域を矩形オブジェクトで選択し、スクリプトを実行します。

//+------------------------------------------------------------------+
//|                                             RECTANGLE_to_csv.mq5 |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.00"
#property script_show_inputs
#include <Graphics/Graphic.mqh>
//---
input string   rectangle_name="RECTANGLE";   // rectangle name
input int      sleeping=15000;               // sleep (milliseconds)
//---
CGraphic m_graphic;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   int result_find=ObjectFind(0,rectangle_name);
   Print("result_find: ",result_find);
   if(result_find!=-1)
     {
      datetime from  = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,0);
      datetime to    = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,1);
      MqlTick tick_array_range[];   // массив для приема тиков
      ResetLastError();
      CopyTicksRange(Symbol(),tick_array_range,COPY_TICKS_INFO,(ulong)from*1000,(ulong)to*1000);
      Print("Error: ",GetLastError());
      if(GetLastError()!=0)
         return;

      double   arr_ask[];
      int size=ArraySize(tick_array_range);
      ArrayResize(arr_ask,size);
      for(int i=0;i<size;i++)
         arr_ask[i]=tick_array_range[i].ask;

      GraphPlot(arr_ask,1);
      m_graphic.Destroy();
      Sleep(sleeping);
      ObjectsDeleteAll(0,"Graphic",0,OBJ_BITMAP_LABEL);
      ChartRedraw();
     }
  }
//+------------------------------------------------------------------+

その結果、Askによって、刻みでプロットされたグラフが表示されるのです。

ファイル:

RECTANGLE_to_csv.mq5 4 kb

Vladimir Karputov 2016.12.11 07:17 #1

CGraphicを使おうとすると。作成すると、マレーヴィッチの正方形が手に入る。

マレーヴィッチの広場

//+------------------------------------------------------------------+
//|                                             RECTANGLE_to_csv.mq5 |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.001"
#property script_show_inputs
#include <Graphics/Graphic.mqh>
//---
input string   rectangle_name="RECTANGLE";   // rectangle name
input int      sleeping=15000;               // sleep (milliseconds)
//---
CGraphic m_graphic;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   int result_find=ObjectFind(0,rectangle_name);
   Print("result_find: ",result_find);
   if(result_find!=-1)
     {
      datetime from  = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,0);
      datetime to    = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,1);
      MqlTick tick_array_range[];   // массив для приема тиков
      ResetLastError();
      CopyTicksRange(Symbol(),tick_array_range,COPY_TICKS_INFO,(ulong)from*1000,(ulong)to*1000);
      Print("Error: ",GetLastError());
      if(GetLastError()!=0)
         return;

      double   arr_ask[];
      int size=ArraySize(tick_array_range);
      ArrayResize(arr_ask,size);
      for(int i=0;i<size;i++)
         arr_ask[i]=tick_array_range[i].ask;

      m_graphic.Create(0,"Deals",0,30,30,500,300);
      m_graphic.CurveAdd(arr_ask,1);
      Print("Цвет фона перед \"Update\": ",m_graphic.BackgroundColor());
      m_graphic.Update();
      Print("Цвет фона после \"Update\": ",m_graphic.BackgroundColor());
      Sleep(sleeping);
      m_graphic.Destroy();
     }
  }
//+------------------------------------------------------------------+

2016.12.11 09:06:02.528 Terminal        MetaTrader 5 x64 build 1495 started (MetaQuotes Software Corp.)
2016.12.11 09:06:02.531 Terminal        Windows 10 Pro (x64 based PC), IE 11.00, UAC, Intel Core i3-3120 M  @ 2.50 GHz, RAM: 4882 / 8077 Mb, HDD: 357683 / 476372 Mb, GMT+02:00
2016.12.11 09:06:02.531 Terminal        C:\Users\barab\AppData\Roaming\MetaQuotes\Terminal\D0E8209F77C8CF37AD8BF550E51FF075

エキスパート」「ジャーナル」のいずれにもエラーはありません。

ファイル:

RECTANGLE_to_csv.mq5 5 kb

Testing CGraphic - questions エラー、バグ、質問 Errors, bugs, questions

Alexey Volchanskiy 2016.12.11 10:24 #2

Vladimir Karputov:

新しい関数のアプリケーションを探す - 特にGrahic ライブラリ（科学的グラフ）のために。

例えば、矩形オブジェクトを使ってグラフ上の領域を選択し、スクリプトを実行します。

ノンプログラマーのために、矩形はRECTANGLEと呼ばれるべきです。

質問 - X軸には何が表示されているのですか？2本のバーM1をマークし、ティックの数を数えたが、合わない、秒数も合わない。

--- 2016.12.11 10:35 #3

Vladimir Karputov:

CGraphicを使おうとすると。作成すると、マレーヴィッチの正方形が手に入る。

Update()の前にRedraw()を行っていません。

Alexey Volchanskiy 2016.12.11 11:37 #4

o_O:
Update()の前にRedraw()を行っていません。

完了、グラフ枠、軸を描画します。グラフそのものは存在しない。

また、このように描画されることも追加されました。

....
      m_graphic.Create(0,"Deals",0,30,30,500,300);
      CCurve* curve = m_graphic.CurveAdd(arr_ask,CURVE_LINES);
      curve.Color(clrBlack);
      curve.Visible(true);
      Print("Цвет фона перед \"Update\": ",m_graphic.BackgroundColor());
      m_graphic.Redraw();
      m_graphic.Update();
....

***

Vladimir Karputov 2016.12.11 11:51 #5

Alexey Volchanskiy:

完了、グラフ枠、軸を描画します。グラフそのものは存在しない。

また、補足すると、このように描画されます。

***

ありがとうございました。

作業バージョン（バージョン "1.003"）。

//+------------------------------------------------------------------+
//|                                             RECTANGLE_to_csv.mq5 |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.003"
#property script_show_inputs
#include <Graphics/Graphic.mqh>
//---
input string   rectangle_name="RECTANGLE";   // rectangle name
input int      sleeping=15000;               // sleep (milliseconds)
//---
CGraphic m_graphic;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   ResetLastError();
   int result_find=ObjectFind(0,rectangle_name);
   if(result_find<0)
     {
      Print("ObjectFind Error: ",GetLastError());
      return;
     }
   datetime from  = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,0);
   datetime to    = (datetime)ObjectGetInteger(0,rectangle_name,OBJPROP_TIME,1);
   MqlTick tick_array_range[];                  // массив для приема тиков
   ResetLastError();
   CopyTicksRange(Symbol(),tick_array_range,COPY_TICKS_INFO,(ulong)from*1000,(ulong)to*1000);
   if(GetLastError()!=0)
      return;

   double   arr_ask[];
   int size=ArraySize(tick_array_range);
   ArrayResize(arr_ask,size);
   for(int i=0;i<size;i++)
      arr_ask[i]=tick_array_range[i].ask;

   m_graphic.Create(0,"Deals",0,30,30,500,300); // создает графический ресурс, привязанный к объекту чарта

   CCurve *curve=m_graphic.CurveAdd(arr_ask,1); // создает и добавляет кривую (CCurve) на график
   curve.Visible(true);                         // отображает кривую

   m_graphic.Redraw();                          // redraw grahic
   m_graphic.Update();                          // отображает на экране сделанные изменения
   Sleep(sleeping);
   m_graphic.Destroy();                         // удаляет с чарта график и уничтожает графический ресурс
  }
//+------------------------------------------------------------------+

バージョン1.003

ファイル:

RECTANGLE_to_csv.mq5 5 kb

Testing CGraphic - questions MetaEditor build 1490 MetaEditor build 1490

--- 2016.12.11 12:58 #6

CGraphic クラスは、そのcanvasが非常に残念な（あるいは考え抜かれた）デザインになっています。

現在の形は、純粋にデモンストレーション用です。それ以外の用途にはほとんど使えません。m_canvas は、それ自身のオブジェクトで描画の位置や大きさを操作することができないため、不用意にグラフィックオブジェクト全体を占有してしまうのです。
また、m_canvasはprivateであるため、継承して自分のものを変更することは不可能です。

一般的には、
、継承時にキャンバスを利用できるようにするか、チャート上に実オブジェクトがなくてもこのm_canvasで作業できるようにし、その後、自分の判断で作った構築物を取り去るようにすることをお願いします。

--- 2016.12.11 16:36 #7

そして2点目は、CGraphicではすべての機能が仮想化されていないことです。

開発者の皆さん、なぜオーバーライドを禁じたのですか？

--- 2016.12.11 17:00 #8

      //--- trim the name
      m_canvas.FontSizeSet(m_history.name_size);
      if(m_canvas.TextWidth(name)>m_history.name_width)
        {
         while(m_canvas.TextWidth(name+"...")>m_history.name_width)
            name=StringSubstr(name,0,StringLen(name)-1);
         name+="...";
        }

m_history.name_width が小さいと while ループが無限大になるバグを発見。

右側の「履歴」を完全に無効にするにはどうすればよいですか？

Vladimir Karputov 2016.12.11 17:05 #9

私の知る限りでは

ゲットエックス

すべての曲線点のX座標を配列に書き込む

グラフ上に描かれたすべての点の「x」座標（ピクセル単位の座標）を配列に取得すればよいのですね。

チェックする。

//+------------------------------------------------------------------+
//|                                             RECTANGLE_to_csv.mq5 |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
#property script_show_inputs
#include <Graphics/Graphic.mqh>
//---
input int      m_width=500;                  // ширина
input int      m_height=300;                 // высота
input int      sleeping=15000;               // sleep (milliseconds)
//---
CGraphic m_graphic;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   double   arr_example[15]={1,2,3,4,5,6,7,8,9,10,11,12,13,14,15};

   m_graphic.Create(0,"Example",0,30,30,m_width,m_height); // создает графический ресурс, привязанный к объекту чарта

   CCurve *curve=m_graphic.CurveAdd(arr_example,1); // создает и добавляет кривую (CCurve) на график
   curve.Visible(true);                         // отображает кривую
   m_graphic.Redraw();                          // redraw grahic

   double arr_get_x[];
   curve.GetX(arr_get_x);                       // записываем координаты X для всех точек кривой в массив

   ArrayPrint(arr_get_x);                       // распечатываем массив

   m_graphic.Update();                          // отображает на экране сделанные изменения
   Sleep(sleeping);
   m_graphic.Destroy();                         // удаляет с чарта график и уничтожает графический ресурс
  }
//+------------------------------------------------------------------+

グラフが描かれる。

CCurve

この配列には、グラフを描くためのデータは含まれていますが、ピクセル単位の「x」座標は含まれていないことがわかりました。

2016.12.11 19:03:09.691 GetX (EURUSD,M1) 0.0 1.00000 2.00000 3.00000 4.00000 5.00000 6.00000 7.00000 8.00000 9.00000 10.00000 11.00000 12.00000 13.00000 14.00000

ファイル:

GetX.mq5 4 kb

Testing CGraphic - questions MetaEditor build 1490 trade.PositionClose() is not working

--- 2016.12.11 17:14 #10

Vladimir Karputov:

グラフ上に描かれたすべての点の「x」座標（ピクセル単位の座標）を配列に取得する必要があるのですが？

私は「ピクセル」なんて言ってませんよ。

Y配列しか提出されていませんね。だから、xは単純な序数である。GetXの言うとおりです。

1 2 3 4 5 6 7 8 9 10 11 12 13

新しいコメント