MQ4へのMySQLのアタッチメント - ページ 2

新しいコメント
 
私はMySqlを扱ったことはありませんが、MS SQLを扱ったことがあります。
 
MQL4でmysql_fetch_row 関数の結果を読み込むにはどうしたらいいですか？
 
sergeev:

MQL4でmysql_fetch_row 関数の結果を読み取る方法?

現在、MySQLデータベースと連動して、読み込み、挿入、削除、変更を行うスクリプトを開発しています。

スクリプトは大きなものですが、データベースとの連携の エッセンスは、1つの関数から理解できると思います。

しかし、この例では、テーブルからレコードのIDが返されますが、それはリメイクに問題はないでしょう、私は覚えていると、データベースから返されたテキストと数字は、すべてが動作しました。 

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
#import "libmysql.dll"
int mysql_init(int db);
int mysql_errno(int TMYSQL);
int mysql_real_connect(int TMYSQL, string host, string user, string password, string DB,int port,int socket,int clientflag);
int mysql_real_query(int TMSQL, string query, int length);
int mysql_store_result(int TMSQL); 
string mysql_fetch_row(int result); 
int mysql_num_rows(int result); 
void mysql_free_result(int result);
void mysql_close(int TMSQL);
int mysql_insert_id(int result);
#import

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int mysql; string query = ""; int myerr;

int CompanyID = 0;
int SymbolID = 0;
int LastRecordQuotesID = 0;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool connect() { 
   mysql = mysql_init(mysql); 
   if (mysql!=0) Print("allocated"); 
   string host="IP adress";          // меняем на своё
   string user="Login";              // меняем на своё
   string password="Password";       // меняем на своё
   string DB="db_base";              // меняем на своё
   int clientflag=0; 
   int port=3306; 
   string socket=""; 
   int res=mysql_real_connect(mysql,host,user,password,DB,port,socket,clientflag); 
   int err=GetLastError(); 
   if (res==mysql){
      Print("connected"); 
      return(true);
   } else {
      Print("error=",mysql," ",mysql_errno(mysql)," ");
      return(false);
   }
return(false);
} 

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int start(){
   if(!connect()) return(0);
//----
   CompanyID = CompanyID(AccountCompany(), AccountServer());
//----
   mysql_close(mysql);
   return(0);
  }

//+--------------------------------------------------------------------------------------------+
//| Функция поиска и вставки названия компании и сервера для связи.                            |
//+--------------------------------------------------------------------------------------------+
//| Переменные:                                                                                |
//|            string AccCompany  - AccountCompany()                                           |
//|            string AccServer   - AccountServer()                                            |
//+--------------------------------------------------------------------------------------------+
int CompanyID(string AccCompany = "", string AccServer = ""){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT id FROM Company WHERE Company = \'",AccCompany,"\' AND `Server` = \'",AccServer,"\'");
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StrToInteger(StringSubstr(row, 8, StringLen(row)-1) ) );
   } else {
      query = StringConcatenate( "INSERT INTO `Company` (`Company`, `Server`) VALUES (\'",AccCompany ,"\', \'",AccServer,"\')");
      mysql_real_query(mysql,query,CountLength(query));
      myerr = mysql_errno(mysql);
      if(myerr > 0) Print("CompanyID(): error=",myerr);
      mysql_free_result(result);
      return(mysql_insert_id(mysql));
   }
}

//+--------------------------------------------------------------------------------------------+
//| Вспомогательная Функция подсчёта колличества символов в передаваемом запросе.              |
//+--------------------------------------------------------------------------------------------+
//| Переменные:                                                                                |
//|            string query  - Текстовая страка                                                |
//+--------------------------------------------------------------------------------------------+
int CountLength(string query){
   return(StringLen(query));
}

//+--------------------------------------------------------------------------------------------+
//| Вспомогательная Функция подсчёта колличества результатов из базы данных                    |
//+--------------------------------------------------------------------------------------------+
//| Переменные:                                                                                |
//|            int result  - Результат запроса                                                 |
//+--------------------------------------------------------------------------------------------+
int Number_Of_Rows(int result){
   return(mysql_num_rows(result));
}
 

じっけんだい


INT id; TEXT user

の2つのフィールドを持つテーブルを作成 しました。テーブルには、
id user
1 aaa
2 bbb の2行があります。

1.SELECT id FROM table "の問い合わせに対して、fetch_row関数は、(アドレス)(アドレス)1 (アドレス)(アドレス) 2
2.SELECT user FROM table" クエリの fetch_row 関数は、(アドレス)aaa (アドレス) bbb

 一般に、これは処理可能ですが、唯一残念なのは、文字列で返されることです。

