Ayuda para crear indicador canal equidistante

Juan David Rendon 2020.09.29 20:19

Buenas tardes compañeros,

Requiero de su ayuda para ejecutar una idea que tengo respecto a la creación de un indicador. La función de este será crear un canal equidistante a partir de una MA. Por ejemplo:

//--- descripción
#property description "El script construye el objeto gráfico \"Canal equidistante\"."
#property description "Las coordenadas de los puntos de anclaje se establecen en por cientos de las dimensiones"
#property description "de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string          InpName="Channel";   // Nombre del canal
input int             InpDate1=25;         // Fecha del 1-er punto en %
input int             InpPrice1=60;        // Precio del 1-er punto en %
input int             InpDate2=65;         // Fecha del 2-do punto en %
input int             InpPrice2=80;        // Precio del 2-do punto en %
input int             InpDate3=30;         // Fecha del 3-er punto en %
input int             InpPrice3=40;        // Precio del 3-er punto en %
input color           InpColor=clrRed;     // Color del canal
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Estilo de las líneas del canal
input int             InpWidth=2;          // Grosor de las líneas del canal
input bool            InpBack=false;       // Canal al fondo
input bool            InpFill=false;       // Relleno del canal con el color
input bool            InpSelection=true;   // Seleccionar para mover
input bool            InpRayLeft=false;    // Continuación del canal a la izquierda
input bool            InpRayRight=false;   // Continuación del canal a la derecha
input bool            InpHidden=true;      // Ocultar en la lista de objetos
input long            InpZOrder=0;         // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea el canal equidistante según las coordenadas establecidas             |
//+------------------------------------------------------------------+
bool ChannelCreate(const long            chart_ID=0,        // ID del gráfico
                   const string          name="Channel",    // nombre del canal
                   const int             sub_window=0,      // número de subventana 
                  datetime              time1=0,           // hora del primer punto
                 double                price1=0,          // precio del primer punto
                 datetime              time2=0,           // hora del segundo punto
                  double                price2=0,          // precio del segundo punto
                   datetime              time3=0,           // hora del tercer punto
                   double                price3=0,          // precio del tercer punto
                   const color           clr=clrRed,        // color del canal
                   const ENUM_LINE_STYLE style=STYLE_SOLID, // estilo de las líneas del canal
                   const int             width=1,           // grosor de las líneas del canal
                   const bool            fill=false,        // relleno del canal con el color
                   const bool            back=false,        // al fondo
                   const bool            selection=true,    // seleccionar para mover
                   const bool            ray_left=false,    // continuación del canal a la izquierda
                   const bool            ray_right=false,   // continuación del canal a la derecha
                   const bool            hidden=true,       // ocultar en la lista de objetos
                   const long            z_order=0)         // prioridad para el clic del ratón
  {
//--- establecemos las coordenadas de los puntos de anclaje si todavía no han sido establecidas
   ChangeChannelEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- anulamos el valor del error
   ResetLastError();
//--- creamos el canal según las coordenadas establecidas
   if(!ObjectCreate(chart_ID,name,OBJ_CHANNEL,sub_window,time1,price1,time2,price2,time3,price3))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al crear el canal equidistante! Código del error = ",GetLastError());
      return(false);
     }
//--- fijamos el color del canal
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de las líneas del canal
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de las líneas del canal
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- activar (true) o desactivar (false) el modo de relleno del canal
   ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de selección del canal para mover
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- activamos (true) o desactivamos (false) el modo de continuación del canal a la izquierda
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- activamos (true) o desactivamos (false) el modo de continuación del canal a la derecha
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje del canal                                 |
//+------------------------------------------------------------------+
bool ChannelPointChange(const long   chart_ID=0,     // ID del gráfico
                        const string name="Channel", // nombre del canal
                        const int    point_index=0,  // número del punto de anclaje
                        datetime     time=0,         // coordenada del tiempo del punto de anclaje
                        double       price=0)        // coordenada del precio del punto de anclaje
  {
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- movemos el punto de anclaje
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Elimina el canal                                                    |
//+------------------------------------------------------------------+
bool ChannelDelete(const long   chart_ID=0,     // ID del gráfico
                   const string name="Channel") // nombre del canal
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos el canal
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al eliminar el canal! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Comprueba los valores de los puntos de anclaje del canal y para   |
//| los valores vacíos establece los valores por defecto                              |
//+------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,double &price1,datetime &time2,
                              double &price2,datetime &time3,double &price3)
  {
//--- si la hora del segundo punto (de la derecha) no ha sido establecida, se colocará en la barra actual
   if(!time2)
      time2=TimeCurrent();
//--- si el precio del segundo punto no ha sido establecido, tendrá el valor Bid
   if(!price2)
      price2=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si la hora del primer punto (de la izquierda) no ha sido establecida, se colocará a 9 barras a la izquierda del segundo
   if(!time1)
     {
      //--- array para recibir la hora de apertura de las últimas 10 barras
      datetime temp[10];
      CopyTime(Symbol(),Period(),time2,10,temp);
      //--- colocamos el primer punto a 9 barras a la izquierda del segundo
      time1=temp[0];
     }
//--- si el precio del primer punto no ha sido establecido, lo moveremos a 300 puntos por encima del segundo punto
   if(!price1)
      price1=price2+300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- si la hora del tercer punto no ha sido establecida, va a coincidir con la hora del primer punto
   if(!time3)
      time3=time1;
//--- si el precio del tercer punto no ha sido establecido, va a coincidir con el precio del segundo punto
   if(!price3)
      price3=price2;
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- comprobamos si los parámetros de entrada son correctos
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 || 
      InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
     {
      Print("¡Error. Los parámetros de entrada no son correctos!");
      return;
     }
//--- número de barras visibles en la ventana del gráfico
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamaño del array price
   int accuracy=1000;
//--- arrays para guardar los valores de las fechas y precios que van a utilizarse
//--- para establecer y modificar las coordenadas de los puntos de anclaje del canal
   datetime date[];
   double   price[];
//--- asignación de la memoria
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- llenamos el array de datos
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
      return;
     }
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- definimos puntos para trazar el canal
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int d3=InpDate3*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
   int p2=InpPrice2*(accuracy-1)/100;
   int p3=InpPrice3*(accuracy-1)/100;
