MQL5の初心者の質問です。プロは素通りしない。 - ページ 8

新しいコメント
 

1つの保留中の注文の チケットを取得するのに役立つ。こうはいかないんです。

      Print("количество ордеров ",OrdersTotal());
      if(OrderGetTicket(1))
     {
      Print("тикет ",OrderGetInteger(ORDER_POSITION_ID)); 
     }
 
ascerdfg:

1つの保留中の注文の チケットを取得するのに役立つ。こうはいかないんです。

オーダーリストの番号は1ではなく、0から始まります。
 
Vasiliy Pushkaryov:
オーダーリストのナンバリングは1ではなく0から始まります。

ゼロも試したことがあります。

 
ascerdfg:

1つの保留中の注文の チケットを取得するのに役立つ。こうはいかないんです。

何を取り出したのか、正確にチェックをしてみてはいかがでしょうか。

ヘルプにあるサンプルを実行するOrderGetTicket is a script:

void OnStart() 
  { 
//--- переменные для получения значений из свойств ордера 
   ulong    ticket; 
   double   open_price; 
   double   initial_volume; 
   datetime time_setup; 
   string   symbol; 
   string   type; 
   long     order_magic; 
   long     positionID; 
//--- количество текущих отложенных ордеров 
   uint     total=OrdersTotal(); 
//--- пройдем в цикле по всем ордерам 
   for(uint i=0;i<total;i++) 
     { 
      //--- получим тикет ордера по его позиции в списке 
      if((ticket=OrderGetTicket(i))>0) 
        { 
         //--- получим свойства ордера 
         open_price    =OrderGetDouble(ORDER_PRICE_OPEN); 
         time_setup    =(datetime)OrderGetInteger(ORDER_TIME_SETUP); 
         symbol        =OrderGetString(ORDER_SYMBOL); 
         order_magic   =OrderGetInteger(ORDER_MAGIC); 
         positionID    =OrderGetInteger(ORDER_POSITION_ID); 
         initial_volume=OrderGetDouble(ORDER_VOLUME_INITIAL); 
         type          =EnumToString(ENUM_ORDER_TYPE(OrderGetInteger(ORDER_TYPE))); 
         //--- подготовим и выведем информацию об ордере 
         printf("#ticket %d %s %G %s at %G was set up at %s", 
                ticket,                 // тикет ордера 
                type,                   // тип 
                initial_volume,         // выставленный объем 
                symbol,                 // символ, по которому выставили 
                open_price,             // указанная цена открытия 
                TimeToString(time_setup)// время установки ордера 
                ); 
        } 
     } 
//--- 
  }
  
Print("тикет ",OrderGetTicket(0));
そういうことなんだ!
12345678
新しいコメント