Stochastic oscillator differenz berrechnen

[Gspandelino1410]

Hallo zusammen ich habe folgende fragen. Beim Stochastic Oscillator(16,6,3) gibt es ja zwei Linien die K% Periode und D% Periode ich wollte fragen ob es möglich ist die Differenz zwischen diesen Perioden berrechnen. Damit meine ich im Chart sind diese beiden als zwei Linien gekennzeichnet kann man die Differenz dieser beiden zueinander berrechnen ?

Ich hoffe jemand kann mir das kurz im Code zeigen. Ich danke für die Mühe =)

[Otto Pauser]

Hi,

ich hab das mal als kleinen EA geproggt.

//+------------------------------------------------------------------+
//|                                                    StochDiff.mq5 |
//|                                Copyright © 2017 Ing. Otto Pauser |
//|                                          http://www.spider4x.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2017 Ing. Otto Pauser"
#property link      "http://www.spider4x.com"
#property version   "1.00"

input    int            inp_Kperiod =  5;             // %K Periode
input    int            inp_Dperiod =  3;             // %D Periode
input    int            inp_slowing =  3;             // Verlangsamung
input    ENUM_MA_METHOD inp_method  = MODE_SMA;       // Methode
input    ENUM_STO_PRICE inp_pricef  = STO_LOWHIGH;    // Preisbereich

int      haStoch;    // handle für iStochastik
double   prozD[1],   // statischer buffer für %D
         prozK[1];   // statischer buffer für %K
double   delta;

int OnInit()
{
   haStoch=iStochastic(_Symbol,_Period,inp_Kperiod,inp_Dperiod,inp_slowing,inp_method,inp_pricef);       // handle iStochastik erstellen
   if(haStoch==INVALID_HANDLE)                                                                           // ErrCheck
      {
         MessageBox("*ERROR* creating handle iStochastic",MQLInfoString(MQL_PROGRAM_NAME),MB_ICONERROR); // Info
         return(INIT_FAILED);                                                                            // da ging was schief
      }
   return(INIT_SUCCEEDED);                                                                               // alles OK
}

void OnDeinit(const int reason)
{
   IndicatorRelease(haStoch);       // handle freigeben (nicht unbedingt erforderlich, sind aber gute Sitten)
}

void OnTick()
{
   if(CopyBuffer(haStoch,0,0,1,prozK)!=1) return;     // Werte aus Buffern holen
   if(CopyBuffer(haStoch,1,0,1,prozD)!=1) return;
   delta=prozK[0]-prozD[0];                           // berechnen
   Comment("Stochastik Differenz %K-%D: ",DoubleToString(delta,2));
}

Viel Erfolg damit

Siehe auch http://www.expert-advisor.com/forum/metatrader-5/programmierung-mql5/codeschnipsel/5899-stochastik-differenz-k-d-berechnen-und-anzeigen.html#post39943

[Gspandelino1410]

Otto Pauser:

Hi,

ich hab das mal als kleinen EA geproggt.

Viel Erfolg damit

Siehe auch http://www.expert-advisor.com/forum/metatrader-5/programmierung-mql5/codeschnipsel/5899-stochastik-differenz-k-d-berechnen-und-anzeigen.html#post39943

Wow danke viel mal Otto Pauser das ist Genial und eine grosse Hilfe ich danke dir vielmals =)

[Gspandelino1410]

Hallo Otto Pauser ich habe erst jetzt gesehen das das Script in MQL5 ist. Ich bin aber zurzeit an einem MQL4 Programm dran wenn es dir nicht zu viel Mühe macht wie muss ich das Script für MQL4 ändern ?

//+------------------------------------------------------------------+
//|                                                    StochDiff.mq5 |
//|                                Copyright © 2017 Ing. Otto Pauser |
//|                                          http://www.spider4x.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2017 Ing. Otto Pauser"
#property link      "http://www.spider4x.com"
#property version   "1.00"

input    int            inp_Kperiod =  5;             // %K Periode
input    int            inp_Dperiod =  3;             // %D Periode
input    int            inp_slowing =  3;             // Verlangsamung
input    ENUM_MA_METHOD inp_method  = MODE_SMA;       // Methode
input    ENUM_STO_PRICE inp_pricef  = STO_LOWHIGH;    // Preisbereich

int      haStoch;    // handle für iStochastik
double   prozD[1],   // statischer buffer für %D
         prozK[1];   // statischer buffer für %K
double   delta;

int OnInit()
{
   haStoch=iStochastic(_Symbol,_Period,inp_Kperiod,inp_Dperiod,inp_slowing,inp_method,inp_pricef);       // handle iStochastik erstellen
   if(haStoch==INVALID_HANDLE)                                                                           // ErrCheck
      {
         MessageBox("*ERROR* creating handle iStochastic",MQLInfoString(MQL_PROGRAM_NAME),MB_ICONERROR); // Info
         return(INIT_FAILED);                                                                            // da ging was schief
      }
   return(INIT_SUCCEEDED);                                                                               // alles OK
}

void OnDeinit(const int reason)
{
   IndicatorRelease(haStoch);       // handle freigeben (nicht unbedingt erforderlich, sind aber gute Sitten)
}

void OnTick()
{
   if(CopyBuffer(haStoch,0,0,1,prozK)!=1) return;     // Werte aus Buffern holen
   if(CopyBuffer(haStoch,1,0,1,prozD)!=1) return;
   delta=prozK[0]-prozD[0];                           // berechnen
   Comment("Stochastik Differenz %K-%D: ",DoubleToString(delta,2));
}