Expert Advisors: Download all ticks of a symbol's history

Neuer Kommentar
 

Download all ticks of a symbol's history:

Laden Sie alle Ticks von Ihrem Broker für alle Symbole in der Marktbeobachtung herunter. Laden Sie die gesamte Historie oder bis zu einem bestimmten Datum in der Vergangenheit herunter, falls verfügbar.

Author: Lorentzos Roussos

 

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Библиотеки: MultiTester

fxsaber, 2020.01.25 12:39

Der bequemste Weg, um die Tick-Historie herunterzuladen (führen Sie den Advisor im Terminal aus).

#property description "Закачивает тики через Тестер."

sinput datetime inFromDate = D'2019.01.01'; // С какой даты закачать тики
sinput bool inAllSymbols = false;           // По всем символам (wahr) или текущему (falsch)

#include <fxsaber\MultiTester\MTTester.mqh> // https://www.mql5.com/ru/code/26132

string PrevTesterSettings = NULL;

string GetMyName( void )
{
  return(StringSubstr(MQLInfoString(MQL_PROGRAM_PATH), StringLen(TerminalInfoString(TERMINAL_DATA_PATH) + "\\MQL5\\Experts\\")));
}

bool RunMe( const datetime FromDate, const bool AllSymbols = false )
{
  const string Str = "[Tester]" +
                     "\nExpert=" + GetMyName() +
                     "\nSymbol=" + _Symbol +
                     "\nOptimization=" + (AllSymbols ? "3" : "0") +
                     "\nModel=4" +
                     "\nFromDate=" + TimeToString(FromDate, TIME_DATE) +
                     "\nToDate=" + TimeToString(TimeCurrent(), TIME_DATE) +
                     "\nForwardMode=0" +
                     "\nProfitInPips=1" +
                     "\nOptimizationCriterion=0" +
                     "\nVisual=0";
                     
  return(MTTESTER::SetSettings2(Str) && MTTESTER::ClickStart());
}

int OnInit()
{
  bool Res = !MQLInfoInteger(MQL_TESTER) && EventSetTimer(1);

  if (Res = Res && MTTESTER::GetSettings(PrevTesterSettings))
    if (!(Res = RunMe(inFromDate, inAllSymbols)))
      MTTESTER::SetSettings2(PrevTesterSettings);

  return(Res ? INIT_SUCCEEDED : INIT_FAILED);
}

void OnTimer()
{
  if (MTTESTER::IsReady())
  {
    MTTESTER::SetSettings2(PrevTesterSettings);
    
    if (inAllSymbols)
      MTTESTER::CloseNotChart();

    ExpertRemove();
  }
}


Danach können Sie Skripte im Terminal ausführen, die mit Ticks arbeiten, und nicht eine lange Zeit ohne Lebenszeichen warten.

 
fxsaber #:

Schön, danke

Es hing manchmal beim Herunterladen und das "Stapeln" und "Hoffen" um die Diagramme scheint das Problem zu lösen, da die Anfrage zu groß für den Server war, denke ich.
Neuer Kommentar