Funciones útiles de KimIV

Igor Kim 2008.05.29 03:30 #231

La función NumberOfLossPosToday().

Esta función devuelve el número de posiciones perdedoras cerradas hoy. La selección de las posiciones a tener en cuenta se realiza mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones de este instrumento. El valor por defecto "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает количество убыточных позиций, закрытых сегодня.     |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int NumberOfLossPosToday(string sy="", int op=-1, int mn=-1) {
  datetime t;
  int      i, k=OrdersHistoryTotal(), kp=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              t=OrderCloseTime();
              if (Year()==TimeYear(t) && DayOfYear()==TimeDayOfYear(t)) {
                if (OrderProfit()<0) kp++;
              }
            }
          }
        }
      }
    }
  }
  return(kp);
}

P.D. Se adjunta un script para probar la función NumberOfLossPosToday().

Archivos adjuntos:

test_numberoflosspostoday.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

Igor Kim 2008.06.01 06:41 #232

La función PriceCloseLastPos().

Esta función devuelve el precio de cierre de la última posición cerrada. La selección de las posiciones a tener en cuenta se define mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones de este instrumento. El valor por defecto "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает цену закрытия последней закрытой позиций.           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double PriceCloseLastPos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=0;
  int      i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (t<OrderCloseTime()) {
                t=OrderCloseTime();
                r=OrderClosePrice();
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

HH. Se adjunta un script para probar la función PriceCloseLastPos().

Archivos adjuntos:

test_pricecloselastpos.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

khorosh 2008.06.01 17:27 #233

Estimado KimIV Estaría bien que publicaras una biblioteca con todas tus funciones al final de tu hilo.

Rid 2008.06.02 05:52 #234

Lo secundo. Incluso puedes hacerlo de esta manera. No toda la biblioteca. Pero varias bibliotecas, y no al final, sino a medida que se acumulan las bibliotecas fi sobre un tema concreto.

Por ejemplo, la biblioteca por separado en la apertura/cierre (apertura f-i sólo más apertura por Market Watch y cierre)

La siguiente biblioteca - con f.i. que devuelve la presencia de posiciones por estos o aquellos atributos.

Y así sucesivamente.

Sólo hay que recoger aquí las sugerencias de los presentes sobre el conjunto completo de bibliotecas.

EURUSD - Tendencias, previsiones ¿Es posible implementar una [¡Archivo!] Cualquier pregunta de

Igor Kim 2008.06.02 16:06 #235

La función PriceOpenLastPos().

Esta función devuelve el precio de apertura de la última posición abierta. La selección de las posiciones a tener en cuenta se especifica mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones del instrumento especificado. El valor por defecto - "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает цену открытия последней открытой позиций.           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double PriceOpenLastPos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=0;
  int      i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (t<OrderOpenTime()) {
                t=OrderOpenTime();
                r=OrderOpenPrice();
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

ZS. Se adjunta un script para probar la función PriceOpenLastPos().

Archivos adjuntos:

test_priceopenlastpos.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

Igor Kim 2008.06.03 02:54 #236

La función PriceOpenLastClosePos().

Esta función devuelve el precio de apertura de la última posición cerrada. La selección de las posiciones a tener en cuenta se especifica mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones de este instrumento. El valor por defecto - "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 03.06.2008                                                     |
//|  Описание : Возвращает цену открытия последней закрытой позиций.           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double PriceOpenLastClosePos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=0;
  int      i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (t<OrderCloseTime()) {
                t=OrderCloseTime();
                r=OrderOpenPrice();
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

HH. Se adjunta un script para probar la función PriceOpenLastClosePos().

Archivos adjuntos:

test_priceopenlastclosepos.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

[Eliminado] 2008.06.03 07:56 #237

rid:

Lo secundo. Incluso podrías hacerlo de esta manera. No toda la biblioteca. Pero varias bibliotecas, y no al final, sino a medida que se acumulan las bibliotecas fi sobre un tema concreto.

Por ejemplo, la biblioteca por separado en la apertura/cierre (apertura f-i sólo más apertura por Market Watch y cierre)

La siguiente biblioteca - con f.i. que devuelve la existencia de posiciones por estos o aquellos atributos.

Y así sucesivamente.

Me gustaría hacer algunas sugerencias sobre la adquisición de bibliotecas.

Buenas tardes.

Querida KimIV.

Estáis haciendo algo muy útil para los escritores expertos principiantes.

Me sumo al anterior peticionario.

Si no es difícil, ¿puede reunir en una "plantilla de expertos " las principales funciones?

-Comprobaciones preliminares

-Apertura de un puesto

-Poner orden

-Cerrar una posición

-Retirar pedidos

-Apoyo (modificación) de órdenes y posiciones.

Y todo el mundo escribirá un bloque con llamadas a estas funciones por sí mismo.

No puedo escribir un EA desde cero.

Por eso empecé cambiando el código de otra persona.

Empecé a añadir sus funciones en bloques - lo que obtengo es un desorden.

Después de unos días de correcciones y adiciones, el Asesor Experto de prueba funcionó, pero muy mal.

Por eso hice esta petición, para crear una plantilla simple de Asesor Experto.

La plantilla de Roche es algo difícil de entender para mí y redundante al principio - del artículo de MetaEditor: Building on the power of templates.

MetaTrader 4 Build 529 [ARCHIVO] Cualquier pregunta de [¡AVISO CERRADO!] Cualquier pregunta

Igor Kim 2008.06.04 04:18 #238

La función PriceOpenNearPos().

Esta función devuelve el precio de apertura de la posición más cercana. La distancia mínima en pips entre el precio de apertura de la posición y el precio actual del mercado sirve como criterio para la "cercanía" de una posición. La selección de las posiciones a tener en cuenta se establece mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones del instrumento especificado. El valor por defecto "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto de -1 representa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 04.06.2008                                                     |
//|  Описание : Возвращает цену открытия ближайшей позиции.                    |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double PriceOpenNearPos(string sy="", int op=-1, int mn=-1) {
  double mi, oop=0, p;
  int    i, k=OrdersTotal(), pp=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (OrderType()==OP_BUY)  mi=MarketInfo(OrderSymbol(), MODE_ASK);
            if (OrderType()==OP_SELL) mi=MarketInfo(OrderSymbol(), MODE_BID);
            p=MarketInfo(OrderSymbol(), MODE_POINT);
            if (p==0) if (StringFind(sy, "JPY")<0) p=0.0001; else p=0.01;
            if (pp==0 || pp>MathAbs(OrderOpenPrice()-mi)/p) {
              pp=MathAbs(OrderOpenPrice()-mi)/p;
              oop=OrderOpenPrice();
            }
          }
        }
      }
    }
  }
  return(oop);
}

