Bibliotecas: TypeToBytes

fxsaber 2016.09.15 07:34 #1

Um breve exemplo de como usar a biblioteca

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Dois BookEvent vizinhos podem duplicar uma pilha

fxsaber, 2016.09.14 16:29

O EA mostra quando duas pilhas vizinhas são cópias uma da outra

#include <TypeToBytes.mqh> // https://www.mql5.com/pt/code/16280

template <typename T>
bool ArrayEqual( const T &Array1[], const T &Array2[] )
{
  const int Amount = ArraySize(Array1);
  bool Res = (Amount == ArraySize(Array2));

  if (Res)
    for (int i = 0; i < Amount; i++)
      if (_R(Array1[i]) != Array2[i]) // https://www.mql5.com/pt/code/16280
      {
        Res = false;

        break;
      }

  return(Res);
}

template <typename T>
bool ArrayClone( const T &Source[], T &Target[] )
{
  ArrayFree(Target);

  return(ArrayCopy(Target, Source) >= 0);
}

void OnInit( void )
{
  MarketBookAdd(_Symbol);
}

void OnDeinit( const int Reason )
{
  MarketBookRelease(_Symbol);
}

void OnBookEvent( const string &symbol )
{
  static MqlBookInfo PrevBook[];
  MqlBookInfo Book[];

  if ((symbol == _Symbol) && MarketBookGet(symbol, Book))
  {
    if (ArrayEqual(Book, PrevBook))
    {
      if (ArraySize(PrevBook) > 0)
        Alert("Book == PrevBook");
    }
    else
      ArrayClone(Book, PrevBook);
  }
}

Resultado

2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:29.406 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:23.151 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:23.151 Test2 (Si-9.16,M1)      Book == PrevBook

Pode haver muitos motivos para essas situações: desde o fato de o MT5 pular algumas apostas até a geração de apostas duplas pela própria bolsa.

Bibliotecas: Expert Discussão do artigo "Receitas Bibliotecas: MT4Orders

fxsaber 2016.09.15 10:11 #2

Outro exemplo

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Testando o 'CopyTicks'

fxsaber, 2016.09.15 10:07 AM

Não sei como os outros usam o CopyTicks. Infelizmente, não há confiança. Muito bruto.

Conselheiro

#include <TypeToBytes.mqh> // https://www.mql5.com/pt/code/16280

void OnTick( void )
{
  static MqlTick PrevTick;  
  static int Amount = 0;
  
  MqlTick Ticks[];
  
  if (Amount > 0)
  {
    Amount = CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, PrevTick.time_msc);
    
    int i;
    
    for (i = 0; i < Amount; i++)
      if (_R(Ticks[i]) == PrevTick) // https://www.mql5.com/pt/code/16280
        break;
        
    if (i == Amount)
      Print("Na história (comprimento = " + (string)Amount + ") não há nenhum tique que estava no evento anterior.");
  }
  else
    Amount = CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, TimeCurrent() * 1000);
    
  if (Amount > 0)
    PrevTick = Ticks[Amount - 1];  
}

Resultado

2016.09.15 11:04:02.810 Test2 (RTS-9.16,M1)     В истории (length = 2) нет тика, что был на предыдущем Event.
2016.09.15 11:03:59.312 Test2 (RTS-9.16,M1)     В истории (length = 13) нет тика, что был на предыдущем Event.
2016.09.15 11:03:59.290 Test2 (RTS-9.16,M1)     В истории (length = 1) нет тика, что был на предыдущем Event.

Um tique que estava no histórico não está mais no histórico no próximo evento de tique!

Caros desenvolvedores, coloquem o CopyTicks em um estado funcional. Até mesmo testes simples falham.

Testando 'CopyTicks'. Scripts: CloseAllPositions História do Tick

fxsaber 2016.09.20 15:15 #3

Encontrei uma brecha que me permite substituir essas entradas complicadas

_W(Tick, Offset, (double)1.23456);     // Escreva o valor (double)1.23456 no deslocamento encontrado
_W(CloneTick, 0, Tick);                // Escreva no CloneTick com deslocamento zero o valor do objeto estrutural Tick
_W(Color, 2, (uchar)230);              // Escreva o valor (uchar)230 no deslocamento 2.

em vez de registros tão volumosos.

_W(Tick)[Offset] = 1.23456;             // Escreva o valor (double)1.23456 no deslocamento encontrado
_W(CloneTick)[0] = Tick;                // Escreva no CloneTick com deslocamento zero o valor do objeto estrutural Tick
_W(Color)[2] = (uchar)230;              // Escreva o valor (uchar)230 no deslocamento 2.

Ou seja, há uma possibilidade real de trabalhar com tipos padrão e estruturas simples como uma matriz, não apenas no modo de leitura, mas também no modo de gravação!

Bibliotecas: MultiTester Quaisquer perguntas de recém-chegados Vantagens e desvantagens de

fxsaber 2016.09.21 21:25 #4

fxsaber:

Encontrei uma brecha que me permite substituir essas entradas complicadas

para fazer o habitual

Ou seja, há uma possibilidade real de trabalhar com tipos padrão e estruturas simples como em uma matriz, não apenas no modo de leitura, mas também no modo de gravação!

Publicado. Agora, para qualquer variável (estrutura ou tipo padrão), funciona não apenas a leitura, como em uma matriz, mas também a gravação:

_W(AnyVariable)[Pos] = AnyValue; // Grava o valor AnyValue no deslocamento de byte Pos na variável AnyVariable

Não foi fácil adivinhar isso antes da implementação - acho que acabou sendo um bom teste para o domínio médio de OOP: só conheço os clássicos para classes.

Se alguém souber de algo semelhante, por favor, compartilhe um link para fins educacionais.

Erros, bugs, perguntas Discussão do artigo "Fundamentos Perguntas de Iniciantes MQL5

fxsaber 2016.10.02 19:27 #5

Exemplo de exibição do conteúdo de bytes de uma variável

#include <TypeToBytes.mqh>

#define  TOSTRING(A) " " + #A + " = " + (string)A

string BytesToString( const uchar &Bytes[] )
{  
  string Str = "";

  const int Amount = ArraySize(Bytes);
  
  for (int i = 0; i < Amount; i++)
    Str += TOSTRING(i) + "," + TOSTRING(Bytes[i]) + "\n";
    
  return(Str);
}

#define  VALUETOSTRING(A) typename(A) + TOSTRING(A) + ":\n" + BytesToString(_R(A).Bytes)

void OnStart()
{
  int Tmp = 1;  
  Print(VALUETOSTRING(Tmp));
  
  Tmp = -1;
  Print(VALUETOSTRING(Tmp));
}

Resultado

2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 3, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 2, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 1, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 0, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     int Tmp = -1:
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 3, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 2, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 1, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 0, Bytes[i] = 1
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     int Tmp = 1:

fxsaber 2016.10.11 13:09 #6

Comparação dupla concisa de não um número

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação

Como comparar rapidamente o double e o QNaN?

fxsaber, 2016.10.11.11:14 pm.

Que legal, não sabia disso! Bem, então é assim

#include <TypeToBytes.mqh>

double Nan(long bit_value)
  {
   struct L { long   x; } l; l.x=bit_value;
   struct D { double x; } d=(D)l;
   return(d.x);
  }

double QNaN   =Nan(0x7FF7000000000000);  

void OnStart()
{
   if (_R(QNaN)==QNaN) {
      Alert("QNaN is QNaN");
   } else {
      Alert("Ooops");
   }   
}

Erros, bugs, perguntas Bibliotecas: MT4Orders Bibliotecas: Expert

fxsaber 2016.10.14 13:34 #7

Exemplo de criação de um duplo não-número

#include <TypeToBytes.mqh>

void OnStart()
{
  double QNaN = 0;

  _W(QNaN) = 0x7FF7000000000000;

  Print(QNaN);
}

fxsaber 2016.11.10 11:12 #8

Exemplo de um novo recurso que não afeta diretamente a biblioteca, mas indiretamente - sobre o tópico de estruturas

Fórum sobre negociação, sistemas de negociação automatizados e teste de estratégias de negociação.

MetaEditor build 1463

fxsaber, 2016.11.10:42 AM

class PRINTCLASS
{
public:
  template <typename T>
  static void MyPrint( const T &Value )
  {
    T Array[1];

    Array[0] = Value;

    ::ArrayPrint(Array);
  }

  template <typename T>
  static void MyPrint( const T Value )
  {
    ::Print(Value);
  }
};

#define Print(A) PRINTCLASS::MyPrint(A)

void OnStart()
{
  MqlTick Tick;

  SymbolInfoTick(_Symbol, Tick);

  Print(Tick);

  int i = 5;

  Print(i);
}

Agora, o Print também pode imprimir estruturas simples.

Print variables values Libraries: TypeToBytes MetaEditor build 1463

fxsaber 2017.02.10 11:26 #9

fxsaber:
Exemplo de criação de uma dupla não numérica

#include <TypeToBytes.mqh>

void OnStart()
{
  double QNaN = 0;

  _W(QNaN) = 0x7FF7000000000000;

  Print(QNaN);
}

Agora podemos fazer isso de forma diferente

#include <TypeToBytes.mqh>

void OnStart()
{
  double Number = (double)"01.23_example";
  double Nan = (double)"nan";

  Print(Number);
  Print(Nan);

  ArrayPrint(_R(Nan).Bytes); // Imprimir bytes

  ulong Num = 0;

  _W(Num) = Nan; // Cópia byte a byte de Nan para Num

  PrintFormat("%I64X", Num);
}

resultado

1.23
nan
255 255 255 255 255 255 255 127
7 F FFFFFFFFFFFFFF

Libraries: TypeToBytes Erros, bugs, perguntas Atualizei Metatrader 5 e

Rashid Umarov 2017.02.10 20:22 #10

fxsaber:

Agora podemos fazer isso de forma diferente

#include <TypeToBytes.mqh>

void OnStart()
{
  double Number = (double)"01.23_example";
  double Nan = (double)"nan";

  Print(Number);
  Print(Nan);

  ArrayPrint(_R(Nan).Bytes); // Imprimir bytes

  ulong Num = 0;

  _W(Num) = Nan; // Cópia byte a byte de Nan para Num

  PrintFormat("%I64X", Num);
}

Resultado

1.23
nan
255 255 255 255 255 255 255 127
7 F FFFFFFFFFFFFFF

Você atualizou o código-fonte na publicação?