SELECT id, user FROM table」という2つのフィールドを問い合わせると、（アドレス）1（アドレス）（アドレス）2
 4が返されます。SELECT user, id FROM table」のフィールドを入れ替えると、関数は（アドレス）aaa（アドレス）bbb

、文字列から最初のフィールドだけがはっきりと見え、もう4バイトのアドレスが追加されていることがわかります。

 
sergeev:

じっけんだい

2つのフィールドを持つテーブルを作成しました。
INT id; TEXT user

テーブルが2行になる
イドユーザー
1 aaa
2 bbb

1.SELECT id FROM table" の問い合わせに対して、fetch_row 関数は (address)(address)1 (address)(address) 2 を返します。
2.SELECT user FROM table" をリクエストすると fetch_row が (address)aaa (address) bbb

 通常は処理できるが、戻り値が文字列になってしまう。

3. 関数が2つのフィールドを要求する場合 "SELECT id, user FROM table" は、 (address)(address)1(address)(address)2
4.SELECT user, id FROM table」のフィールドを入れ替えると、（アドレス）aaa（アドレス）bbb
 が返されます。
は、文字列から最初のフィールドだけを明示的に見て、別の4バイトのアドレスを追加していることが判明しました。


この後、どのようにプログラムに反映させるのですか？

基本的には浮動小数点数を書いて、それを読み取るということをやっています。

 
HIDDEN:

現在、MySQLデータベースと連動して、読み込み、挿入、削除、変更を行うスクリプトを開発しています。

スクリプトは大きなものですが、データベースとの連携のエッセンスは、1つの関数から理解できると思います。

Trueは、この例では、テーブルからレコードIDを返しますが、何の問題もリメイクするために、私は覚えていて、テキストと数字は、データベースから返され、すべてが働いた。


これは面白い例ですが、数値データの読み方を示しているわけではありません。

基本的には、2つのアクションだけのために3列のテーブルを持つベースを使いたいのです。

1) 最初の2列（インデックスと最初の数値列）を読み取る。

次に、MQ4プログラム内の数値欄から最も適切な数値を選択します。

2) 2番目の列からその番号のインデックスを使って番号を読み取る。

この場合、どの関数を使用すればよいのでしょうか？また、指定されたDLLでは正常に動作するのでしょうか？

 
Eugene1:


これは面白い例ですが、数値データの読み方を示しているわけではありません。


何がどのように返されるかを確認するために、1行でもコードを書いたことがありますか？

HIDDENは、データベースから1つのフィールドを読み取るための完全な解決策をすでに提供していますが、それを実行しましたか？

 
Graff:

もしあなたがMKL5用のansi-unicodeコンバータを書くのを手伝うことができるなら、そのコードは前の投稿に示されています。MKL4の動作コードをお送りしますので、MKL5のクラスを作成する際にもお役立てください。


MQL5にはユニコードを変換する関数があります。en/docs/convert/chararraytostring および/en/docs/convert/stringtochararray を参照してください。

関数のインポートで、文字列の代わりにuchar配列を宣言する。

 
stringo:


インポート関数では、文字列を宣言せず、uchar 型の配列を宣言してください。


問題は、残念ながら、これらの文字列は関数の結果として 返されるのであって、関数の＆パラメータの1つとして返されるのではないことです。

mysql_fetch_row は文字列の配列へのポインタを 返します。

--------

は、char 配列からchar ** 文字列を返す低レベルのカーネル関数があるかどうか、誰か知っていますか？
(strcpy、strcat...など)

同様に、 int* 配列から、その特定の要素を取得するためのいくつかの lib 関数？
その関数自体がこの操作のために直接設計されていないとしても :)

 

フルコードの実装....

#import "libmysql.dll"
int mysql_init(int db);
int mysql_errno(int TMYSQL);
int mysql_real_connect(int TMYSQL, string host, string user, string password, string DB,int port,int socket,int clientflag);
int mysql_real_query(int TMSQL, string query, int length);
int mysql_store_result(int TMSQL); 
string mysql_fetch_row(int result); 
int mysql_num_rows(int result); 
void mysql_free_result(int result);
void mysql_close(int TMSQL);
int mysql_insert_id(int result);
#import

#include <WinUser32.mqh>

int mysql; string query = ""; int myerr;
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start(){
   if(!connect()) return(0);
//----
   Print("Возвращаем ID из MySQL: ",Read_ID(10));
   Print("Возвращаем Integer из MySQL: ",Read_Integer(1));
   Print("Возвращаем Double из MySQL: ",DoubleToStr(Read_Double(1),8));
   Print("Возвращаем Datetime из MySQL: ",Read_Datetime(1)," (",StrToTime(Read_Datetime(1)),")");
   Print("Возвращаем Text из MySQL: ",Read_Text(1));
//----
   mysql_close(mysql);
   return(0);
  }
