Алексей Тарабанов 2014.09.10 22:50 #21

evillive:

Да добавлял я, и единичку, и больше, как это связано с отсутствием счёта?

Повторюсь, код тот же, что прекрасно работал в 482 и там нет ничего из тех примочек, которые мешали бы этому коду работать в новом билде...

Вот ошибка:

limit=Bars-IndicatorCounted();

  if (limit>0) limit=Bars-1;

Vitalie Postolache 2014.09.10 23:19 #22

tara:

Вот ошибка:

limit=Bars-IndicatorCounted();

и так, и так попробовал:

1.
  limit=Bars-IndicatorCounted();
  if (limit>0) limit=Bars-1;
2.  
  int counted_bars=IndicatorCounted();
  if(counted_bars>0) counted_bars--;
  limit=Bars-1-counted_bars;

всё равно в тестере не считает, да ещё первый вариант тормозит больше.

Vitalie Postolache 2014.09.11 00:18 #23

И ещё раз повторюсь - проблема обнаружена именно в тестере, в режиме визуализации. В реальном времени, похоже, всё работает.

Rashid Umarov 2014.09.11 05:10 #24

evillive:

Вот, например, этот - в 482 перерасчитывается нормально, сам, в 670 рисует такое, пока не стукнешь его по башке:

а вот этот мой, он просто прямые линии рисует с момента первого расчёта и до повторной компиляции (в билде 482 всё нормально перерасчитывается без дополнительных пинков или пляски с бубном):

В чем здесь проблема, рисуется без проблем? Код простой , добавляем распринтовку значения limit (выделено желтым)

Код

//+------------------------------------------------------------------+
//|                                                        Pivot.mq4 |
//|                               Copyright © 2004, Poul_Trade_Forum |
//|                                                         Aborigen |
//|                                          http://forex.kbpauk.ru/ |
//+------------------------------------------------------------------+
#property copyright "Poul Trade Forum"
#property link      "http://forex.kbpauk.ru/"
//----
#property indicator_chart_window
//#property indicator_separate_window
#property indicator_buffers 7
#property indicator_color1 Orange
#property indicator_color2 DarkBlue
#property indicator_color3 Maroon
#property indicator_color4 DarkBlue
#property indicator_color5 Maroon
#property indicator_color6 Green
#property indicator_color7 Green
//---- input parameters
//---- buffers
double PBuffer[];
double S1Buffer[];
double R1Buffer[];
double S2Buffer[];
double R2Buffer[];
double S3Buffer[];
double R3Buffer[];
string Pivot="Pivot Point",Sup1="S 1",Res1="R 1";
string Sup2="S 2",Res2="R 2",Sup3="S 3",Res3="R 3";
int fontsize=10;
double P,S1,R1,S2,R2,S3,R3;
double LastHigh,LastLow,x;
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- TODO: add your code here
   ObjectDelete("Pivot");
   ObjectDelete("Sup1");
   ObjectDelete("Res1");
   ObjectDelete("Sup2");
   ObjectDelete("Res2");
   ObjectDelete("Sup3");
   ObjectDelete("Res3");
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   string short_name;
//---- indicator line
   SetIndexStyle(0,DRAW_LINE,0,2,Orange);
   SetIndexStyle(1,DRAW_LINE,0,2,DarkBlue);
   SetIndexStyle(2,DRAW_LINE,0,2,Maroon);
   SetIndexStyle(3,DRAW_LINE,0,2,DarkBlue);
   SetIndexStyle(4,DRAW_LINE,0,2,Maroon);
   SetIndexStyle(5,DRAW_LINE,0,2,Green);
   SetIndexStyle(6,DRAW_LINE,0,2,Green);
   SetIndexBuffer(0,PBuffer);
   SetIndexBuffer(1,S1Buffer);
   SetIndexBuffer(2,R1Buffer);
   SetIndexBuffer(3,S2Buffer);
   SetIndexBuffer(4,R2Buffer);
   SetIndexBuffer(5,S3Buffer);
   SetIndexBuffer(6,R3Buffer);
//---- name for DataWindow and indicator subwindow label
   short_name="Pivot Point";
   IndicatorShortName(short_name);
   SetIndexLabel(0,short_name);
//----
   SetIndexDrawBegin(0,1);
//----
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int    counted_bars=IndicatorCounted();
   int limit,i;
   if(counted_bars<0) return(-1);