//--- creamos el canal equidistante
   if(!ChannelCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],InpColor,
      InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
     {
      return;
     }
//--- redibujamos el gráfico y esperamos 1 segundo
   ChartRedraw();
   Sleep(1000);
//--- ahora vamos a mover los puntos de anclaje del canal
//--- contador del ciclo
   int h_steps=bars/6;
//--- movemos el segundo punto de anclaje
   for(int i=0;i<h_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(d2<bars-1)
         d2+=1;
      //--- movemos el punto
      if(!ChannelPointChange(0,InpName,1,date[d2],price[p2]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,05 segundo
      Sleep(50);
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- movemos el primer punto de anclaje
   for(int i=0;i<h_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(d1>1)
         d1-=1;
      //--- movemos el punto
      if(!ChannelPointChange(0,InpName,0,date[d1],price[p1]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,05 segundo
      Sleep(50);
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- contador del ciclo
   int v_steps=accuracy/10;
//--- movemos el tercer punto de anclaje
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(p3>1)
         p3-=1;
      //--- movemos el punto
      if(!ChannelPointChange(0,InpName,2,date[d3],price[p3]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- eliminamos el canal desde el gráfico
   ChannelDelete(0,InpName);
   ChartRedraw();
//--- retardo de 1 segundo
   Sleep(1000);
//---
  }

Esta base la vi en la página de mql5, pero no entiendo respecto a los porcentajes de fecha y precio, no se donde introducir los valores de la MA, ni como definir los tiempos para que los puntos de anclaje sean una, dos y tres velas anteriores a la actual vela. Además al compilar el código me sale un error respecto a que la variable "i" ya fue definida antes. En el primer comentario colocaré el código que encontré.

Jesus Victor Lerga Bezunartea 2020.10.03 08:39 #1

No entiendo muy bien lo que quieres hacer....

Pero el error de i te da por que en los dos bucles for tienes "int i"

Debes definir la variable al comienzo de la función: "int i;" y después en los for utilizar "for i=....."

Cualquier pregunta de los [ARCHIVO] Cualquier pregunta de Preguntas de los principiantes

Juan David Rendon 2020.10.05 16:28 #2

Jesus Victor Lerga Bezunartea:

No entiendo muy bien lo que quieres hacer....

Pero el error de i te da por que en los dos bucles for tienes "int i"

Debes definir la variable al comienzo de la función: "int i;" y después en los for utilizar "for i=....."

Hola Jesús, la idea que tengo es la de crear un indicador que vaya creando con cada vela un canal equidistante, este canal equidistante debe crearse a partir de los valores de una SMA. O sea, se sabe que un canal equidistante tiene dos coordenadas de donde se crea, supongamos dos valores mínimos del precio en distantes momentos, y una tercer coordenada define la distancia de las líneas o la altura del canal, supongamos un valor máximo del precio en determinado rango ¿cierto?. Entonces lo que quiero es digamos:

//Estos serían los puntos del primer y segundo punto del canal equidistante

SMAPoint1 = iMA(NULL, 0, 10, 0, MODE_SMA, PRICE_COSE, i+3);

SMAPoint2 = iMA(NULL, 0, 10, 0, MODE_SMA, PRICE_COSE, i+1);

//Este sería el punto que definiría la distancia de las líneas

PointDistance = 50 (puntos o pips, la verdad no se como se definiría acá)

¿Es posible encontrar programáticamente Cualquier pregunta de novato, Voy a escribir el

Enrique Enguix 2020.10.05 17:55 #3

Juan David Rendon:

//Estos serían los puntos del primer y segundo punto del canal equidistante

SMAPoint1 = iMA(NULL, 0, 10, 0, MODE_SMA, PRICE_COSE, i+3);

SMAPoint2 = iMA(NULL, 0, 10, 0, MODE_SMA, PRICE_COSE, i+1);

//Este sería el punto que definiría la distancia de las líneas

PointDistance = 50 (puntos o pips, la verdad no se como se definiría acá)

//+------------------------------------------------------------------+
//|                         Modificación para Foro indicador RVM.mq4 |
//|                  Copyright 2020, MetaQuotes Software Corp. Envex |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp. Envex"
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
#include <stdlib.mqh>
#include <stderror.mqh>

//--- indicator settings
#property indicator_chart_window
#property indicator_buffers 3

#property indicator_type1 DRAW_LINE
#property indicator_style1 STYLE_SOLID
#property indicator_width1 2
#property indicator_color1 clrBlue
#property indicator_label1 "Neutral"

#property indicator_type2 DRAW_LINE
#property indicator_style2 STYLE_SOLID
#property indicator_width2 2
#property indicator_color2 clrRed
#property indicator_label2 "Sell"

#property indicator_type3 DRAW_LINE
#property indicator_style3 STYLE_SOLID
#property indicator_width3 2
#property indicator_color3 clrGreen
#property indicator_label3 "Buy"

//--- indicator buffers
double Buffer1[];
double Buffer2[];
double Buffer3[];

extern int MA_Period = 34;
extern int Distance=5;
extern color CenterLineColor= clrBlue;
extern color TopLineColor= clrRed;
extern color BottomLineColor= clrGreen;





double myPoint; //initialized in OnInit

void myAlert(string type, string message)
  {
   if(type == "print")
      Print(message);
   else if(type == "error")
     {
      Print(type+" | Canal TMA @ "+Symbol()+","+IntegerToString(Period())+" | "+message);
     }
   else if(type == "order")
     {
     }
   else if(type == "modify")
     {
     }
  }

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {   
   IndicatorBuffers(3);
   SetIndexStyle(0,DRAW_LINE,indicator_style1,indicator_width1,CenterLineColor);
   SetIndexBuffer(0, Buffer1);
   SetIndexEmptyValue(0, EMPTY_VALUE);
   
   SetIndexStyle(1,DRAW_LINE,indicator_style2,indicator_width2,TopLineColor);
   SetIndexBuffer(1, Buffer2);
   SetIndexEmptyValue(1, EMPTY_VALUE);
   
   SetIndexBuffer(2, Buffer3);
   SetIndexStyle(2,DRAW_LINE,indicator_style3,indicator_width3,BottomLineColor);
   SetIndexEmptyValue(2, EMPTY_VALUE);
   //initialize myPoint
   myPoint = Point();
   if(Digits() == 5 || Digits() == 3)
     {
      myPoint *= 10;
     }
   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime& time[],
                const double& open[],
                const double& high[],
                const double& low[],
                const double& close[],
                const long& tick_volume[],
                const long& volume[],
                const int& spread[])
  {
   int limit = rates_total - prev_calculated;
   //--- counting from 0 to rates_total
   ArraySetAsSeries(Buffer1, true);
   ArraySetAsSeries(Buffer2, true);
   ArraySetAsSeries(Buffer3, true);
   //--- initial zero
   if(prev_calculated < 1)
     {
      ArrayInitialize(Buffer1, 0);
      ArrayInitialize(Buffer2, 0);
      ArrayInitialize(Buffer3, 0);
     }
   else
      limit++;
   
   //--- main loop
   for(int i = limit-1; i >= 0; i--)
     {
      if (i >= MathMin(5000-1, rates_total-1-50)) continue; //omit some old rates to prevent "Array out of range" or slow calculation   
      
      //Indicator Buffer 1
      if(true //no conditions!
      )
        {
         Buffer1[i] = iMA(NULL, PERIOD_CURRENT, MA_Period, 0, MODE_SMA, PRICE_CLOSE, i); 
        }
      
      
        {
         Buffer2[i] = Buffer1[i] + Distance*myPoint; 
        }
      
 
        {
         Buffer3[i] = Buffer1[i] - Distance*myPoint; 
        }
      
     }
   return(rates_total);
  }
//+-----------------------------------

Esta es una modificación rápida de un indicador que tengo hecho, pruébalo a ver si es lo que quieres. Por cierto, esto es para MT4, no he encontrado si has dicho en algún sitio si querías MT4 o MT5

Preguntas de los principiantes MakeGrid Un tema para los

Juan David Rendon 2020.10.09 13:27 #4

Enrique Enguix Vino:

Hola Enrique, agradezco tu aporte, me temo que no es lo que quiero. Dejaré una imagen para mostrar a que me refiero con canal equidistante.

Canal equidistante

https://www.metatrader5.com/i/help/terminal/en/equidistant_channel.png

Enrique Enguix 2020.10.09 17:15 #5

Juan David Rendon:

Hola Enrique, agradezco tu aporte, me temo que no es lo que quiero. Dejaré una imagen para mostrar a que me refiero con canal equidistante.

https://www.metatrader5.com/i/help/terminal/en/equidistant_channel.png

AAAAh, de acuerdo, lo entendí mal entonces, no había visto la imagen

Nuevo comentario