Bibliotecas: Expert

hini 2025.06.14 17:15 #121

fxsaber #:

Se houver algum problema, forneça arquivos mq5 prontos para reprodução.

#define  MT4ORDERS_LIBRARY
#include "../../utils/MT4Orders.mqh" 
// #define REPORT_BROWSER // Criação de um relatório com a inicialização do navegador - requer permissão da DLL.
#define  TESTER_CUSTOM // Executar o Expert Advisor no testador de usuário
#include "../../utils/fxsaber/Tester/Tester.mqh" // https://www.mql5.com/pt/code/24848

#define  Bid SymbolInfoDouble(_Symbol, SYMBOL_BID)
#define  Ask SymbolInfoDouble(_Symbol, SYMBOL_ASK)

#define  KEY_B 66
#define  KEY_S 83
#define  KEY_C 67

input int In1 = 1;
input group "label1"
input double In2 = 2.0;
// 
void OnChartEvent( const int id, const long &lparam, const double &dparam, const string &sparam ) {
  if (id == CHARTEVENT_KEYDOWN) {
    switch ((int)lparam) {
    case KEY_B: // comprar
      OrderSend(_Symbol, OP_BUY, 1, Ask, 100, 0, 0);
      break;
    case KEY_S: // vender
      OrderSend(_Symbol, OP_SELL, 1, Bid, 100, 0, 0);
      break;
    case KEY_C: // fechar
      for (int i = OrdersTotal() - 1; i >= 0; i--)
        if (OrderSelect(i, SELECT_BY_POS) && (OrderType() <= OP_SELL))
          OrderClose(OrderTicket(), OrderLots(), OrderClosePrice(), 100);
    }
  }
}


void OnTick() {
  //Print(_Symbol, " ", SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE));
}
void OnTimer() { /* Comentário(REPORT::OrdersToString(_Symbol, 0, 5)); */ }
int OnInit() {
  Print(_Symbol, " ", SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_SIZE));
  Print(_Symbol, " In2 = ", In2);
  return(INIT_SUCCEEDED);
}
//
void OnDeinit( const int ) {}
//
void OnTradeTransaction(const MqlTradeTransaction& trans, const MqlTradeRequest& request, const MqlTradeResult& result) {

}
//+------------------------------------------------------------------+

O código de amostra usa o código de sua biblioteca Tester. Após a inicialização, a variável In2 é 0, não 2. Ou seja, todos os parâmetros de entrada não podem ser recuperados após o grupo.

fxsaber 2025.06.17 07:43 #122

hini #:

Essa situação parece não ter sido considerada. Quando o parâmetro é um grupo, não há um valor específico e o valor obtido será nulo, portanto, nenhum parâmetro após o grupo será obtido.

O código a seguir mostra que tudo é tratado corretamente.

input int In1 = 1;
input group "label1"
input double In2 = 2.0;

#include <fxsaber\Expert.mqh> // https://www.mql5.com/pt/code/19003

int GetAmountExperts()
{
  int Res = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    Res += (ChartGetString(Chart, CHART_EXPERT_NAME) != "");
    
  return(Res);
}

void OnInit()
{
  if (GetAmountExperts() < 2)
  {
    MqlParam Params[];
    string Names[];
            
    const int Size = EXPERT::Parameters(0, Params, Names) - 1;
    
    ArrayPrint(Params);
    ArrayPrint(Names);
    
    for (uint i = Size; (bool)i--;)
      EXPERT::AddInputName(Params[i + 1], Names[i]);
            
    Params[Size].string_value = "7";
    EXPERT::Run(ChartOpen(_Symbol, _Period), Params);
  }
}

Resultado.

    [type] [integer_value] [double_value]      [string_value]
[0]     14               0           0.00 "Scripts\Test6.ex5"
[1]     14               1           1.00 "1"                
[2]     14               0           0.00 null               
[3]     14               2           2.00 "2.0"              
"In1" null  "In2"

O Expert Advisor foi iniciado por meio do Expert.mqh.

hini 2025.06.17 14:36 #123

input bool InRun = true;
input group "label1"
input double In2 = 2.0;

#include <fxsaber\Expert.mqh> // https://www.mql5.com/pt/code/19003


int GetAmountExperts()
{
  int Res = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    Res += (ChartGetString(Chart, CHART_EXPERT_NAME) != "");
    
  return(Res);
}

void OnInit()
{
  if (InRun)
  {
    MqlParam Params[];
    string Names[];
            
    const int Size = EXPERT::Parameters(0, Params, Names) - 1;
    
    ArrayPrint(Params);
    ArrayPrint(Names);
    int nameSize = ArraySize(Names);
    for (int i = nameSize-1; i >= 0; i--) {
      if (Names[i] == "InRun")
        Params[i+1].string_value = "false";
      EXPERT::AddInputName(Params[i + 1], Names[i]);
    }  
            
    ArrayPrint(Params);
    ArrayPrint(Names);
    //Params[Size].string_value = "7";
    EXPERT::Run(ChartOpen(_Symbol, _Period), Params);
    return;
  }
  Print("In2 = ", In2);
}

