Вылетает ошибка invalid price

Fresto 2017.07.12 11:42 #11

Vladimir Karputov:

А какое значение возвращает метод TickSize по данному символу? 10 или 1?

10. У инструмента RTS цены кратны 10.

Vladimir Karputov 2017.07.12 12:34 #12

Fresto:

10. У инструмента RTS цены кратны 10.

Нет, Вы проверьте по склейке, а не по RTS.

Fresto 2017.07.12 12:40 #13

Vladimir Karputov:

Нет, Вы проверьте по склейке, а не по RTS.

Да, там тоже написано 10.

Vladimir Karputov 2017.07.12 12:48 #14

Fresto:

Да, там тоже написано 10.

А какое значение возвращает метод TickSize по данному символу? 10 или 1?

Vladimir Karputov 2017.07.12 13:36 #15

Не понимаю, как Вы при использовании метода NormalizePrice класса CSymbolInfo получаете на данном символе в SL и TP цены оканчивающиеся не "0"? У Вас там и "1" и "9".

Второе: поставьте такие принты:

//+------------------------------------------------------------------+
//| Open Buy position                                                |
//+------------------------------------------------------------------+
void OpenBuy(double lot,double sl,double tp)
  {
   sl=m_symbol.NormalizePrice(sl);
   tp=m_symbol.NormalizePrice(tp);

   double volume=LotCheck(lot);
   if(volume==0.0)
      return;
//--- check volume before OrderSend to avoid "not enough money" error (CTrade)
   double check_volume_lot=m_trade.CheckVolume(m_symbol.Name(),volume,m_symbol.Ask(),ORDER_TYPE_BUY);

   if(check_volume_lot!=0.0)
      if(check_volume_lot>=volume)
        {
         if(m_trade.Buy(volume,NULL,m_symbol.Ask(),sl,tp))
           {
            if(m_trade.ResultDeal()==0)
              {
               Print("Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription(),
                     ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                     ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                     ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
              }
            else
              {
               Print("Buy -> true. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription(),
                     ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                     ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                     ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
              }
           }
         else
           {
            Print("Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),
                  ", description of result: ",m_trade.ResultRetcodeDescription(),
                  ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                  ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                  ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
           }
        }
//---
  }
//+------------------------------------------------------------------+
//| Open Sell position                                               |
//+------------------------------------------------------------------+
void OpenSell(double lot,double sl,double tp)
  {
   sl=m_symbol.NormalizePrice(sl);
   tp=m_symbol.NormalizePrice(tp);

   double volume=LotCheck(lot);
   if(volume==0.0)
      return;
//--- check volume before OrderSend to avoid "not enough money" error (CTrade)
   double check_volume_lot=m_trade.CheckVolume(m_symbol.Name(),volume,m_symbol.Bid(),ORDER_TYPE_SELL);

   if(check_volume_lot!=0.0)
      if(check_volume_lot>=volume)
        {
         if(m_trade.Sell(volume,NULL,m_symbol.Bid(),sl,tp))
           {
            if(m_trade.ResultDeal()==0)
              {
               Print("Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription(),
                     ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                     ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                     ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
              }
            else
              {
               Print("Sell -> true. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription(),
                     ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                     ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                     ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
              }
           }
         else
           {
            Print("Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),
                  ", description of result: ",m_trade.ResultRetcodeDescription(),
                  ", Bid: ",DoubleToString(m_symbol.Bid(),m_symbol.Digits()),
                  ", Ask: ",DoubleToString(m_symbol.Ask(),m_symbol.Digits()),
                  ", Last: ",DoubleToString(m_symbol.Last(),m_symbol.Digits()));
           }
        }
//---
  }

Ошибки возникают, когда: цена открытия позиция не совпадает в ценой Last и при этом Last равен стопу (SL или TP).

TrailStop барахлит Помощь в кодировании Invalid Price

Fresto 2017.07.13 08:06 #16

Так, у меня выводило в итоге любые числа при NormalizePrice. Сам не пойму, почему. В итоге полностью все ошибки ушли только при самостоятельном расчете чисел, относительно TickSize. Не знаю, в чем могут быть причины.

mysymbol.Name("RTS Splice");
double tickSize = mysymbol.TickSize();

stloss = mysymbol.NormalizePrice(mysymbol.Ask() + (int)(Stop/tickSize)*tickSize); //--- Stop Loss
tprofit = mysymbol.NormalizePrice(mysymbol.Ask() - (int)(Stop * StTkDiff/tickSize)*tickSize);
stopPrice = mysymbol.NormalizePrice(mysymbol.Ask() - (int)(Stop/tickSize)*tickSize);

P.s. две функции добавлю, спасибо, если будут ошибки, я сюда еще отпишу. Но все ошибки полностью прошли с помощью данной манипуляции.

Советники: Торговый ТРЕНАЖЕР 2 Вопросы от начинающих MQL5 Не отображаются правильно цифры

Aleksey Vyazmikin 2017.07.20 07:38 #17

Так должен или нет советник в тестере работать на склейках?

Fresto 2017.07.27 08:39 #18

Aleksey Vyazmikin:

Так должен или нет советник в тестере работать на склейках?

Должен, всё нормально) Просто для RTS почему-то получение цены покупки, sl и tp высчитывается, лично у меня, по-другому)

Aleksey Vyazmikin 2017.07.27 08:41 #19

Fresto:

Должен, всё нормально) Просто для RTS почему-то получение цены покупки, sl и tp высчитывается, лично у меня, по-другому)

Это как, по-другому?

Fresto 2017.07.31 09:15 #20

Aleksey Vyazmikin:

Это как, по-другому?

stloss = mysymbol.NormalizePrice(mysymbol.Ask() + (int)(Stop/tickSize)*tickSize); //--- Stop Loss

Stop = оптимизируемое число. Такая штука нормализует стоп по цене. Я слишком намучился со всем, что после данного костыля у меня всё заработало и я ничего просто не трогаю больше)

Вылетает ошибка invalid price - страница 2