SZY. Se adjunta un script para probar la función PriceOpenNearPos().

Si alguien está interesado, que compare DistMarketAndPos() y PriceOpenNearPos() por sí mismo. Fíjate en las diferencias.

Archivos adjuntos:

test_priceopennearpos.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

Igor Kim 2008.06.05 03:34 #239

La función TicketNearPos().

Esta función devuelve el ticket de la posición más cercana al mercado. La distancia mínima en puntos entre el precio de apertura y el precio actual del mercado se utiliza como criterio de "cercanía" de una posición. La selección de las posiciones a considerar se establece mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones del instrumento especificado. El valor por defecto "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 05.06.2008                                                     |
//|  Описание : Возвращает тикет ближайшей к рынку позиции по цене открытия.   |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int TicketNearPos(string sy="", int op=-1, int mn=-1) {
  double mi, p;
  int    i, k=OrdersTotal(), pp=0, ti=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (OrderType()==OP_BUY)  mi=MarketInfo(OrderSymbol(), MODE_ASK);
            if (OrderType()==OP_SELL) mi=MarketInfo(OrderSymbol(), MODE_BID);
            p=MarketInfo(OrderSymbol(), MODE_POINT);
            if (p==0) if (StringFind(sy, "JPY")<0) p=0.0001; else p=0.01;
            if (pp==0 || pp>MathAbs(OrderOpenPrice()-mi)/p) {
              pp=MathAbs(OrderOpenPrice()-mi)/p;
              ti=OrderTicket();
            }
          }
        }
      }
    }
  }
  return(ti);
}

ZS. Se adjunta un script para probar la función TicketNearPos().

Archivos adjuntos:

test_ticketnearpos.mq4 4 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

Igor Kim 2008.06.07 04:12 #240

Función TypeNearPos().

Esta función devuelve el tipo(0-Compra, 1-Venta) de la posición más cercana al mercado al precio de apertura o -1. La distancia mínima en pips entre el precio de apertura de una posición y el precio actual del mercado sirve como criterio para la "cercanía" de una posición. La selección de las posiciones a tener en cuenta se establece mediante parámetros externos:

sy - Nombre del instrumento de mercado. Si se establece este parámetro, la función sólo tendrá en cuenta las posiciones del instrumento especificado. El valor por defecto "" significa cualquier instrumento de mercado. El valor nulo significa el instrumento actual.
op - Operación comercial, tipo de posición. Valores válidos: OP_BUY, OP_SELL o -1. El valor por defecto -1 significa cualquier posición.
mn - Identificador de posición, MagicNumber. El valor por defecto -1 significa cualquier identificador.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 07.06.2008                                                     |
//|  Описание : Возвращает тип ближайшей к рынку позиции или -1.               |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int TypeNearPos(string sy="", int op=-1, int mn=-1) {
  double mi, p;
  int    i, k=OrdersTotal(), pp=0, ty=-1;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (OrderType()==OP_BUY)  mi=MarketInfo(OrderSymbol(), MODE_ASK);
            if (OrderType()==OP_SELL) mi=MarketInfo(OrderSymbol(), MODE_BID);
            p=MarketInfo(OrderSymbol(), MODE_POINT);
            if (p==0) if (StringFind(sy, "JPY")<0) p=0.0001; else p=0.01;
            if (pp==0 || pp>MathAbs(OrderOpenPrice()-mi)/p) {
              pp=MathAbs(OrderOpenPrice()-mi)/p;
              ty=OrderType();
            }
          }
        }
      }
    }
  }
  return(ty);
}

ZS. Se adjunta un script para probar la función TypeNearPos().

Archivos adjuntos:

test_typenearpos.mq4 5 kb

Solo "Características útiles de Y hagamos una "caricatura" Cualquier pregunta de los

Funciones útiles de KimIV - página 24

La función NumberOfLossPosToday().

La función PriceCloseLastPos().

La función PriceOpenLastPos().

La función PriceOpenLastClosePos().

La función PriceOpenNearPos().

La función TicketNearPos().

Función TypeNearPos().