A função GetAmountExperts é executada por um motivo desconhecido, por um período muito longo, sem nenhum resultado. Alterei um pouco o código - por favor, execute-o novamente. Você não deve atribuir o valor 7 ao parâmetro In2 (você verá que há 0, não 2).

[ARQUIVO!] Qualquer pergunta de MetaTrader 4 Build 529 Chirk alguém por 5

fxsaber 2025.06.17 17:53 #124

hini #:

Alterei um pouco o código - por favor, execute-o novamente.

Este é um relatório de bug exemplar: executei o código conciso, que imediatamente mostrou o bug.

Fiz a correção, obrigado.

hini 2025.06.18 01:38 #125

fxsaber #:

Este é um relatório de bug exemplar: executou um código conciso que imediatamente mostrou um bug.

Fiz a correção, obrigado.

Entendo que, em caso de problemas, farei relatórios no mesmo formato.

hini 2025.12.25 03:24 #126

Se o script for carregado, parece que os parâmetros de entrada não podem ser alterados.

 //Test1.ex5
#property script_show_inputs
input string str = "test1" ;
//void OnInit() {
void OnStart () {
   Print (str);
}

 // Iniciar o Expert Advisor com os parâmetros de entrada especificados
#property script_show_inputs

#include "Expert.mqh"

input bool CurrentChart = false ; // Executar o EA no gráfico atual (true)/novo (false)

string GetMyName( void ) {
   return ( StringSubstr ( MQLInfoString ( MQL_PROGRAM_PATH ), StringLen ( TerminalInfoString ( TERMINAL_DATA_PATH ) + "\\MQL5\\" )));
}

bool RunExpert( const long Chart ) {
   MqlParam Params[ 2 ];
  Params[ 0 ].string_value = "Experts\\Advisors\\Test1.ex5" ;
   // O primeiro parâmetro de entrada do Expert Advisor
  Params[ 1 ].type = TYPE_STRING ;
  Params[ 1 ].string_value = "Hello World!" ;
   return (EXPERT::Run(Chart, Params));
}

#define  NAME __FILE__

void OnStart () {
   union UNION {
     double Double;
     long Long;
  } Chart;
   if (CurrentChart) {
    Chart.Long = ChartID ();
     GlobalVariableSet (NAME, Chart.Double);
     MqlParam Params[ 1 ];
     // Caminho para si mesmo (script)
    Params[ 0 ].string_value = GetMyName();
     // No novo gráfico, nós nos lançamos
    EXPERT::Run( ChartOpen ( _Symbol , _Period ), Params);
  } else if ( GlobalVariableCheck (NAME)) {
    Chart.Double = GlobalVariableGet (NAME);
     GlobalVariableDel (NAME);
    RunExpert(Chart.Long);
     ChartClose ();
  } else // A maneira mais fácil de executar o Expert Advisor (com parâmetros não padrão) não é no gráfico atual
    RunExpert( ChartOpen ( _Symbol , _Period ));
}
//+------------------------------------------------------------------+

fxsaber 2025.12.25 13:03 #127

hini #:

Se o script for carregado, parece que os parâmetros de entrada não podem ser alterados.

A arquitetura do MT5 é tal que você não pode definir valores de parâmetros de entrada para scripts e não pode lê-los.

A biblioteca tem um nome eloquente.

hini 2025.12.25 16:32 #128

fxsaber #:

A arquitetura do MT5 é tal que não é possível definir valores de parâmetros de entrada para scripts e não é possível lê-los.

A biblioteca tem um nome eloquente.

ok

fxsaber 2026.01.01 17:27 #129

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Bibliotecas: Expert

fxsaber, 2018.11.16 09:19 AM.

Um exemplo de outro aplicativo da biblioteca

Mais sobre o tópico do modo de quadro, quando a otimização é iniciada sem definir intervalos de otimização.

#include <fxsaber\Expert.mqh> // https://www.mql5.com/pt/code/19003

input group "Params"
input int inRange1 = 0;
input double inRange2 = 0;

// Verifica se os intervalos de otimização estão definidos.
bool OptimizationIsCorrect()
{
  bool Res = false;
  
  if (MQLInfoInteger(MQL_FRAME_MODE))
  {    
    MqlParam Parameters[];
    string Names[];

    EXPERT::Parameters(0, Parameters, Names);
  
    for (uint i = ArraySize(Names); !Res && (bool)i--;)
    {
      long S[4];
      
      ParameterGetRange(Names[i], Res, S[0], S[1], S[2], S[3]);
    }
  }
      
  return(Res);
}

void OnTesterInit()
{
  if (!OptimizationIsCorrect())
  {
    Alert("no optimized parameter selected, please check input(s) to be optimized and set start, step and stop values");
    
    ChartClose();
  }
}

void OnTesterDeinit() {}

Sem essa solução, um Expert Advisor no modo de quadro permanece suspenso no gráfico. Isso é especialmente crítico ao automatizar o testador.

Discussão do artigo "Algoritmos Bibliotecas: MT4Orders Discussão do artigo "Trabalhemos

Bibliotecas: Expert - página 13