Советники: Программирование на MQL5 для трейдеров — исходные коды из книги. Часть 6 - страница 3

[Alain Verleyen]

hini #property tester_set "FrameTransfer.set" (недопустимое расширение файла набора тестера, '*.set' ожидается FrameTransfer.mq5)

Для успешной компиляции его нужно изменить следующим образом: #property tester_set "\\Presets\\FrameTransfer.set"

Даже `#property tester_set "/Presets/FrameTransfer.set"` будет неудачным.

Возможно, вы могли бы изменить описание в книге алгоритмов:

Исправление доступно в сборке 5506.

[hini]

Alain Verleyen #:
Исправление доступно в сборке 5506.

Спасибо.

[Stanislav Korotky]

Stanislav Korotky #:

Прикладываю обновленную версию файла расчета кастом-критерия оптимизации на основе R2 - RSquared.mqh, в которой поправлен расчет для случая переменных лотов.

Значительно улучшено качество оценки - судя по таблице результатов оптимизации получилась комбинация параметров фактора восстановления и шарпа.

Пример использования.

Внимание! Если торгуются разные символы, для получения адекватной оценки объемов нужно их переводить из лотов в стоимость в валюте депозита, например (один из упрощенных вариантов):

#include <MQL5Book/DealFilter.mqh>
#include <MQL5Book/RSquared.mqh>

template<typename T>
union Type2Bytes
{
   T d;
   uchar bytes[sizeof(T)];
};

double OnTester()
{
   HistorySelect(0, LONG_MAX);
   
   #define  STAT_PROPS 5
   
   const ENUM_DEAL_PROPERTY_DOUBLE props[STAT_PROPS] =
   {
      DEAL_PROFIT, DEAL_SWAP, DEAL_COMMISSION, DEAL_FEE, DEAL_VOLUME
   };
   double expenses[][STAT_PROPS];
   ulong tickets[]; // used here only to match 'select' prototype, but useful for debug
   
   DealFilter filter;
   filter.let(DEAL_TYPE, (1 << DEAL_TYPE_BUY) | (1 << DEAL_TYPE_SELL), IS::OR_BITWISE)
      .let(DEAL_ENTRY, (1 << DEAL_ENTRY_OUT) | (1 << DEAL_ENTRY_INOUT) | (1 << DEAL_ENTRY_OUT_BY), IS::OR_BITWISE)
      .select(props, tickets, expenses);

   const int n = ArraySize(tickets);
   
   double balance[];
   double volumes[]; // take trade volumes into account for using R2 criterion
   
   ArrayResize(balance, n + 1);
   balance[0] = 0;
   ArrayResize(volumes, n + 1);
   volumes[0] = 0;

   MapArray<ulong,double> sym2value; // symbol hash to 1 lot value
   
   for(int i = 0; i < n; ++i)
   {
      const string s = HistoryDealGetString(tickets[i], DEAL_SYMBOL);

      double value = 1;
      Type2Bytes<ulong> sym;
      ArrayInitialize(sym.bytes, 0);
      StringToCharArray(s, sym.bytes);
      int idx = sym2value.find(sym.d);
      if(idx == -1) // no record yet for symbol value per lot
      {
         const double price = SymbolInfoDouble(s, SYMBOL_ASK);
         const double pt = SymbolInfoDouble(s, SYMBOL_POINT);
         double profit = 1;
         ResetLastError();
         if(!OrderCalcProfit(ORDER_TYPE_BUY, s, 1, price, price + pt, profit)) // NB: estimated approximately, because it uses current rate for account currency
         {
            // WARN(StringFormat("OrderCalcProfit Error: %s %d ", s, _LastError));
         }
         value = profit * (price / pt); // NB: leverage is not applied here
         idx = sym2value.put(sym.d, value);
      }
      else
      {
         value = sym2value.getValue(idx);
      }
   
      double result = 0;
      for(int j = 0; j < STAT_PROPS - 1; ++j) // loop through all requested props except for deal volume
      {
         result += expenses[i][j];
      }
      // use volumes as a model - more investments - more returns expected
      volumes[i + 1] = expenses[i][STAT_PROPS - 1] * value + volumes[i];
      balance[i + 1] = result + balance[i];
   }
   
   const double r2 = RSquaredTest(balance, volumes);
   
   #undef  STAT_PROPS
   
   return r2 * 100;
}

Желтым помечено то, что потребовалось добавить по сравнению с расчетом торговли одним символом (из предыдущего примера).

[Stanislav Korotky]

Stanislav Korotky #:

Исправление MQL5/Include/MQL5Book/TradeUtils.mqh.

Еще одно связанное исправление (в методе NormalizeLot ):

const double newLotsRounded = MathFloor(nlot * (1 + DBL_EPSILON) / stepLot) * stepLot;