Помогите с каналом стандартного отклонения - нужны ценовые координаты. - MQL4 и MetaTrader 4

Aleksey Lebedev 2010.02.05 03:26 #1

средняя линия - линейная регрессия.

мона так:)

Правая точка: 3*LWMA(N)-2*SMA(N).

Левая точка: 4*SMA(N)-3*LWMA(N).

Коэффициент "a" в уравнении y=a*x+b.

a=6*(LWMA(N)-SMA(N))/(N-1).

SMA - простая средняя.

LWMA - линейно-взвешенная.

N - период усреднения, растояние в барах от начала до конца канала (bar_left-bar_right+1).

Цикл трендов Шаффа Диалог автора. Александр Смирнов. Элитные показатели :)

Victor Nikolaev 2010.02.05 03:33 #2

AlexTrader0618 писал(а) >>
Доброго времени суток!

Есть идея построить Советник на 'скользящем канале стандартного отклонения' т.е. канал StDev строится от 0-до до N-го бара. с него снимаются направление и угол подъема\падения. На каждом новом баре канал сдвигается вперед (т.е. он постоянно строится на последних N-барах). Если угол больше X от горизонтали - то открывается позиция на покупку\продажу. Если позиция уже существует - она закрывается когда угол наклона канала становится меньше X от горизонта - т.е. канал уходит во флэт. Есть проблемка - из встроенной функции 'канал стандартного отклонения' нельзя вытянуть Ценовые уровни (Y-координаты) по которым построен канал. В описании MT4 по этому поводу говорится следующее (Ось X - Время; Ось Y - Цена):

Из выше изложенного возникает вопрос: как получить Y-координаты (уровень цен) для начала и конца канала (это НЕ те же самые цены, что цены Закрытия на '0'-(нулевом) и 'N'-ом баре), чтобы вычислить угол его (канала) наклона. За любую информацию и советы заранее спасибо.

P.S. Чтоб у вас все было и вам за это ничего не было.

Переделайте под себя индикатор https://www.mql5.com/ru/forum/108553/page3

khorosh 2010.02.05 05:49 #3

AlexTrader0618 писал(а) >>
Доброго времени суток!

Есть идея построить Советник на 'скользящем канале стандартного отклонения' т.е. канал StDev строится от 0-до до N-го бара. с него снимаются направление и угол подъема\падения. На каждом новом баре канал сдвигается вперед (т.е. он постоянно строится на последних N-барах). Если угол больше X от горизонтали - то открывается позиция на покупку\продажу. Если позиция уже существует - она закрывается когда угол наклона канала становится меньше X от горизонта - т.е. канал уходит во флэт. Есть проблемка - из встроенной функции 'канал стандартного отклонения' нельзя вытянуть Ценовые уровни (Y-координаты) по которым построен канал. В описании MT4 по этому поводу говорится следующее (Ось X - Время; Ось Y - Цена):

Из выше изложенного возникает вопрос: как получить Y-координаты (уровень цен) для начала и конца канала (это НЕ те же самые цены, что цены Закрытия на '0'-(нулевом) и 'N'-ом баре), чтобы вычислить угол его (канала) наклона. За любую информацию и советы заранее спасибо.

P.S. Чтоб у вас все было и вам за это ничего не было.

Проще использовать такой индикатор, там цены всех трёх линий можно считать из 3-х соответствующих буферов. Если degree принять равным 1, то будет линейная регрессия, если 2 параболическая и т.д.

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1 LimeGreen
#property indicator_color2 Gold
#property indicator_color3 Gold


extern int degree = 2;
extern double kstd = 2.7;
extern int bars = 19;
extern int shift = 0;


//-----
double fx[],sqh[],sql[];

double ai[10,10],b[10],x[10],sx[20];
double sum; 
int ip,p,n,f;
double qq,mm,tt;
int ii,jj,kk,ll,nn;
double sq;

int i0 = 0;