//---- indicator calculation
   if(counted_bars==0)
     {
      x=Period();
      if(x>240) return(-1);
      ObjectCreate("Pivot",OBJ_TEXT,0,0,0);
      ObjectSetText("Pivot","                 Pivot Point",fontsize,"Arial",Red);
      ObjectCreate("Sup1",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup1","      S 1",fontsize,"Arial",Red);
      ObjectCreate("Res1",OBJ_TEXT,0,0,0);
      ObjectSetText("Res1","      R 1",fontsize,"Arial",Red);
      ObjectCreate("Sup2",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup2","      S 2",fontsize,"Arial",Red);
      ObjectCreate("Res2",OBJ_TEXT,0,0,0);
      ObjectSetText("Res2","      R 2",fontsize,"Arial",Red);
      ObjectCreate("Sup3",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup3","      S 3",fontsize,"Arial",Red);
      ObjectCreate("Res3",OBJ_TEXT,0,0,0);
      ObjectSetText("Res3","      R 3",fontsize,"Arial",Red);
     }
   if(counted_bars>0) counted_bars--;
   limit=Bars-counted_bars;
   if(counted_bars==0) limit-=1+1;
   Print("limit=",limit);
//----   
   for(i=limit; i>=0;i--)
     {
      if(High[i+1]>LastHigh) LastHigh=High[i+1];
      if(Low[i+1]<LastLow) LastLow=Low[i+1];
      if(TimeDay(Time[i])!=TimeDay(Time[i+1]))
        {
         P=(LastHigh+LastLow+Close[i+1])/3;
         R1=(2*P)-LastLow;
         S1=(2*P)-LastHigh;
         R2=P+(LastHigh - LastLow);
         S2=P-(LastHigh - LastLow);
         R3=(2*P)+(LastHigh-(2*LastLow));
         S3=(2*P)-((2* LastHigh)-LastLow);
         LastLow=Open[i]; LastHigh=Open[i];
         //----
         ObjectMove("Pivot",0,Time[i],P);
         ObjectMove("Sup1",0,Time[i],S1);
         ObjectMove("Res1",0,Time[i],R1);
         ObjectMove("Sup2",0,Time[i],S2);
         ObjectMove("Res2",0,Time[i],R2);
         ObjectMove("Sup3",0,Time[i],S3);
         ObjectMove("Res3",0,Time[i],R3);
        }
      PBuffer[i]=P;
      S1Buffer[i]=S1;
      R1Buffer[i]=R1;
      S2Buffer[i]=S2;
      R2Buffer[i]=R2;
      S3Buffer[i]=S3;
      R3Buffer[i]=R3;
     }
//----
   return(0);
  }
//+------------------------------------------------------------------+

Видим, что расчеты всегда ведутся на 3-х последних барах

Boris 2014.09.11 05:53 #25

evillive:

да ещё хуже этот ваш DailyPivotPoints, а ещё также без толкача не считает на новых сутках.

Да всё считает, только программно в 00:00 удаляю объекты с первым тиком, и они тут же со следующим встают на свои новые места!

Vitalie Postolache 2014.09.11 08:15 #26

В который раз уже повторяю, специально для тех, кто упорно доказывает, что всё нормально - проблема обнаружена именно в тестере, в режиме визуализации. В реальном времени всё работает.

Rashid Umarov 2014.09.11 09:42 #27

Вот правильный вариант для работы режиме онлайн

//+------------------------------------------------------------------+
//|                                                        Pivot.mq4 |
//|                               Copyright © 2004, Poul_Trade_Forum |
//|                                                         Aborigen |
//|                                          http://forex.kbpauk.ru/ |
//+------------------------------------------------------------------+
#property copyright "Poul Trade Forum"
#property link      "http://forex.kbpauk.ru/"
//----
#property indicator_chart_window
//#property indicator_separate_window
#property indicator_buffers 7
#property indicator_color1 Orange
#property indicator_color2 DarkBlue
#property indicator_color3 Maroon
#property indicator_color4 DarkBlue
#property indicator_color5 Maroon
#property indicator_color6 Green
#property indicator_color7 Green
//---- input parameters
//---- buffers
double PBuffer[];
double S1Buffer[];
double R1Buffer[];
double S2Buffer[];
double R2Buffer[];
double S3Buffer[];
double R3Buffer[];
string Pivot="Pivot Point",Sup1="S 1",Res1="R 1";
string Sup2="S 2",Res2="R 2",Sup3="S 3",Res3="R 3";
int fontsize=10;
double P,S1,R1,S2,R2,S3,R3;
double LastHigh,LastLow,x;
int    LastDay,CurrDay;
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- TODO: add your code here
   ObjectDelete("Pivot");
   ObjectDelete("Sup1");
   ObjectDelete("Res1");
   ObjectDelete("Sup2");
   ObjectDelete("Res2");
   ObjectDelete("Sup3");
   ObjectDelete("Res3");
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   string short_name;
//---- indicator line
   SetIndexStyle(0,DRAW_LINE,0,2,Orange);
   SetIndexStyle(1,DRAW_LINE,0,2,DarkBlue);
   SetIndexStyle(2,DRAW_LINE,0,2,Maroon);
   SetIndexStyle(3,DRAW_LINE,0,2,DarkBlue);
   SetIndexStyle(4,DRAW_LINE,0,2,Maroon);
   SetIndexStyle(5,DRAW_LINE,0,2,Green);
   SetIndexStyle(6,DRAW_LINE,0,2,Green);
   SetIndexBuffer(0,PBuffer);
   SetIndexBuffer(1,S1Buffer);
   SetIndexBuffer(2,R1Buffer);
   SetIndexBuffer(3,S2Buffer);
   SetIndexBuffer(4,R2Buffer);
   SetIndexBuffer(5,S3Buffer);
   SetIndexBuffer(6,R3Buffer);
//---- name for DataWindow and indicator subwindow label
   short_name="Pivot Point";
   IndicatorShortName(short_name);
   SetIndexLabel(0,short_name);
//----
   SetIndexDrawBegin(0,1);
//----
   LastDay=-1;
   CurrDay=-2;
   LastHigh=0;
   LastLow=100000;
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int    counted_bars=IndicatorCounted();
   int limit,i;
   if(counted_bars<0) return(-1);
//---- indicator calculation
   if(counted_bars==0)
     {
      x=Period();
      if(x>240) return(-1);
      ObjectCreate("Pivot",OBJ_TEXT,0,0,0);
      ObjectSetText("Pivot","                 Pivot Point",fontsize,"Arial",Red);
      ObjectCreate("Sup1",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup1","      S 1",fontsize,"Arial",Red);
      ObjectCreate("Res1",OBJ_TEXT,0,0,0);
      ObjectSetText("Res1","      R 1",fontsize,"Arial",Red);
      ObjectCreate("Sup2",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup2","      S 2",fontsize,"Arial",Red);
      ObjectCreate("Res2",OBJ_TEXT,0,0,0);
      ObjectSetText("Res2","      R 2",fontsize,"Arial",Red);
      ObjectCreate("Sup3",OBJ_TEXT,0,0,0);
      ObjectSetText("Sup3","      S 3",fontsize,"Arial",Red);
      ObjectCreate("Res3",OBJ_TEXT,0,0,0);
      ObjectSetText("Res3","      R 3",fontsize,"Arial",Red);
     }
   if(counted_bars==0)
      limit=Bars-2; // initial first calculation
   else
      limit=0;      // calculate only last bar!
//----   
   for(i=limit; i>=0;i--)
     {
      //--- check if new day opened
      if(TimeDay(Time[i])!=CurrDay)
        {
         //--- update last day number
         LastDay=CurrDay;
         CurrDay=TimeDay(Time[i]);
         //--- caclucalte levels based on saved vakues
         P=(LastHigh+LastLow+Close[i+1])/3;
         R1=(2*P)-LastLow;
         S1=(2*P)-LastHigh;
         R2=P+(LastHigh - LastLow);
         S2=P-(LastHigh - LastLow);
         R3=(2*P)+(LastHigh-(2*LastLow));
         S3=(2*P)-((2* LastHigh)-LastLow);
         LastLow=Open[i]; LastHigh=Open[i];
         //---- move lines to new levels
         ObjectMove("Pivot",0,Time[i],P);
         ObjectMove("Sup1",0,Time[i],S1);
         ObjectMove("Res1",0,Time[i],R1);
         ObjectMove("Sup2",0,Time[i],S2);
         ObjectMove("Res2",0,Time[i],R2);
         ObjectMove("Sup3",0,Time[i],S3);
         ObjectMove("Res3",0,Time[i],R3);
        }
      PBuffer[i]=P;
      S1Buffer[i]=S1;
      R1Buffer[i]=R1;
      S2Buffer[i]=S2;
      R2Buffer[i]=R2;
      S3Buffer[i]=S3;
      R3Buffer[i]=R3;
      //--- save extremums' values 
      if(High[i]>LastHigh) LastHigh=High[i];
      if(Low[i]<LastLow) LastLow=Low[i];

     }
//----
   return(0);
  }
//+------------------------------------------------------------------+

Slava 2014.09.11 10:55 #28

Проблема не в тестере, а в коде.

Тестер помог эту проблему выявить, потому что именно в визуальном тестере видно то, что не видно в реале, ибо ночь.

Vitalie Postolache 2014.09.11 11:01 #29

Rosh:

Вот правильный вариант для работы режиме онлайн

Для моего варианта такое не подходит, там период расчёта в зависимости от ТФ выбирается, может быть и неделя, и месяц. Почему с iBarShift не работает-то, вот что интересно...

Vitalie Postolache 2014.09.11 11:13 #30

stringo:

Проблема не в тестере, а в коде.

Тестер помог эту проблему выявить, потому что именно в визуальном тестере видно то, что не видно в реале, ибо ночь.

что за ночь?

Что не так с индикаторами Pivot? - страница 3