Coordenadas de tiempo y precio

Para los objetos de los tipos que existen en el sistema de coordenadas de las cotizaciones, la API de MQL5 admite un par de propiedades para especificar las vinculaciones de tiempo y precio. En caso de que un objeto tenga varios puntos de anclaje, las propiedades requieren la especificación de un parámetro modificador que contenga el índice del punto de anclaje al llamar a las funciones ObjectSet y ObjectGet.

Identificador	Descripción	Tipo de valor
OBJPROP_TIME	Coordenada de tiempo	datetime
OBJPROP_PRICE	Coordenada de precio	double

Estas propiedades están disponibles para absolutamente todos los objetos, pero no tiene sentido establecerlas o leerlas para objetos con coordenadas de pantalla.

Para demostrar cómo trabajar con coordenadas, analicemos el indicador sin búfer ObjectHighLowChannel.mq5, que dibuja dos líneas de tendencia para un determinado segmento de barras. Sus puntos de comienzo y fin en el eje temporal coinciden con la primera y la última barra del segmento, y a lo largo del eje de precios, los valores se calculan de forma diferente para cada una de las líneas: para la línea superior se utilizan los precios High más alto y más bajo, y para la línea inferior, los precios Low más alto y más bajo. A medida que el gráfico se actualice, nuestro improvisado canal debería moverse con los precios.

El rango de barras se establece mediante dos variables de entrada: el número de la barra inicial BarOffset y el número de barras BarCount. Por defecto, las líneas se trazan a los precios más recientes, ya que bar offset = 0.

input int BarOffset = 0;
input int BarCount = 10;

const string Prefix = "HighLowChannel-";

Los objetos tienen el prefijo de nombre común «HighLowChannel-».

En el manejador OnCalculate supervisamos la aparición de nuevas barras sobre la hora iTime de la barra 0-ésima. En cuanto se forma la barra, se analizan los precios en el segmento especificado, se toman los valores máximo y mínimo de los precios de cada uno de los dos tipos (MODE_HIGH, MODE_LOW) y se llama a la función auxiliar DrawFigure para ellos, y aquí es donde tiene lugar el trabajo con los objetos: la creación y modificación de coordenadas.

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const int begin,
                const double &price[])
{
   static datetime now = 0;
   if(now != iTime(NULL, 0, 0))
   {
      const int hh = iHighest(NULL, 0, MODE_HIGH, BarCount, BarOffset);
      const int lh = iLowest(NULL, 0, MODE_HIGH, BarCount, BarOffset);
      const int ll = iLowest(NULL, 0, MODE_LOW, BarCount, BarOffset);
      const int hl = iHighest(NULL, 0, MODE_LOW, BarCount, BarOffset);

      datetime t[2] = {iTime(NULL, 0, BarOffset + BarCount), iTime(NULL, 0, BarOffset)};
      double ph[2] = {iHigh(NULL, 0, fmax(hh, lh)), iHigh(NULL, 0, fmin(hh, lh))};
      double pl[2] = {iLow(NULL, 0, fmax(ll, hl)), iLow(NULL, 0, fmin(ll, hl))};

      DrawFigure(Prefix + "Highs", t, ph, clrBlue);
      DrawFigure(Prefix + "Lows", t, pl, clrRed);

      now = iTime(NULL, 0, 0);
   }
   return rates_total;
}

Y aquí está la función DrawFigure propiamente dicha:

bool DrawFigure(const string name, const datetime &t[], const double &p[],
   const color clr)
{
   if(ArraySize(t) != ArraySize(p)) return false;

   ObjectCreate(0, name, OBJ_TREND, 0, 0, 0);

   for(int i = 0; i < ArraySize(t); ++i)
   {
      ObjectSetInteger(0, name, OBJPROP_TIME, i, t[i]);
      ObjectSetDouble(0, name, OBJPROP_PRICE, i, p[i]);
   }

   ObjectSetInteger(0, name, OBJPROP_COLOR, clr);
   return true;
}

Después de la llamada a ObjectCreate que garantiza la existencia de un objeto, se llama a las funciones ObjectSet apropiadas para OBJPROP_TIME y OBJPROP_PRICE en todos los puntos de anclaje (dos en este caso).

En la imagen siguiente se muestra el resultado del indicador:

Canal en dos líneas de tendencia a precios máximos y mínimos

Puede ejecutar el indicador en el probador visual para ver cómo cambian las coordenadas de la línea sobre la marcha.

Propiedades principales de los objetos

Anclar la esquina de la ventana y las coordenadas de la pantalla