ForumSezioni

Caratteristiche del linguaggio mql5, sottigliezze e tecniche - pagina 196

Nuovo commento
fxsaber:

Nessun suggerimento sulla provenienza dell'ora (lo stesso per me). Forse dipende dal fuso orario.


Questo non è più interessante.

Nessun indovinello. Ho Mosca. Con GMT non un'ora... Nessun altro pensiero.

Andrey Khatimlianskii:

Forum sul trading, sistemi di trading automatico e test di strategie di trading

Come usare il monitoraggio automatico degli errori nel terminale?

Renat Fatkhullin, 2021.01.22 16:12

C'è un modo non documentato per resettare forzatamente i log su disco attraverso Print(NULL)

Fico!

Andrey Khatimlianskii:

fxsaber:

Fico!

Nella fretta di condividere senza controllare.

Andrey Khatimlianskii:

Nella mia fretta di condividere senza controllare.


Cosa succede se la stringa viene prima azzerata e poi stampata

Opzione per mostrare (non attivare) il grafico (solo MT5)

// Показывает (не активирует) данный чарт.
bool ChartShow( const long Chart )
{
  const bool IsDocked = ChartGetInteger(Chart, CHART_IS_DOCKED);
  
  return(ChartSetInteger(Chart, CHART_IS_DOCKED, !IsDocked) && 
         ChartSetInteger(Chart, CHART_IS_DOCKED, IsDocked) &&
         ChartGetInteger(Chart, CHART_WINDOW_HANDLE));  
}


Esempio di utilizzo.

// Переключает чарты клавишами клавиатуры '<'/'>'.

#define  KEY_LEFT2 188  // '<'
#define  KEY_RIGHT2 190 // '>'

int GetExpertCharts( long &Charts[], const string ExpertName = NULL )
{
  int Amount = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    if ((ExpertName == NULL ) || (ChartGetString(Chart, CHART_EXPERT_NAME) == ExpertName))
    {
      Amount = ArrayResize(Charts, Amount + 1, 10);
      
      Charts[Amount - 1] = Chart;
    }
    
  return(ArrayResize(Charts, Amount));
}

long ChartNextShow( const long Chart, const int Step = 1 )
{
  long ResChart = Chart;
  
  long Charts[];  
  const int Size = GetExpertCharts(Charts);
  
  if ((Size > 1) && (bool)(Step % Size))
    for (int i = 0; i < Size; i++)  
      if (Charts[i] == Chart)
      {
        ResChart = Charts[(i + ((Step > 0) ? Step : (Size - ((-Step) % Size)))) % Size];
        
        ChartShow(ResChart); // https://www.mql5.com/ru/forum/170952/page196#comment_20841674
        
        break;
      }

  return(ResChart);  
}

void OnChartEvent( const int id, const long &lparam, const double&, const string& ) 
{         
  static long Chart = ChartID();
  
  if (id == CHARTEVENT_KEYDOWN) 
    switch ((int)lparam)
    {
    case KEY_LEFT2:
      Chart = ChartNextShow(Chart, -1); // Показали чарт слева
      break;

    case KEY_RIGHT2:
      Chart = ChartNextShow(Chart); // Показали чарт справа
      break;
    }
}

Sfortunatamente, non è stato possibile trovare alcuna opzione di attivazione dei grafici. Solo visualizzazione.

Soluzione ad un vecchio problema. 
/*
// https://www.mql5.com/ru/forum/1111/page2863#comment_18591240
#define VALUE 10

#define MACROS

#ifdef MACROS
  // Нужно VALUE увеличить в два раза.
#endif
*/

// https://www.mql5.com/ru/forum/1111/page2965#comment_20841725
#define  MACRO(  x, y, z )       enum nn##z { y = x };
#define  MACRO2( x, y )          MACRO( x, y, __LINE__ )

// https://www.mql5.com/ru/forum/1111/page2866#comment_18603128
#define  VALUE 10

MACRO2(VALUE, VALUE_TMP) // VALUE_TMP - поле enum, поэтому имя не должно повторяться.
#undef  VALUE
#define  VALUE (VALUE_TMP * 2)

void OnStart()
{
  Print(VALUE);
}

Questa opzione è migliore di questa.

#define  MACRO3(x, y)            const int y = x;

MACRO3(VALUE, VALUE_TMP)

Non ha bisogno di una variabile. Tutti i valori sono impostati al momento della compilazione. Grazie @A100!

fxsaber:

Sfortunatamente, non è stato possibile trovare alcuna opzione di attivazione dei grafici. Solo il display.

Non capisco......... è di questo che stai parlando? È un copione.


ps; E cos'è questo

  const bool IsDocked = ChartGetInteger(Chart, CHART_IS_DOCKED);

Non riesco a trovarlo nella documentazione...

File:
200.mq5  2 kb
Alexey Viktorov:

ps; Cos'è questo

Non riesco a trovarlo nella documentazione...

È ALT+D sul grafico.

Alexey Viktorov:

Non capisco......... stai parlando di questo? È un copione.

Grazie, qualcosa che ho esagerato. Naturalmente, sopra ha ottenuto la gestione dei grafici che non poteva essere raggiunta prima. Ma il mio obiettivo era diverso.

// Активирует данный чарт.
bool ChartActivate( const long Chart )
{
  return(ChartSetInteger(Chart, CHART_BRING_TO_TOP, true) && ChartGetInteger(Chart, CHART_WINDOW_HANDLE));
}


Esempio di utilizzo.

// Переключает чарты с одним и тем же советником клавишами клавиатуры '<'/'>'.

void ChartNextActivate( const int Step = 1, const bool Expert = true )
{
  long Charts[];  
  // https://www.mql5.com/ru/forum/170952/page196#comment_20841674
  const int Size = GetExpertCharts(Charts, Expert ? ChartGetString(0, CHART_EXPERT_NAME) : NULL);
  const long Chart = ChartID();
  
  if ((Size > 1) && (bool)(Step % Size))
    for (int i = 0; i < Size; i++)  
      if (Charts[i] == Chart)
      {
        // https://www.mql5.com/ru/forum/170952/page197#comment_20845067
        ChartActivate(Charts[(i + ((Step > 0) ? Step : (Size - ((-Step) % Size)))) % Size]);
        
        break;
      }

  return;  
}

void OnChartEvent( const int id, const long &lparam, const double&, const string& ) 
{         
  if (id == CHARTEVENT_KEYDOWN) 
    switch ((int)lparam)
    {
    case KEY_LEFT2:
      ChartNextActivate(-1);
      break;

    case KEY_RIGHT2:
      ChartNextActivate();      
      break;
    }
}
1...189190191192193194195196197198199200201202203...247
Nuovo commento