/*  
void clear()
{
  int total = ObjectsTotal();  
  for (int i=total-1; i >= 0; i--) 
  {
    string name = ObjectName(i);
    if (StringFind(name, prefix) == 0) ObjectDelete(name);
  }
}
*/
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
  SetIndexBuffer(0, fx); // Буферы массивов индикатора
  SetIndexBuffer(1, sqh);
  SetIndexBuffer(2, sql);

  SetIndexStyle(0, DRAW_LINE);
  SetIndexStyle(1, DRAW_LINE);
  SetIndexStyle(2, DRAW_LINE);

  SetIndexEmptyValue(0, 0.0);
  SetIndexEmptyValue(1, 0.0);
  SetIndexEmptyValue(2, 0.0);
  
  SetIndexShift(0, shift);
  SetIndexShift(1, shift);
  SetIndexShift(2, shift);

  return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
{
  //clear();
  return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
  //if(Volume[0]<2)
   {
  if (Bars < bars) return;

//---- 
    
  int mi; // переменная использующаяся только в start
  ip = bars;
  p=ip; // типа присваивание
  sx[1]=p+1; // примечание - [] - означает массив
  nn = degree+1;

  SetIndexDrawBegin(0, Bars-p-1);
  SetIndexDrawBegin(1, Bars-p-1);
  SetIndexDrawBegin(2, Bars-p-1); 
   
//----------------------sx-------------------------------------------------------------------
  for(mi=1;mi<=nn*2-2;mi++) // математическое выражение - для всех mi от 1 до nn*2-2 
  {
    sum=0;
    for(n=i0;n<=i0+p;n++)
    {
       sum+=MathPow(n,mi);
    }
    sx[mi+1]=sum;
  }  
  //----------------------syx-----------
  for(mi=1;mi<=nn;mi++)
  {
    sum=0.00000;
    for(n=i0;n<=i0+p;n++)
    {
       if(mi==1) sum+=Close[n];
       else sum+=Close[n]*MathPow(n,mi-1);
    }
    b[mi]=sum;
  } 
//===============Matrix=======================================================================================================
  for(jj=1;jj<=nn;jj++)
  {
    for(ii=1; ii<=nn; ii++)
    {
       kk=ii+jj-1;
       ai[ii,jj]=sx[kk];
    }
  }  
//===============Gauss========================================================================================================
  for(kk=1; kk<=nn-1; kk++)
  {
    ll=0;
    mm=0;
    for(ii=kk; ii<=nn; ii++)
    {
       if(MathAbs(ai[ii,kk])>mm)
       {
          mm=MathAbs(ai[ii,kk]);
          ll=ii;
       }
    }
    if(ll==0) return(0);   
    if (ll!=kk)
    {
       for(jj=1; jj<=nn; jj++)
       {
          tt=ai[kk,jj];
          ai[kk,jj]=ai[ll,jj];
          ai[ll,jj]=tt;
       }
       tt=b[kk];
       b[kk]=b[ll];
       b[ll]=tt;
    }  
    for(ii=kk+1;ii<=nn;ii++)
    {
       qq=ai[ii,kk]/ai[kk,kk];
       for(jj=1;jj<=nn;jj++)
       {
          if(jj==kk) ai[ii,jj]=0;
          else ai[ii,jj]=ai[ii,jj]-qq*ai[kk,jj];
       }
       b[ii]=b[ii]-qq*b[kk];
    }
  }  
  x[nn]=b[nn]/ai[nn,nn];
  for(ii=nn-1;ii>=1;ii--)
  {
    tt=0;
    for(jj=1;jj<=nn-ii;jj++)
    {
       tt=tt+ai[ii,ii+jj]*x[ii+jj];
       x[ii]=(1/ai[ii,ii])*(b[ii]-tt);
    }
  } 
//===========================================================================================================================
  for(n=i0;n<=i0+p;n++)
  {
    sum=0;
    for(kk=1;kk<=degree;kk++)
    {
       sum+=x[kk+1]*MathPow(n,kk);
    }
    fx[n]=x[1]+sum;
  } 
//-----------------------------------Std-----------------------------------------------------------------------------------
  sq=0.0;
  for(n=i0;n<=i0+p;n++)
  {
    sq+=MathPow(Close[n]-fx[n],2);
  }
  sq=MathSqrt(sq/(p+1))*kstd;

  for(n=i0;n<=i0+p;n++)
  {
    sqh[n]=fx[n]+sq;
    sql[n]=fx[n]-sq;
  }
}
  return(0);
}
//+------------------------------------------------------------------+