//+------------------------------------------------------------------+
bool connect() { 
   mysql = mysql_init(mysql); 
   if (mysql!=0) Print("allocated"); 
   string host="localhost"; 
   string user="root"; 
   string password=""; 
   string DB="mql4"; 
   int clientflag=0; 
   int port=3306; 
   string socket=""; 
   int res=mysql_real_connect(mysql,host,user,password,DB,port,socket,clientflag); 
   int err=GetLastError(); 
   if (res==mysql){
      Print("connected"); 
      return(true);
   } else {
      Print("error=",mysql," ",mysql_errno(mysql)," ");
      return(false);
   }
return(false);
} 

//+--------------------------------------------------------------------------------------------+
//| Читаем ID из MySQL                                                                         |
//+--------------------------------------------------------------------------------------------+
int Read_ID(int number = 0){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT id FROM MQL4_TEST WHERE `integer` = ", number);
   
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StrToInteger(StringSubstr(row, 8, StringLen(row)-1) ) );
   }
}

//+--------------------------------------------------------------------------------------------+
//| Читаем Integer из MySQL                                                                         |
//+--------------------------------------------------------------------------------------------+
int Read_Integer(int id = 0){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT `integer` FROM MQL4_TEST WHERE id = ", id);
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StrToInteger(StringSubstr(row, 8, StringLen(row)-1) ) );
   }
}

//+--------------------------------------------------------------------------------------------+
//| Читаем Double из MySQL                                                                         |
//+--------------------------------------------------------------------------------------------+
double Read_Double(int id = 0){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT `double` FROM MQL4_TEST WHERE id = ", id);
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StrToDouble(StringSubstr(row, 8, StringLen(row)-1) ) );
   }
}

//+--------------------------------------------------------------------------------------------+
//| Читаем Datetime из MySQL                                                                         |
//+--------------------------------------------------------------------------------------------+
string Read_Datetime(int id = 0){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT `datetame` FROM MQL4_TEST WHERE id = ", id);
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StringSubstr(row, 8, StringLen(row)-1) );
   }
}

//+--------------------------------------------------------------------------------------------+
//| Читаем Text из MySQL                                                                         |
//+--------------------------------------------------------------------------------------------+
string Read_Text(int id = 0){
   int count_records, result;
   string row = "";
   
   query = StringConcatenate("SELECT text FROM MQL4_TEST WHERE id = ", id);
   mysql_real_query(mysql,query,CountLength(query));
   myerr = mysql_errno(mysql);
   if(myerr > 0) Print("error=",myerr);
   result = mysql_store_result(mysql);
   count_records = Number_Of_Rows(result);
   
   if (count_records > 0){
      row = mysql_fetch_row(result);
      mysql_free_result(result);
      return( StringSubstr(row, 8, StringLen(row)-1) );
   }
}
//+--------------------------------------------------------------------------------------------+
//| Вспомогательная Функция подсчёта колличества результатов из базы данных                    |
//+--------------------------------------------------------------------------------------------+
//| Переменные:                                                                                |
//|            int result  - Результат запроса                                                 |
//+--------------------------------------------------------------------------------------------+
int Number_Of_Rows(int result){
   return(mysql_num_rows(result));
}

//+--------------------------------------------------------------------------------------------+
//| Вспомогательная Функция подсчёта колличества символов в передаваемом запросе.              |
//+--------------------------------------------------------------------------------------------+
//| Переменные:                                                                                |
//|            string query  - Текстовая страка                                                |
//+--------------------------------------------------------------------------------------------+
int CountLength(string query){
   return(StringLen(query));
}

データベースのSQLダンプ

SET FOREIGN_KEY_CHECKS=0;
-- ----------------------------
-- Table structure for `MQL4_TEST`
-- ----------------------------
DROP TABLE IF EXISTS `MQL4_TEST`;
CREATE TABLE `MQL4_TEST` (
  `id` int(11) NOT NULL AUTO_INCREMENT,
  `integer` int(11) DEFAULT NULL,
  `double` double(11,8) DEFAULT NULL,
  `datetame` datetime DEFAULT NULL,
  `text` varchar(255) DEFAULT NULL,
  PRIMARY KEY (`id`)
) ENGINE=MyISAM AUTO_INCREMENT=2 DEFAULT CHARSET=cp1251;

-- ----------------------------
-- Records of MQL4_TEST
-- ----------------------------
INSERT INTO `MQL4_TEST` VALUES ('1', '10', '20.12345678', '2011-05-16 10:24:43', 'Тестирование MySQL и MQL4');

動作結果

1234567
新しいコメント