Kütüphaneler: HistoryLoader

Yeni yorum
 

HistoryLoader:

Sorgu sonucunun işlenmesi ile herhangi bir geçmiş veriye erişimi düzenlemek için Çoklu Para Birimi Uzman Danışmanı işlevsel modülü.

Author: Nikolay Kositsin

 
Automated-Trading:

HistoryLoader:

Yazar: Nikolay Kositsin

Satır 91'de sözdizimi hatası (eksik H)."SERIES_SYNCRONIZED" ifadesi "SERIES_SYNCHRONIZED"şeklinde olmalıdır.
 
elib:
Satır 91'de sözdizimi hatası (eksik H)."SERIES_SYNCRONIZED", "SERIES_SYNCHRONIZED"olmalıdır.

Ayın altında hiçbir şey sonsuza kadar sürmez!

//+------------------------------------------------------------------+
//| yükleme için geçmişi kontrol etme|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- sembol ve noktayı kontrol et
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- MarketWatch'ta sembolün seçili olup olmadığını kontrol edin
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Karakter eklenemedi ",symbol,"MarketWatch penceresinde!!!");
     }
//--- verinin mevcut olup olmadığını kontrol edin
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- eğer bir gösterge ise kendi verilerinin yüklenmesini istemeyin
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- ikinci deneme
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- zaman serileri oluşturmak için yüklenmiş veri var
      if(first_date>0)
        {
         //--- zaman serisi oluşturmaya zorla
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- kontrol tarihi
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- terminal seçeneklerinden grafikteki maksimum çubuklar
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- sembol geçmişi bilgilerini yükle
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- yükleme için başlangıç tarihini düzeltin
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- verileri adım adım yükle
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- zaman serisinin oluşturulmasını bekleyin
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- inşa edilmiş çubukları isteyin
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- ilk buluşma için sor
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- sonraki parçanın kopyalanması veri yüklemesini zorlar
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- veri olup olmadığını kontrol edin
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- en fazla 100 başarısız deneme
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+
 

Çalışmıyor, ilk karakterde ölüyor....

İşte kod

//+------------------------------------------------------------------+ 
//|TestLoadHistory.mq5 | 
//| Telif Hakkı 2009, MetaQuotes Software Corp. | | 
//| https://www.mql5.com | 
//+------------------------------------------------------------------+ 
#property copyright "2009, MetaQuotes Software Corp." 
#property link      "https://www.mql5.com" 
#property version   "1.02" 
#property script_show_inputs 

//--- giriş parametreleri 

//+------------------------------------------------------------------+ 
//| Komut dosyası programı başlatma işlevi| 
//+------------------------------------------------------------------+ 
void OnStart()
  {


   int      all_symbols=SymbolsTotal(false);   string  sym_name="";
   Print("Load symbols ",all_symbols);

   for(int k=0;k<all_symbols;k++)
      if((sym_name=SymbolName(k,false))!="")
        {
         SymbolSelect(sym_name,true);

         Print(k," Symbol name ",sym_name);

datetime time= (TimeCurrent()-60*60*24*5);


         int res=CheckLoadHistory(sym_name,PERIOD_M1,time);

         switch(res)
           {
            case -1 : Print("Unknown symbol ",sym_name);             break;
            case -2 : Print("Requested bars more than max bars in chart ",sym_name); break;
            case -3 : Print("Program was stopped ",sym_name);                        break;
            case -4 : Print("Indicator shouldn't load its own data ",sym_name);      break;
            case -5 : Print("Load failed ",sym_name);                                break;
            case  0 : Print("Loaded OK ",sym_name);                                  break;
            case  1 : Print("Loaded previously ",sym_name);                          break;
            case  2 : Print("Loaded previously and built ",sym_name);                break;
            default : Print("Unknown result ",sym_name);
           }

         datetime first_date;
         SeriesInfoInteger(sym_name,PERIOD_M1,SERIES_FIRSTDATE,first_date);
         int bars=Bars(sym_name,PERIOD_M1);
         Print("First date ",first_date," - ",bars," bars");
       }
//--- 

//--- 
  }
//+------------------------------------------------------------------+
//| yükleme için geçmişi kontrol etme|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- sembol ve noktayı kontrol et
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- MarketWatch'ta sembolün seçili olup olmadığını kontrol edin
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Karakter eklenemedi ",symbol,"MarketWatch penceresinde!!!");
     }
//--- verinin mevcut olup olmadığını kontrol edin
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- eğer bir gösterge ise kendi verilerinin yüklenmesini istemeyin
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- ikinci deneme
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- zaman serileri oluşturmak için yüklenmiş veri var
      if(first_date>0)
        {
         //--- zaman serisi oluşturmaya zorla
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- kontrol tarihi
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- terminal seçeneklerinden grafikteki maksimum çubuklar
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- sembol geçmişi bilgilerini yükle
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- yükleme için başlangıç tarihini düzeltin
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- verileri adım adım yükle
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- zaman serisinin oluşturulmasını bekleyin
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- inşa edilmiş çubukları isteyin
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- ilk buluşma için sor
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- sonraki parçanın kopyalanması veri yüklemesini zorlar
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- veri olup olmadığını kontrol edin
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- en fazla 100 başarısız deneme
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+

ve burada ölür

while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
 

Merhaba Nikolay

Historyloader.mqh yalnızca

int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)

bahsedildiği gibi Loadhistory() işlevi yoktur.
 
Nikolay Kositsin:

Ayın altında hiçbir şey sonsuza kadar sürmez!

Çok teşekkürler, benim için çalışıyor!

Yeni yorum