servidor vps - página 4
Você está perdendo oportunidades de negociação:
- Aplicativos de negociação gratuitos
- 8 000+ sinais para cópia
- Notícias econômicas para análise dos mercados financeiros
Registro
Login
Você concorda com a política do site e com os termos de uso
Se você não tem uma conta, por favor registre-se
e se não houver internet, não haverá nenhum tiquetaque. A função OnTick não vai funcionar ?
Também correto. Estou de alguma forma preso na conexão com o servidor comercial. É claro que você está certo - sem internet, sem carrapatos - ninguém negocia em nenhum lugar.
Sim, obrigado)
Outra pergunta. Você pode me dizer como selecionar da história as ordens da última semana?
Sim, obrigado)
Outra pergunta. Você pode me dizer como selecionar as ordens da última semana a partir da história?
Quem usa os pedidos agora? É melhor analisar os ofícios. Aqui está um exemplo de solicitação de negócios da história:
//| HistoryDealGetTicket.mq5 |
//| Copyright 2016, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.000"
#property script_show_inputs
//---
input datetime from_date=D'2016.09.20 11:11:00';
input datetime to_date=D'2016.09.20 11:40:00';
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
ulong deal_ticket; // тикет сделки
ulong order_ticket; // тикет ордера,по которому была совершена сделка
datetime transaction_time; // время совершения сделки
long deal_type; // тип торговой операции
long deal_entry; // направление сделки
long position_ID; // идентификатор позиции
string deal_description; // описание операции
double volume; // объем операции
string symbol; // по какому символу была сделка
////--- установим начальную и конечную дату для запроса истории сделок
// datetime from_date=0; // с самого начала
// datetime to_date=TimeCurrent();// по текущий момент
//--- запросим историрю сделок в указанном интервале
HistorySelect(from_date,to_date);
//--- общее количество в списке сделок
int deals=HistoryDealsTotal();
//--- теперь обработаем каждую сделку
for(int i=0;i<deals;i++)
{
deal_ticket=HistoryDealGetTicket(i);
volume=HistoryDealGetDouble(deal_ticket,DEAL_VOLUME);
transaction_time=(datetime)HistoryDealGetInteger(deal_ticket,DEAL_TIME);
order_ticket=HistoryDealGetInteger(deal_ticket,DEAL_ORDER);
deal_type=HistoryDealGetInteger(deal_ticket,DEAL_TYPE);
deal_entry=HistoryDealGetInteger(deal_ticket,DEAL_ENTRY);
symbol=HistoryDealGetString(deal_ticket,DEAL_SYMBOL);
position_ID=HistoryDealGetInteger(deal_ticket,DEAL_POSITION_ID);
deal_description=GetDealDescription(deal_entry,deal_type,volume,symbol,order_ticket,position_ID);
//--- сделаем красивое форматирование для номера сделки
string print_index=StringFormat("% 3d",i);
//--- выведем информацию по сделке
Print(print_index+": deal #",deal_ticket," at ",transaction_time,deal_description);
}
}
//+------------------------------------------------------------------+
//| Возвращает строковое описание операции |
//+------------------------------------------------------------------+
string GetDealDescription(long deal_entry,long deal_type,double volume,string symbol,long ticket,long pos_ID)
{
string descr;
//---
switch(deal_entry)
{
case DEAL_ENTRY_IN: descr="Вход в рынок, "; break;
case DEAL_ENTRY_OUT: descr="Выход из рынка, "; break;
case DEAL_ENTRY_INOUT: descr="Разворот, "; break;
case DEAL_ENTRY_OUT_BY: descr="Закрытие встречной позицией, "; break;
}
//---
switch(deal_type)
{
case DEAL_TYPE_BALANCE: return ("balance");
case DEAL_TYPE_CREDIT: return ("credit");
case DEAL_TYPE_CHARGE: return ("charge");
case DEAL_TYPE_CORRECTION: return ("correction");
case DEAL_TYPE_BUY: descr+="buy"; break;
case DEAL_TYPE_SELL: descr+="sell"; break;
case DEAL_TYPE_BONUS: return ("bonus");
case DEAL_TYPE_COMMISSION: return ("additional commission");
case DEAL_TYPE_COMMISSION_DAILY: return ("daily commission");
case DEAL_TYPE_COMMISSION_MONTHLY: return ("monthly commission");
case DEAL_TYPE_COMMISSION_AGENT_DAILY: return ("daily agent commission");
case DEAL_TYPE_COMMISSION_AGENT_MONTHLY: return ("monthly agent commission");
case DEAL_TYPE_INTEREST: return ("interest rate");
case DEAL_TYPE_BUY_CANCELED: descr+="cancelled buy deal"; break;
case DEAL_TYPE_SELL_CANCELED: descr+="cancelled sell deal"; break;
}
descr=StringFormat("%s %G %s (order #%d, position ID %d)",
descr, // текущее описание
volume, // объем сделки
symbol, // инструмент сделки
ticket, // тикет ордера,вызвавшего сделку
pos_ID // ID позиции, в которой участвовала сделка
);
return(descr);
//---
}
//+------------------------------------------------------------------+
Quem utiliza os mandados hoje em dia? É melhor analisar os ofícios. Aqui está um exemplo de solicitação de negócios da história:
Obrigado, mas preciso ir ao mql4. Não quero mudar para mql5 ainda. De alguma forma eu me acostumei ao MT4.
Para os preguiçosos e para aqueles que são estranhos ao progresso:MQL4 e MetaTrader 4
ahaha... obrigado. Ainda há muitas pessoas hospedadas no MT4. O que qualquer um gosta... Não discuto, há características úteis no MT5, mas não gosto do fato de não se poder abrir duas posições diferentes em direções diferentes com bilhetes diferentes no mesmo símbolo.
De onde vem este niilismo? Você precisa abrir um terminal MetaTrader 5 antes de poder falar :). O terminal MetaTrader 5 há muito tempo tem DOIS tipos de contas de negociação: netting e hedging (sendo o hedging "duas posições diferentes em direções diferentes com carrapatos diferentes no mesmo símbolo").
De onde vem este niilismo? Você precisa abrir um terminal MetaTrader 5 antes de poder falar :). O terminal MetaTrader 5 há muito tempo tem DOIS tipos de contas de negociação: netting e hedging (sendo o hedging "duas posições diferentes em direções diferentes com carrapatos diferentes no mesmo símbolo").
Eu não sabia sobre a sebe. Obrigado (risos) Vou dar uma olhada agora.
Como abrir contas de hedge:sistema de contabilidade de posição de hedge,
não há caixa de seleção "Use hedging" disponível ...( Talvez um terminal antigo?